sasum()

real function sasum	(	integer	n,
		real, dimension(*)	sx,
		integer	incx
	)

SASUM

Purpose:

    SASUM takes the sum of the absolute values.
    uses unrolled loops for increment equal to one.

Parameters

[in]	N	N is INTEGER number of elements in input vector(s)
[in]	SX	SX is REAL array, dimension ( 1 + ( N - 1 )*abs( INCX ) )
[in]	INCX	INCX is INTEGER storage spacing between elements of SX

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

     jack dongarra, linpack, 3/11/78.
     modified 3/93 to return if incx .le. 0.
     modified 12/3/93, array(1) declarations changed to array(*)

Definition at line 71 of file sasum.f.

*
*  -- Reference BLAS level1 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER INCX,N
*     ..
*     .. Array Arguments ..
      REAL SX(*)
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      REAL STEMP
      INTEGER I,M,MP1,NINCX
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC abs,mod
*     ..
      sasum = 0.0e0
      stemp = 0.0e0
      IF (n.LE.0 .OR. incx.LE.0) RETURN
      IF (incx.EQ.1) THEN
*        code for increment equal to 1
*
*
*        clean-up loop
*
         m = mod(n,6)
         IF (m.NE.0) THEN
            DO i = 1,m
               stemp = stemp + abs(sx(i))
            END DO
            IF (n.LT.6) THEN
               sasum = stemp
               RETURN
            END IF
         END IF
         mp1 = m + 1
         DO i = mp1,n,6
            stemp = stemp + abs(sx(i)) + abs(sx(i+1)) +
     $              abs(sx(i+2)) + abs(sx(i+3)) +
     $              abs(sx(i+4)) + abs(sx(i+5))
         END DO
      ELSE
*
*        code for increment not equal to 1
*
         nincx = n*incx
         DO i = 1,nincx,incx
            stemp = stemp + abs(sx(i))
         END DO
      END IF
      sasum = stemp
      RETURN
*
*     End of SASUM
*

Here is the call graph for this function:

Here is the caller graph for this function: