zgerq2()

subroutine zgerq2	(	integer	m,
		integer	n,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( * )	tau,
		complex*16, dimension( * )	work,
		integer	info )

ZGERQ2 computes the RQ factorization of a general rectangular matrix using an unblocked algorithm.

Download ZGERQ2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZGERQ2 computes an RQ factorization of a complex m by n matrix A:
!> A = R * Q.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in,out]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> On entry, the m by n matrix A. !> On exit, if m <= n, the upper triangle of the subarray !> A(1:m,n-m+1:n) contains the m by m upper triangular matrix R; !> if m >= n, the elements on and above the (m-n)-th subdiagonal !> contain the m by n upper trapezoidal matrix R; the remaining !> elements, with the array TAU, represent the unitary matrix !> Q as a product of elementary reflectors (see Further !> Details). !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,M). !>
[out]	TAU	!> TAU is COMPLEX*16 array, dimension (min(M,N)) !> The scalar factors of the elementary reflectors (see Further !> Details). !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (M) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  The matrix Q is represented as a product of elementary reflectors
!>
!>     Q = H(1)**H H(2)**H . . . H(k)**H, where k = min(m,n).
!>
!>  Each H(i) has the form
!>
!>     H(i) = I - tau * v * v**H
!>
!>  where tau is a complex scalar, and v is a complex vector with
!>  v(n-k+i+1:n) = 0 and v(n-k+i) = 1; conjg(v(1:n-k+i-1)) is stored on
!>  exit in A(m-k+i,1:n-k+i-1), and tau in TAU(i).
!> 

Definition at line 120 of file zgerq2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, M, N
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16         ONE
      parameter( one = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, K
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zlacgv, zlarf1l, zlarfg
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZGERQ2', -info )
         RETURN
      END IF
*
      k = min( m, n )
*
      DO 10 i = k, 1, -1
*
*        Generate elementary reflector H(i) to annihilate
*        A(m-k+i,1:n-k+i-1)
*
         CALL zlacgv( n-k+i, a( m-k+i, 1 ), lda )
         CALL zlarfg( n-k+i, a( m-k+i, n-k+i ), a( m-k+i, 1 ), lda,
     $                tau( i ) )
*
*        Apply H(i) to A(1:m-k+i-1,1:n-k+i) from the right
*
         CALL zlarf1l( 'Right', m-k+i-1, n-k+i, a( m-k+i, 1 ), lda,
     $                 tau( i ), a, lda, work )
         CALL zlacgv( n-k+i-1, a( m-k+i, 1 ), lda )
   10 CONTINUE
      RETURN
*
*     End of ZGERQ2
*

Here is the call graph for this function:

Here is the caller graph for this function: