LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ dsysvx()

subroutine dsysvx ( character  FACT,
character  UPLO,
integer  N,
integer  NRHS,
double precision, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( ldaf, * )  AF,
integer  LDAF,
integer, dimension( * )  IPIV,
double precision, dimension( ldb, * )  B,
integer  LDB,
double precision, dimension( ldx, * )  X,
integer  LDX,
double precision  RCOND,
double precision, dimension( * )  FERR,
double precision, dimension( * )  BERR,
double precision, dimension( * )  WORK,
integer  LWORK,
integer, dimension( * )  IWORK,
integer  INFO 
)

DSYSVX computes the solution to system of linear equations A * X = B for SY matrices

Download DSYSVX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DSYSVX uses the diagonal pivoting factorization to compute the
 solution to a real system of linear equations A * X = B,
 where A is an N-by-N symmetric matrix and X and B are N-by-NRHS
 matrices.

 Error bounds on the solution and a condition estimate are also
 provided.
Description:
 The following steps are performed:

 1. If FACT = 'N', the diagonal pivoting method is used to factor A.
    The form of the factorization is
       A = U * D * U**T,  if UPLO = 'U', or
       A = L * D * L**T,  if UPLO = 'L',
    where U (or L) is a product of permutation and unit upper (lower)
    triangular matrices, and D is symmetric and block diagonal with
    1-by-1 and 2-by-2 diagonal blocks.

 2. If some D(i,i)=0, so that D is exactly singular, then the routine
    returns with INFO = i. Otherwise, the factored form of A is used
    to estimate the condition number of the matrix A.  If the
    reciprocal of the condition number is less than machine precision,
    INFO = N+1 is returned as a warning, but the routine still goes on
    to solve for X and compute error bounds as described below.

 3. The system of equations is solved for X using the factored form
    of A.

 4. Iterative refinement is applied to improve the computed solution
    matrix and calculate error bounds and backward error estimates
    for it.
Parameters
[in]FACT
          FACT is CHARACTER*1
          Specifies whether or not the factored form of A has been
          supplied on entry.
          = 'F':  On entry, AF and IPIV contain the factored form of
                  A.  AF and IPIV will not be modified.
          = 'N':  The matrix A will be copied to AF and factored.
[in]UPLO
          UPLO is CHARACTER*1
          = 'U':  Upper triangle of A is stored;
          = 'L':  Lower triangle of A is stored.
[in]N
          N is INTEGER
          The number of linear equations, i.e., the order of the
          matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
          The number of right hand sides, i.e., the number of columns
          of the matrices B and X.  NRHS >= 0.
[in]A
          A is DOUBLE PRECISION array, dimension (LDA,N)
          The symmetric matrix A.  If UPLO = 'U', the leading N-by-N
          upper triangular part of A contains the upper triangular part
          of the matrix A, and the strictly lower triangular part of A
          is not referenced.  If UPLO = 'L', the leading N-by-N lower
          triangular part of A contains the lower triangular part of
          the matrix A, and the strictly upper triangular part of A is
          not referenced.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[in,out]AF
          AF is DOUBLE PRECISION array, dimension (LDAF,N)
          If FACT = 'F', then AF is an input argument and on entry
          contains the block diagonal matrix D and the multipliers used
          to obtain the factor U or L from the factorization
          A = U*D*U**T or A = L*D*L**T as computed by DSYTRF.

          If FACT = 'N', then AF is an output argument and on exit
          returns the block diagonal matrix D and the multipliers used
          to obtain the factor U or L from the factorization
          A = U*D*U**T or A = L*D*L**T.
[in]LDAF
          LDAF is INTEGER
          The leading dimension of the array AF.  LDAF >= max(1,N).
[in,out]IPIV
          IPIV is INTEGER array, dimension (N)
          If FACT = 'F', then IPIV is an input argument and on entry
          contains details of the interchanges and the block structure
          of D, as determined by DSYTRF.
          If IPIV(k) > 0, then rows and columns k and IPIV(k) were
          interchanged and D(k,k) is a 1-by-1 diagonal block.
          If UPLO = 'U' and IPIV(k) = IPIV(k-1) < 0, then rows and
          columns k-1 and -IPIV(k) were interchanged and D(k-1:k,k-1:k)
          is a 2-by-2 diagonal block.  If UPLO = 'L' and IPIV(k) =
          IPIV(k+1) < 0, then rows and columns k+1 and -IPIV(k) were
          interchanged and D(k:k+1,k:k+1) is a 2-by-2 diagonal block.

          If FACT = 'N', then IPIV is an output argument and on exit
          contains details of the interchanges and the block structure
          of D, as determined by DSYTRF.
[in]B
          B is DOUBLE PRECISION array, dimension (LDB,NRHS)
          The N-by-NRHS right hand side matrix B.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,N).
[out]X
          X is DOUBLE PRECISION array, dimension (LDX,NRHS)
          If INFO = 0 or INFO = N+1, the N-by-NRHS solution matrix X.
[in]LDX
          LDX is INTEGER
          The leading dimension of the array X.  LDX >= max(1,N).
[out]RCOND
          RCOND is DOUBLE PRECISION
          The estimate of the reciprocal condition number of the matrix
          A.  If RCOND is less than the machine precision (in
          particular, if RCOND = 0), the matrix is singular to working
          precision.  This condition is indicated by a return code of
          INFO > 0.
[out]FERR
          FERR is DOUBLE PRECISION array, dimension (NRHS)
          The estimated forward error bound for each solution vector
          X(j) (the j-th column of the solution matrix X).
          If XTRUE is the true solution corresponding to X(j), FERR(j)
          is an estimated upper bound for the magnitude of the largest
          element in (X(j) - XTRUE) divided by the magnitude of the
          largest element in X(j).  The estimate is as reliable as
          the estimate for RCOND, and is almost always a slight
          overestimate of the true error.
[out]BERR
          BERR is DOUBLE PRECISION array, dimension (NRHS)
          The componentwise relative backward error of each solution
          vector X(j) (i.e., the smallest relative change in
          any element of A or B that makes X(j) an exact solution).
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK))
          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
[in]LWORK
          LWORK is INTEGER
          The length of WORK.  LWORK >= max(1,3*N), and for best
          performance, when FACT = 'N', LWORK >= max(1,3*N,N*NB), where
          NB is the optimal blocksize for DSYTRF.

          If LWORK = -1, then a workspace query is assumed; the routine
          only calculates the optimal size of the WORK array, returns
          this value as the first entry of the WORK array, and no error
          message related to LWORK is issued by XERBLA.
[out]IWORK
          IWORK is INTEGER array, dimension (N)
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument had an illegal value
          > 0: if INFO = i, and i is
                <= N:  D(i,i) is exactly zero.  The factorization
                       has been completed but the factor D is exactly
                       singular, so the solution and error bounds could
                       not be computed. RCOND = 0 is returned.
                = N+1: D is nonsingular, but RCOND is less than machine
                       precision, meaning that the matrix is singular
                       to working precision.  Nevertheless, the
                       solution and error bounds are computed because
                       there are a number of situations where the
                       computed solution can be more accurate than the
                       value of RCOND would suggest.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 281 of file dsysvx.f.

284 *
285 * -- LAPACK driver routine --
286 * -- LAPACK is a software package provided by Univ. of Tennessee, --
287 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
288 *
289 * .. Scalar Arguments ..
290  CHARACTER FACT, UPLO
291  INTEGER INFO, LDA, LDAF, LDB, LDX, LWORK, N, NRHS
292  DOUBLE PRECISION RCOND
293 * ..
294 * .. Array Arguments ..
295  INTEGER IPIV( * ), IWORK( * )
296  DOUBLE PRECISION A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
297  $ BERR( * ), FERR( * ), WORK( * ), X( LDX, * )
298 * ..
299 *
300 * =====================================================================
301 *
302 * .. Parameters ..
303  DOUBLE PRECISION ZERO
304  parameter( zero = 0.0d+0 )
305 * ..
306 * .. Local Scalars ..
307  LOGICAL LQUERY, NOFACT
308  INTEGER LWKOPT, NB
309  DOUBLE PRECISION ANORM
310 * ..
311 * .. External Functions ..
312  LOGICAL LSAME
313  INTEGER ILAENV
314  DOUBLE PRECISION DLAMCH, DLANSY
315  EXTERNAL lsame, ilaenv, dlamch, dlansy
316 * ..
317 * .. External Subroutines ..
318  EXTERNAL dlacpy, dsycon, dsyrfs, dsytrf, dsytrs, xerbla
319 * ..
320 * .. Intrinsic Functions ..
321  INTRINSIC max
322 * ..
323 * .. Executable Statements ..
324 *
325 * Test the input parameters.
326 *
327  info = 0
328  nofact = lsame( fact, 'N' )
329  lquery = ( lwork.EQ.-1 )
330  IF( .NOT.nofact .AND. .NOT.lsame( fact, 'F' ) ) THEN
331  info = -1
332  ELSE IF( .NOT.lsame( uplo, 'U' ) .AND. .NOT.lsame( uplo, 'L' ) )
333  $ THEN
334  info = -2
335  ELSE IF( n.LT.0 ) THEN
336  info = -3
337  ELSE IF( nrhs.LT.0 ) THEN
338  info = -4
339  ELSE IF( lda.LT.max( 1, n ) ) THEN
340  info = -6
341  ELSE IF( ldaf.LT.max( 1, n ) ) THEN
342  info = -8
343  ELSE IF( ldb.LT.max( 1, n ) ) THEN
344  info = -11
345  ELSE IF( ldx.LT.max( 1, n ) ) THEN
346  info = -13
347  ELSE IF( lwork.LT.max( 1, 3*n ) .AND. .NOT.lquery ) THEN
348  info = -18
349  END IF
350 *
351  IF( info.EQ.0 ) THEN
352  lwkopt = max( 1, 3*n )
353  IF( nofact ) THEN
354  nb = ilaenv( 1, 'DSYTRF', uplo, n, -1, -1, -1 )
355  lwkopt = max( lwkopt, n*nb )
356  END IF
357  work( 1 ) = lwkopt
358  END IF
359 *
360  IF( info.NE.0 ) THEN
361  CALL xerbla( 'DSYSVX', -info )
362  RETURN
363  ELSE IF( lquery ) THEN
364  RETURN
365  END IF
366 *
367  IF( nofact ) THEN
368 *
369 * Compute the factorization A = U*D*U**T or A = L*D*L**T.
370 *
371  CALL dlacpy( uplo, n, n, a, lda, af, ldaf )
372  CALL dsytrf( uplo, n, af, ldaf, ipiv, work, lwork, info )
373 *
374 * Return if INFO is non-zero.
375 *
376  IF( info.GT.0 )THEN
377  rcond = zero
378  RETURN
379  END IF
380  END IF
381 *
382 * Compute the norm of the matrix A.
383 *
384  anorm = dlansy( 'I', uplo, n, a, lda, work )
385 *
386 * Compute the reciprocal of the condition number of A.
387 *
388  CALL dsycon( uplo, n, af, ldaf, ipiv, anorm, rcond, work, iwork,
389  $ info )
390 *
391 * Compute the solution vectors X.
392 *
393  CALL dlacpy( 'Full', n, nrhs, b, ldb, x, ldx )
394  CALL dsytrs( uplo, n, nrhs, af, ldaf, ipiv, x, ldx, info )
395 *
396 * Use iterative refinement to improve the computed solutions and
397 * compute error bounds and backward error estimates for them.
398 *
399  CALL dsyrfs( uplo, n, nrhs, a, lda, af, ldaf, ipiv, b, ldb, x,
400  $ ldx, ferr, berr, work, iwork, info )
401 *
402 * Set INFO = N+1 if the matrix is singular to working precision.
403 *
404  IF( rcond.LT.dlamch( 'Epsilon' ) )
405  $ info = n + 1
406 *
407  work( 1 ) = lwkopt
408 *
409  RETURN
410 *
411 * End of DSYSVX
412 *
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:69
subroutine dlacpy(UPLO, M, N, A, LDA, B, LDB)
DLACPY copies all or part of one two-dimensional array to another.
Definition: dlacpy.f:103
integer function ilaenv(ISPEC, NAME, OPTS, N1, N2, N3, N4)
ILAENV
Definition: ilaenv.f:162
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
double precision function dlansy(NORM, UPLO, N, A, LDA, WORK)
DLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: dlansy.f:122
subroutine dsycon(UPLO, N, A, LDA, IPIV, ANORM, RCOND, WORK, IWORK, INFO)
DSYCON
Definition: dsycon.f:130
subroutine dsytrs(UPLO, N, NRHS, A, LDA, IPIV, B, LDB, INFO)
DSYTRS
Definition: dsytrs.f:120
subroutine dsyrfs(UPLO, N, NRHS, A, LDA, AF, LDAF, IPIV, B, LDB, X, LDX, FERR, BERR, WORK, IWORK, INFO)
DSYRFS
Definition: dsyrfs.f:191
subroutine dsytrf(UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO)
DSYTRF
Definition: dsytrf.f:182
Here is the call graph for this function:
Here is the caller graph for this function: