cgees()

subroutine cgees	(	character	jobvs,
		character	sort,
		external	select,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		integer	sdim,
		complex, dimension( * )	w,
		complex, dimension( ldvs, * )	vs,
		integer	ldvs,
		complex, dimension( * )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		logical, dimension( * )	bwork,
		integer	info )

CGEES computes the eigenvalues, the Schur form, and, optionally, the matrix of Schur vectors for GE matrices

Download CGEES + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CGEES computes for an N-by-N complex nonsymmetric matrix A, the
!> eigenvalues, the Schur form T, and, optionally, the matrix of Schur
!> vectors Z.  This gives the Schur factorization A = Z*T*(Z**H).
!>
!> Optionally, it also orders the eigenvalues on the diagonal of the
!> Schur form so that selected eigenvalues are at the top left.
!> The leading columns of Z then form an orthonormal basis for the
!> invariant subspace corresponding to the selected eigenvalues.
!>
!> A complex matrix is in Schur form if it is upper triangular.
!> 

Parameters

[in]	JOBVS	!> JOBVS is CHARACTER*1 !> = 'N': Schur vectors are not computed; !> = 'V': Schur vectors are computed. !>
[in]	SORT	!> SORT is CHARACTER*1 !> Specifies whether or not to order the eigenvalues on the !> diagonal of the Schur form. !> = 'N': Eigenvalues are not ordered: !> = 'S': Eigenvalues are ordered (see SELECT). !>
[in]	SELECT	!> SELECT is a LOGICAL FUNCTION of one COMPLEX argument !> SELECT must be declared EXTERNAL in the calling subroutine. !> If SORT = 'S', SELECT is used to select eigenvalues to order !> to the top left of the Schur form. !> IF SORT = 'N', SELECT is not referenced. !> The eigenvalue W(j) is selected if SELECT(W(j)) is true. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in,out]	A	!> A is COMPLEX array, dimension (LDA,N) !> On entry, the N-by-N matrix A. !> On exit, A has been overwritten by its Schur form T. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	SDIM	!> SDIM is INTEGER !> If SORT = 'N', SDIM = 0. !> If SORT = 'S', SDIM = number of eigenvalues for which !> SELECT is true. !>
[out]	W	!> W is COMPLEX array, dimension (N) !> W contains the computed eigenvalues, in the same order that !> they appear on the diagonal of the output Schur form T. !>
[out]	VS	!> VS is COMPLEX array, dimension (LDVS,N) !> If JOBVS = 'V', VS contains the unitary matrix Z of Schur !> vectors. !> If JOBVS = 'N', VS is not referenced. !>
[in]	LDVS	!> LDVS is INTEGER !> The leading dimension of the array VS. LDVS >= 1; if !> JOBVS = 'V', LDVS >= N. !>
[out]	WORK	!> WORK is COMPLEX array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. LWORK >= max(1,2*N). !> For good performance, LWORK must generally be larger. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	RWORK	!> RWORK is REAL array, dimension (N) !>
[out]	BWORK	!> BWORK is LOGICAL array, dimension (N) !> Not referenced if SORT = 'N'. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value. !> > 0: if INFO = i, and i is !> <= N: the QR algorithm failed to compute all the !> eigenvalues; elements 1:ILO-1 and i+1:N of W !> contain those eigenvalues which have converged; !> if JOBVS = 'V', VS contains the matrix which !> reduces A to its partially converged Schur form. !> = N+1: the eigenvalues could not be reordered because !> some eigenvalues were too close to separate (the !> problem is very ill-conditioned); !> = N+2: after reordering, roundoff changed values of !> some complex eigenvalues so that leading !> eigenvalues in the Schur form no longer satisfy !> SELECT = .TRUE.. This could also be caused by !> underflow due to scaling. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 193 of file cgees.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          JOBVS, SORT
      INTEGER            INFO, LDA, LDVS, LWORK, N, SDIM
*     ..
*     .. Array Arguments ..
      LOGICAL            BWORK( * )
      REAL               RWORK( * )
      COMPLEX            A( LDA, * ), VS( LDVS, * ), W( * ), WORK( * )
*     ..
*     .. Function Arguments ..
      LOGICAL            SELECT
      EXTERNAL           SELECT
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e0, one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, SCALEA, WANTST, WANTVS
      INTEGER            HSWORK, I, IBAL, ICOND, IERR, IEVAL, IHI, ILO,
     $                   ITAU, IWRK, MAXWRK, MINWRK
      REAL               ANRM, BIGNUM, CSCALE, EPS, S, SEP, SMLNUM
*     ..
*     .. Local Arrays ..
      REAL               DUM( 1 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           ccopy, cgebak, cgebal, cgehrd, chseqr,
     $                   clacpy,
     $                   clascl, ctrsen, cunghr, xerbla
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      REAL               CLANGE, SLAMCH, SROUNDUP_LWORK
      EXTERNAL           lsame, ilaenv, clange,
     $                   slamch, sroundup_lwork
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      lquery = ( lwork.EQ.-1 )
      wantvs = lsame( jobvs, 'V' )
      wantst = lsame( sort, 'S' )
      IF( ( .NOT.wantvs ) .AND. ( .NOT.lsame( jobvs, 'N' ) ) ) THEN
         info = -1
      ELSE IF( ( .NOT.wantst ) .AND.
     $         ( .NOT.lsame( sort, 'N' ) ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -6
      ELSE IF( ldvs.LT.1 .OR. ( wantvs .AND. ldvs.LT.n ) ) THEN
         info = -10
      END IF
*
*     Compute workspace
*      (Note: Comments in the code beginning "Workspace:" describe the
*       minimal amount of workspace needed at that point in the code,
*       as well as the preferred amount for good performance.
*       CWorkspace refers to complex workspace, and RWorkspace to real
*       workspace. NB refers to the optimal block size for the
*       immediately following subroutine, as returned by ILAENV.
*       HSWORK refers to the workspace preferred by CHSEQR, as
*       calculated below. HSWORK is computed assuming ILO=1 and IHI=N,
*       the worst case.)
*
      IF( info.EQ.0 ) THEN
         IF( n.EQ.0 ) THEN
            minwrk = 1
            maxwrk = 1
         ELSE
            maxwrk = n + n*ilaenv( 1, 'CGEHRD', ' ', n, 1, n, 0 )
            minwrk = 2*n
*
            CALL chseqr( 'S', jobvs, n, 1, n, a, lda, w, vs, ldvs,
     $             work, -1, ieval )
            hswork = int( work( 1 ) )
*
            IF( .NOT.wantvs ) THEN
               maxwrk = max( maxwrk, hswork )
            ELSE
               maxwrk = max( maxwrk, n + ( n - 1 )*ilaenv( 1,
     $                       'CUNGHR',
     $                       ' ', n, 1, n, -1 ) )
               maxwrk = max( maxwrk, hswork )
            END IF
         END IF
         work( 1 ) = sroundup_lwork(maxwrk)
*
         IF( lwork.LT.minwrk .AND. .NOT.lquery ) THEN
            info = -12
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CGEES ', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 ) THEN
         sdim = 0
         RETURN
      END IF
*
*     Get machine constants
*
      eps = slamch( 'P' )
      smlnum = slamch( 'S' )
      bignum = one / smlnum
      smlnum = sqrt( smlnum ) / eps
      bignum = one / smlnum
*
*     Scale A if max element outside range [SMLNUM,BIGNUM]
*
      anrm = clange( 'M', n, n, a, lda, dum )
      scalea = .false.
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
         scalea = .true.
         cscale = smlnum
      ELSE IF( anrm.GT.bignum ) THEN
         scalea = .true.
         cscale = bignum
      END IF
      IF( scalea )
     $   CALL clascl( 'G', 0, 0, anrm, cscale, n, n, a, lda, ierr )
*
*     Permute the matrix to make it more nearly triangular
*     (CWorkspace: none)
*     (RWorkspace: need N)
*
      ibal = 1
      CALL cgebal( 'P', n, a, lda, ilo, ihi, rwork( ibal ), ierr )
*
*     Reduce to upper Hessenberg form
*     (CWorkspace: need 2*N, prefer N+N*NB)
*     (RWorkspace: none)
*
      itau = 1
      iwrk = n + itau
      CALL cgehrd( n, ilo, ihi, a, lda, work( itau ), work( iwrk ),
     $             lwork-iwrk+1, ierr )
*
      IF( wantvs ) THEN
*
*        Copy Householder vectors to VS
*
         CALL clacpy( 'L', n, n, a, lda, vs, ldvs )
*
*        Generate unitary matrix in VS
*        (CWorkspace: need 2*N-1, prefer N+(N-1)*NB)
*        (RWorkspace: none)
*
         CALL cunghr( n, ilo, ihi, vs, ldvs, work( itau ),
     $                work( iwrk ),
     $                lwork-iwrk+1, ierr )
      END IF
*
      sdim = 0
*
*     Perform QR iteration, accumulating Schur vectors in VS if desired
*     (CWorkspace: need 1, prefer HSWORK (see comments) )
*     (RWorkspace: none)
*
      iwrk = itau
      CALL chseqr( 'S', jobvs, n, ilo, ihi, a, lda, w, vs, ldvs,
     $             work( iwrk ), lwork-iwrk+1, ieval )
      IF( ieval.GT.0 )
     $   info = ieval
*
*     Sort eigenvalues if desired
*
      IF( wantst .AND. info.EQ.0 ) THEN
         IF( scalea )
     $      CALL clascl( 'G', 0, 0, cscale, anrm, n, 1, w, n, ierr )
         DO 10 i = 1, n
            bwork( i ) = SELECT( w( i ) )
   10    CONTINUE
*
*        Reorder eigenvalues and transform Schur vectors
*        (CWorkspace: none)
*        (RWorkspace: none)
*
         CALL ctrsen( 'N', jobvs, bwork, n, a, lda, vs, ldvs, w,
     $                sdim,
     $                s, sep, work( iwrk ), lwork-iwrk+1, icond )
      END IF
*
      IF( wantvs ) THEN
*
*        Undo balancing
*        (CWorkspace: none)
*        (RWorkspace: need N)
*
         CALL cgebak( 'P', 'R', n, ilo, ihi, rwork( ibal ), n, vs,
     $                ldvs,
     $                ierr )
      END IF
*
      IF( scalea ) THEN
*
*        Undo scaling for the Schur form of A
*
         CALL clascl( 'U', 0, 0, cscale, anrm, n, n, a, lda, ierr )
         CALL ccopy( n, a, lda+1, w, 1 )
      END IF
*
      work( 1 ) = sroundup_lwork(maxwrk)
      RETURN
*
*     End of CGEES
*

Here is the call graph for this function:

Here is the caller graph for this function: