LAPACK  3.10.1
LAPACK: Linear Algebra PACKage

◆ clangb()

real function clangb ( character  NORM,
integer  N,
integer  KL,
integer  KU,
complex, dimension( ldab, * )  AB,
integer  LDAB,
real, dimension( * )  WORK 
)

CLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of general band matrix.

Download CLANGB + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CLANGB  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the element of  largest absolute value  of an
 n by n band matrix  A,  with kl sub-diagonals and ku super-diagonals.
Returns
CLANGB
    CLANGB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in CLANGB as described
          above.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.  When N = 0, CLANGB is
          set to zero.
[in]KL
          KL is INTEGER
          The number of sub-diagonals of the matrix A.  KL >= 0.
[in]KU
          KU is INTEGER
          The number of super-diagonals of the matrix A.  KU >= 0.
[in]AB
          AB is COMPLEX array, dimension (LDAB,N)
          The band matrix A, stored in rows 1 to KL+KU+1.  The j-th
          column of A is stored in the j-th column of the array AB as
          follows:
          AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(n,j+kl).
[in]LDAB
          LDAB is INTEGER
          The leading dimension of the array AB.  LDAB >= KL+KU+1.
[out]WORK
          WORK is REAL array, dimension (MAX(1,LWORK)),
          where LWORK >= N when NORM = 'I'; otherwise, WORK is not
          referenced.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 123 of file clangb.f.

125 *
126 * -- LAPACK auxiliary routine --
127 * -- LAPACK is a software package provided by Univ. of Tennessee, --
128 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
129 *
130 * .. Scalar Arguments ..
131  CHARACTER NORM
132  INTEGER KL, KU, LDAB, N
133 * ..
134 * .. Array Arguments ..
135  REAL WORK( * )
136  COMPLEX AB( LDAB, * )
137 * ..
138 *
139 * =====================================================================
140 *
141 * .. Parameters ..
142  REAL ONE, ZERO
143  parameter( one = 1.0e+0, zero = 0.0e+0 )
144 * ..
145 * .. Local Scalars ..
146  INTEGER I, J, K, L
147  REAL SCALE, SUM, VALUE, TEMP
148 * ..
149 * .. External Functions ..
150  LOGICAL LSAME, SISNAN
151  EXTERNAL lsame, sisnan
152 * ..
153 * .. External Subroutines ..
154  EXTERNAL classq
155 * ..
156 * .. Intrinsic Functions ..
157  INTRINSIC abs, max, min, sqrt
158 * ..
159 * .. Executable Statements ..
160 *
161  IF( n.EQ.0 ) THEN
162  VALUE = zero
163  ELSE IF( lsame( norm, 'M' ) ) THEN
164 *
165 * Find max(abs(A(i,j))).
166 *
167  VALUE = zero
168  DO 20 j = 1, n
169  DO 10 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
170  temp = abs( ab( i, j ) )
171  IF( VALUE.LT.temp .OR. sisnan( temp ) ) VALUE = temp
172  10 CONTINUE
173  20 CONTINUE
174  ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
175 *
176 * Find norm1(A).
177 *
178  VALUE = zero
179  DO 40 j = 1, n
180  sum = zero
181  DO 30 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
182  sum = sum + abs( ab( i, j ) )
183  30 CONTINUE
184  IF( VALUE.LT.sum .OR. sisnan( sum ) ) VALUE = sum
185  40 CONTINUE
186  ELSE IF( lsame( norm, 'I' ) ) THEN
187 *
188 * Find normI(A).
189 *
190  DO 50 i = 1, n
191  work( i ) = zero
192  50 CONTINUE
193  DO 70 j = 1, n
194  k = ku + 1 - j
195  DO 60 i = max( 1, j-ku ), min( n, j+kl )
196  work( i ) = work( i ) + abs( ab( k+i, j ) )
197  60 CONTINUE
198  70 CONTINUE
199  VALUE = zero
200  DO 80 i = 1, n
201  temp = work( i )
202  IF( VALUE.LT.temp .OR. sisnan( temp ) ) VALUE = temp
203  80 CONTINUE
204  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
205 *
206 * Find normF(A).
207 *
208  scale = zero
209  sum = one
210  DO 90 j = 1, n
211  l = max( 1, j-ku )
212  k = ku + 1 - j + l
213  CALL classq( min( n, j+kl )-l+1, ab( k, j ), 1, scale, sum )
214  90 CONTINUE
215  VALUE = scale*sqrt( sum )
216  END IF
217 *
218  clangb = VALUE
219  RETURN
220 *
221 * End of CLANGB
222 *
subroutine classq(n, x, incx, scl, sumsq)
CLASSQ updates a sum of squares represented in scaled form.
Definition: classq.f90:137
logical function sisnan(SIN)
SISNAN tests input for NaN.
Definition: sisnan.f:59
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
real function clangb(NORM, N, KL, KU, AB, LDAB, WORK)
CLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: clangb.f:125
Here is the call graph for this function:
Here is the caller graph for this function: