cchkhb2stg()

subroutine cchkhb2stg	(	integer	nsizes,
		integer, dimension( * )	nn,
		integer	nwdths,
		integer, dimension( * )	kk,
		integer	ntypes,
		logical, dimension( * )	dotype,
		integer, dimension( 4 )	iseed,
		real	thresh,
		integer	nounit,
		complex, dimension( lda, * )	a,
		integer	lda,
		real, dimension( * )	sd,
		real, dimension( * )	se,
		real, dimension( * )	d1,
		real, dimension( * )	d2,
		real, dimension( * )	d3,
		complex, dimension( ldu, * )	u,
		integer	ldu,
		complex, dimension( * )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		real, dimension( * )	result,
		integer	info )

CCHKHB2STG

Purpose:

!>
!> CCHKHB2STG tests the reduction of a Hermitian band matrix to tridiagonal
!> from, used with the Hermitian eigenvalue problem.
!>
!> CHBTRD factors a Hermitian band matrix A as  U S U* , where * means
!> conjugate transpose, S is symmetric tridiagonal, and U is unitary.
!> CHBTRD can use either just the lower or just the upper triangle
!> of A; CCHKHB2STG checks both cases.
!>
!> CHETRD_HB2ST factors a Hermitian band matrix A as  U S U* ,
!> where * means conjugate transpose, S is symmetric tridiagonal, and U is
!> unitary. CHETRD_HB2ST can use either just the lower or just
!> the upper triangle of A; CCHKHB2STG checks both cases.
!>
!> DSTEQR factors S as  Z D1 Z'.
!> D1 is the matrix of eigenvalues computed when Z is not computed
!> and from the S resulting of DSBTRD  (used as reference for DSYTRD_SB2ST)
!> D2 is the matrix of eigenvalues computed when Z is not computed
!> and from the S resulting of DSYTRD_SB2ST .
!> D3 is the matrix of eigenvalues computed when Z is not computed
!> and from the S resulting of DSYTRD_SB2ST .
!>
!> When CCHKHB2STG is called, a number of matrix  (), a number
!> of bandwidths (), and a number of matrix  are
!> specified.  For each size (), each bandwidth () less than or
!> equal to , and each type of matrix, one matrix will be generated
!> and used to test the hermitian banded reduction routine.  For each
!> matrix, a number of tests will be performed:
!>
!> (1)     | A - V S V* | / ( |A| n ulp )  computed by CHBTRD with
!>                                         UPLO='U'
!>
!> (2)     | I - UU* | / ( n ulp )
!>
!> (3)     | A - V S V* | / ( |A| n ulp )  computed by CHBTRD with
!>                                         UPLO='L'
!>
!> (4)     | I - UU* | / ( n ulp )
!>
!> (5)     | D1 - D2 | / ( |D1| ulp )      where D1 is computed by
!>                                         DSBTRD with UPLO='U' and
!>                                         D2 is computed by
!>                                         CHETRD_HB2ST with UPLO='U'
!>
!> (6)     | D1 - D3 | / ( |D1| ulp )      where D1 is computed by
!>                                         DSBTRD with UPLO='U' and
!>                                         D3 is computed by
!>                                         CHETRD_HB2ST with UPLO='L'
!>
!> The  are specified by an array NN(1:NSIZES); the value of
!> each element NN(j) specifies one size.
!> The  are specified by a logical array DOTYPE( 1:NTYPES );
!> if DOTYPE(j) is .TRUE., then matrix type  will be generated.
!> Currently, the list of possible types is:
!>
!> (1)  The zero matrix.
!> (2)  The identity matrix.
!>
!> (3)  A diagonal matrix with evenly spaced entries
!>      1, ..., ULP  and random signs.
!>      (ULP = (first number larger than 1) - 1 )
!> (4)  A diagonal matrix with geometrically spaced entries
!>      1, ..., ULP  and random signs.
!> (5)  A diagonal matrix with  entries 1, ULP, ..., ULP
!>      and random signs.
!>
!> (6)  Same as (4), but multiplied by SQRT( overflow threshold )
!> (7)  Same as (4), but multiplied by SQRT( underflow threshold )
!>
!> (8)  A matrix of the form  U* D U, where U is unitary and
!>      D has evenly spaced entries 1, ..., ULP with random signs
!>      on the diagonal.
!>
!> (9)  A matrix of the form  U* D U, where U is unitary and
!>      D has geometrically spaced entries 1, ..., ULP with random
!>      signs on the diagonal.
!>
!> (10) A matrix of the form  U* D U, where U is unitary and
!>      D has  entries 1, ULP,..., ULP with random
!>      signs on the diagonal.
!>
!> (11) Same as (8), but multiplied by SQRT( overflow threshold )
!> (12) Same as (8), but multiplied by SQRT( underflow threshold )
!>
!> (13) Hermitian matrix with random entries chosen from (-1,1).
!> (14) Same as (13), but multiplied by SQRT( overflow threshold )
!> (15) Same as (13), but multiplied by SQRT( underflow threshold )
!> 

Parameters

[in]	NSIZES	!> NSIZES is INTEGER !> The number of sizes of matrices to use. If it is zero, !> CCHKHB2STG does nothing. It must be at least zero. !>
[in]	NN	!> NN is INTEGER array, dimension (NSIZES) !> An array containing the sizes to be used for the matrices. !> Zero values will be skipped. The values must be at least !> zero. !>
[in]	NWDTHS	!> NWDTHS is INTEGER !> The number of bandwidths to use. If it is zero, !> CCHKHB2STG does nothing. It must be at least zero. !>
[in]	KK	!> KK is INTEGER array, dimension (NWDTHS) !> An array containing the bandwidths to be used for the band !> matrices. The values must be at least zero. !>
[in]	NTYPES	!> NTYPES is INTEGER !> The number of elements in DOTYPE. If it is zero, CCHKHB2STG !> does nothing. It must be at least zero. If it is MAXTYP+1 !> and NSIZES is 1, then an additional type, MAXTYP+1 is !> defined, which is to use whatever matrix is in A. This !> is only useful if DOTYPE(1:MAXTYP) is .FALSE. and !> DOTYPE(MAXTYP+1) is .TRUE. . !>
[in]	DOTYPE	!> DOTYPE is LOGICAL array, dimension (NTYPES) !> If DOTYPE(j) is .TRUE., then for each size in NN a !> matrix of that size and of type j will be generated. !> If NTYPES is smaller than the maximum number of types !> defined (PARAMETER MAXTYP), then types NTYPES+1 through !> MAXTYP will not be generated. If NTYPES is larger !> than MAXTYP, DOTYPE(MAXTYP+1) through DOTYPE(NTYPES) !> will be ignored. !>
[in,out]	ISEED	!> ISEED is INTEGER array, dimension (4) !> On entry ISEED specifies the seed of the random number !> generator. The array elements should be between 0 and 4095; !> if not they will be reduced mod 4096. Also, ISEED(4) must !> be odd. The random number generator uses a linear !> congruential sequence limited to small integers, and so !> should produce machine independent random numbers. The !> values of ISEED are changed on exit, and can be used in the !> next call to CCHKHB2STG to continue the same random number !> sequence. !>
[in]	THRESH	!> THRESH is REAL !> A test will count as if the , computed as !> described above, exceeds THRESH. Note that the error !> is scaled to be O(1), so THRESH should be a reasonably !> small multiple of 1, e.g., 10 or 100. In particular, !> it should not depend on the precision (single vs. double) !> or the size of the matrix. It must be at least zero. !>
[in]	NOUNIT	!> NOUNIT is INTEGER !> The FORTRAN unit number for printing out error messages !> (e.g., if a routine returns IINFO not equal to 0.) !>
[in,out]	A	!> A is COMPLEX array, dimension !> (LDA, max(NN)) !> Used to hold the matrix whose eigenvalues are to be !> computed. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of A. It must be at least 2 (not 1!) !> and at least max( KK )+1. !>
[out]	SD	!> SD is REAL array, dimension (max(NN)) !> Used to hold the diagonal of the tridiagonal matrix computed !> by CHBTRD. !>
[out]	SE	!> SE is REAL array, dimension (max(NN)) !> Used to hold the off-diagonal of the tridiagonal matrix !> computed by CHBTRD. !>
[out]	D1	!> D1 is REAL array, dimension (max(NN)) !> Used store eigenvalues resulting from the tridiagonal !> form using the DSBTRD. !>
[out]	D2	!> D2 is REAL array, dimension (max(NN)) !>
[out]	D3	!> D3 is REAL array, dimension (max(NN)) !>
[out]	U	!> U is COMPLEX array, dimension (LDU, max(NN)) !> Used to hold the unitary matrix computed by CHBTRD. !>
[in]	LDU	!> LDU is INTEGER !> The leading dimension of U. It must be at least 1 !> and at least max( NN ). !>
[out]	WORK	!> WORK is COMPLEX array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The number of entries in WORK. This must be at least !> max( LDA+1, max(NN)+1 )*max(NN). !>
[out]	RWORK	!> RWORK is REAL array !>
[out]	RESULT	!> RESULT is REAL array, dimension (4) !> The values computed by the tests described above. !> The values are currently limited to 1/ulp, to avoid !> overflow. !>
[out]	INFO	!> INFO is INTEGER !> If 0, then everything ran OK. !> !>----------------------------------------------------------------------- !> !> Some Local Variables and Parameters: !> ---- ----- --------- --- ---------- !> ZERO, ONE Real 0 and 1. !> MAXTYP The number of types defined. !> NTEST The number of tests performed, or which can !> be performed so far, for the current matrix. !> NTESTT The total number of tests performed so far. !> NMAX Largest value in NN. !> NMATS The number of matrices generated so far. !> NERRS The number of tests which have exceeded THRESH !> so far. !> COND, IMODE Values to be passed to the matrix generators. !> ANORM Norm of A; passed to matrix generators. !> !> OVFL, UNFL Overflow and underflow thresholds. !> ULP, ULPINV Finest relative precision and its inverse. !> RTOVFL, RTUNFL Square roots of the previous 2 values. !> The following four arrays decode JTYPE: !> KTYPE(j) The general type (1-10) for type . !> KMODE(j) The MODE value to be passed to the matrix !> generator for type . !> KMAGN(j) The order of magnitude ( O(1), !> O(overflow^(1/2) ), O(underflow^(1/2) ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 337 of file cchkhb2stg.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDU, LWORK, NOUNIT, NSIZES, NTYPES,
     $                   NWDTHS
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            ISEED( 4 ), KK( * ), NN( * )
      REAL               RESULT( * ), RWORK( * ), SD( * ), SE( * ),
     $                   D1( * ), D2( * ), D3( * )
      COMPLEX            A( LDA, * ), U( LDU, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
      REAL               ZERO, ONE, TWO, TEN
      parameter( zero = 0.0e+0, one = 1.0e+0, two = 2.0e+0,
     $                   ten = 10.0e+0 )
      REAL               HALF
      parameter( half = one / two )
      INTEGER            MAXTYP
      parameter( maxtyp = 15 )
*     ..
*     .. Local Scalars ..
      LOGICAL            BADNN, BADNNB
      INTEGER            I, IINFO, IMODE, ITYPE, J, JC, JCOL, JR, JSIZE,
     $                   JTYPE, JWIDTH, K, KMAX, LH, LW, MTYPES, N,
     $                   NERRS, NMATS, NMAX, NTEST, NTESTT
      REAL               ANINV, ANORM, COND, OVFL, RTOVFL, RTUNFL,
     $                   TEMP1, TEMP2, TEMP3, TEMP4, ULP, ULPINV, UNFL
*     ..
*     .. Local Arrays ..
      INTEGER            IDUMMA( 1 ), IOLDSD( 4 ), KMAGN( MAXTYP ),
     $                   KMODE( MAXTYP ), KTYPE( MAXTYP )
*     ..
*     .. External Functions ..
      REAL               SLAMCH
      EXTERNAL           slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           slasum, xerbla, chbt21, chbtrd, clacpy, claset,
     $                   clatmr, clatms, chetrd_hb2st, csteqr
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, real, conjg, max, min, sqrt
*     ..
*     .. Data statements ..
      DATA               ktype / 1, 2, 5*4, 5*5, 3*8 /
      DATA               kmagn / 2*1, 1, 1, 1, 2, 3, 1, 1, 1, 2, 3, 1,
     $                   2, 3 /
      DATA               kmode / 2*0, 4, 3, 1, 4, 4, 4, 3, 1, 4, 4, 0,
     $                   0, 0 /
*     ..
*     .. Executable Statements ..
*
*     Check for errors
*
      ntestt = 0
      info = 0
*
*     Important constants
*
      badnn = .false.
      nmax = 1
      DO 10 j = 1, nsizes
         nmax = max( nmax, nn( j ) )
         IF( nn( j ).LT.0 )
     $      badnn = .true.
   10 CONTINUE
*
      badnnb = .false.
      kmax = 0
      DO 20 j = 1, nsizes
         kmax = max( kmax, kk( j ) )
         IF( kk( j ).LT.0 )
     $      badnnb = .true.
   20 CONTINUE
      kmax = min( nmax-1, kmax )
*
*     Check for errors
*
      IF( nsizes.LT.0 ) THEN
         info = -1
      ELSE IF( badnn ) THEN
         info = -2
      ELSE IF( nwdths.LT.0 ) THEN
         info = -3
      ELSE IF( badnnb ) THEN
         info = -4
      ELSE IF( ntypes.LT.0 ) THEN
         info = -5
      ELSE IF( lda.LT.kmax+1 ) THEN
         info = -11
      ELSE IF( ldu.LT.nmax ) THEN
         info = -15
      ELSE IF( ( max( lda, nmax )+1 )*nmax.GT.lwork ) THEN
         info = -17
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CCHKHB2STG', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( nsizes.EQ.0 .OR. ntypes.EQ.0 .OR. nwdths.EQ.0 )
     $   RETURN
*
*     More Important constants
*
      unfl = slamch( 'Safe minimum' )
      ovfl = one / unfl
      ulp = slamch( 'Epsilon' )*slamch( 'Base' )
      ulpinv = one / ulp
      rtunfl = sqrt( unfl )
      rtovfl = sqrt( ovfl )
*
*     Loop over sizes, types
*
      nerrs = 0
      nmats = 0
*
      DO 190 jsize = 1, nsizes
         n = nn( jsize )
         aninv = one / real( max( 1, n ) )
*
         DO 180 jwidth = 1, nwdths
            k = kk( jwidth )
            IF( k.GT.n )
     $         GO TO 180
            k = max( 0, min( n-1, k ) )
*
            IF( nsizes.NE.1 ) THEN
               mtypes = min( maxtyp, ntypes )
            ELSE
               mtypes = min( maxtyp+1, ntypes )
            END IF
*
            DO 170 jtype = 1, mtypes
               IF( .NOT.dotype( jtype ) )
     $            GO TO 170
               nmats = nmats + 1
               ntest = 0
*
               DO 30 j = 1, 4
                  ioldsd( j ) = iseed( j )
   30          CONTINUE
*
*              Compute "A".
*              Store as "Upper"; later, we will copy to other format.
*
*              Control parameters:
*
*                  KMAGN  KMODE        KTYPE
*              =1  O(1)   clustered 1  zero
*              =2  large  clustered 2  identity
*              =3  small  exponential  (none)
*              =4         arithmetic   diagonal, (w/ eigenvalues)
*              =5         random log   hermitian, w/ eigenvalues
*              =6         random       (none)
*              =7                      random diagonal
*              =8                      random hermitian
*              =9                      positive definite
*              =10                     diagonally dominant tridiagonal
*
               IF( mtypes.GT.maxtyp )
     $            GO TO 100
*
               itype = ktype( jtype )
               imode = kmode( jtype )
*
*              Compute norm
*
               GO TO ( 40, 50, 60 )kmagn( jtype )
*
   40          CONTINUE
               anorm = one
               GO TO 70
*
   50          CONTINUE
               anorm = ( rtovfl*ulp )*aninv
               GO TO 70
*
   60          CONTINUE
               anorm = rtunfl*n*ulpinv
               GO TO 70
*
   70          CONTINUE
*
               CALL claset( 'Full', lda, n, czero, czero, a, lda )
               iinfo = 0
               IF( jtype.LE.15 ) THEN
                  cond = ulpinv
               ELSE
                  cond = ulpinv*aninv / ten
               END IF
*
*              Special Matrices -- Identity & Jordan block
*
*                 Zero
*
               IF( itype.EQ.1 ) THEN
                  iinfo = 0
*
               ELSE IF( itype.EQ.2 ) THEN
*
*                 Identity
*
                  DO 80 jcol = 1, n
                     a( k+1, jcol ) = anorm
   80             CONTINUE
*
               ELSE IF( itype.EQ.4 ) THEN
*
*                 Diagonal Matrix, [Eigen]values Specified
*
                  CALL clatms( n, n, 'S', iseed, 'H', rwork, imode,
     $                         cond, anorm, 0, 0, 'Q', a( k+1, 1 ), lda,
     $                         work, iinfo )
*
               ELSE IF( itype.EQ.5 ) THEN
*
*                 Hermitian, eigenvalues specified
*
                  CALL clatms( n, n, 'S', iseed, 'H', rwork, imode,
     $                         cond, anorm, k, k, 'Q', a, lda, work,
     $                         iinfo )
*
               ELSE IF( itype.EQ.7 ) THEN
*
*                 Diagonal, random eigenvalues
*
                  CALL clatmr( n, n, 'S', iseed, 'H', work, 6, one,
     $                         cone, 'T', 'N', work( n+1 ), 1, one,
     $                         work( 2*n+1 ), 1, one, 'N', idumma, 0, 0,
     $                         zero, anorm, 'Q', a( k+1, 1 ), lda,
     $                         idumma, iinfo )
*
               ELSE IF( itype.EQ.8 ) THEN
*
*                 Hermitian, random eigenvalues
*
                  CALL clatmr( n, n, 'S', iseed, 'H', work, 6, one,
     $                         cone, 'T', 'N', work( n+1 ), 1, one,
     $                         work( 2*n+1 ), 1, one, 'N', idumma, k, k,
     $                         zero, anorm, 'Q', a, lda, idumma, iinfo )
*
               ELSE IF( itype.EQ.9 ) THEN
*
*                 Positive definite, eigenvalues specified.
*
                  CALL clatms( n, n, 'S', iseed, 'P', rwork, imode,
     $                         cond, anorm, k, k, 'Q', a, lda,
     $                         work( n+1 ), iinfo )
*
               ELSE IF( itype.EQ.10 ) THEN
*
*                 Positive definite tridiagonal, eigenvalues specified.
*
                  IF( n.GT.1 )
     $               k = max( 1, k )
                  CALL clatms( n, n, 'S', iseed, 'P', rwork, imode,
     $                         cond, anorm, 1, 1, 'Q', a( k, 1 ), lda,
     $                         work, iinfo )
                  DO 90 i = 2, n
                     temp1 = abs( a( k, i ) ) /
     $                       sqrt( abs( a( k+1, i-1 )*a( k+1, i ) ) )
                     IF( temp1.GT.half ) THEN
                        a( k, i ) = half*sqrt( abs( a( k+1,
     $                              i-1 )*a( k+1, i ) ) )
                     END IF
   90             CONTINUE
*
               ELSE
*
                  iinfo = 1
               END IF
*
               IF( iinfo.NE.0 ) THEN
                  WRITE( nounit, fmt = 9999 )'Generator', iinfo, n,
     $               jtype, ioldsd
                  info = abs( iinfo )
                  RETURN
               END IF
*
  100          CONTINUE
*
*              Call CHBTRD to compute S and U from upper triangle.
*
               CALL clacpy( ' ', k+1, n, a, lda, work, lda )
*
               ntest = 1
               CALL chbtrd( 'V', 'U', n, k, work, lda, sd, se, u, ldu,
     $                      work( lda*n+1 ), iinfo )
*
               IF( iinfo.NE.0 ) THEN
                  WRITE( nounit, fmt = 9999 )'CHBTRD(U)', iinfo, n,
     $               jtype, ioldsd
                  info = abs( iinfo )
                  IF( iinfo.LT.0 ) THEN
                     RETURN
                  ELSE
                     result( 1 ) = ulpinv
                     GO TO 150
                  END IF
               END IF
*
*              Do tests 1 and 2
*
               CALL chbt21( 'Upper', n, k, 1, a, lda, sd, se, u, ldu,
     $                      work, rwork, result( 1 ) )
*
*              Before converting A into lower for DSBTRD, run DSYTRD_SB2ST
*              otherwise matrix A will be converted to lower and then need
*              to be converted back to upper in order to run the upper case
*              ofDSYTRD_SB2ST
*
*              Compute D1 the eigenvalues resulting from the tridiagonal
*              form using the DSBTRD and used as reference to compare
*              with the DSYTRD_SB2ST routine
*
*              Compute D1 from the DSBTRD and used as reference for the
*              DSYTRD_SB2ST
*
               CALL scopy( n, sd, 1, d1, 1 )
               IF( n.GT.0 )
     $            CALL scopy( n-1, se, 1, rwork, 1 )
*
               CALL csteqr( 'N', n, d1, rwork, work, ldu,
     $                      rwork( n+1 ), iinfo )
               IF( iinfo.NE.0 ) THEN
                  WRITE( nounit, fmt = 9999 )'CSTEQR(N)', iinfo, n,
     $               jtype, ioldsd
                  info = abs( iinfo )
                  IF( iinfo.LT.0 ) THEN
                     RETURN
                  ELSE
                     result( 5 ) = ulpinv
                     GO TO 150
                  END IF
               END IF
*
*              DSYTRD_SB2ST Upper case is used to compute D2.
*              Note to set SD and SE to zero to be sure not reusing
*              the one from above. Compare it with D1 computed
*              using the DSBTRD.
*
               CALL slaset( 'Full', n, 1, zero, zero, sd, n )
               CALL slaset( 'Full', n, 1, zero, zero, se, n )
               CALL clacpy( ' ', k+1, n, a, lda, u, ldu )
               lh = max(1, 4*n)
               lw = lwork - lh
               CALL chetrd_hb2st( 'N', 'N', "U", n, k, u, ldu, sd, se,
     $                      work, lh, work( lh+1 ), lw, iinfo )
*
*              Compute D2 from the DSYTRD_SB2ST Upper case
*
               CALL scopy( n, sd, 1, d2, 1 )
               IF( n.GT.0 )
     $            CALL scopy( n-1, se, 1, rwork, 1 )
*
               CALL csteqr( 'N', n, d2, rwork, work, ldu,
     $                      rwork( n+1 ), iinfo )
               IF( iinfo.NE.0 ) THEN
                  WRITE( nounit, fmt = 9999 )'CSTEQR(N)', iinfo, n,
     $               jtype, ioldsd
                  info = abs( iinfo )
                  IF( iinfo.LT.0 ) THEN
                     RETURN
                  ELSE
                     result( 5 ) = ulpinv
                     GO TO 150
                  END IF
               END IF
*
*              Convert A from Upper-Triangle-Only storage to
*              Lower-Triangle-Only storage.
*
               DO 120 jc = 1, n
                  DO 110 jr = 0, min( k, n-jc )
                     a( jr+1, jc ) = conjg( a( k+1-jr, jc+jr ) )
  110             CONTINUE
  120          CONTINUE
               DO 140 jc = n + 1 - k, n
                  DO 130 jr = min( k, n-jc ) + 1, k
                     a( jr+1, jc ) = zero
  130             CONTINUE
  140          CONTINUE
*
*              Call CHBTRD to compute S and U from lower triangle
*
               CALL clacpy( ' ', k+1, n, a, lda, work, lda )
*
               ntest = 3
               CALL chbtrd( 'V', 'L', n, k, work, lda, sd, se, u, ldu,
     $                      work( lda*n+1 ), iinfo )
*
               IF( iinfo.NE.0 ) THEN
                  WRITE( nounit, fmt = 9999 )'CHBTRD(L)', iinfo, n,
     $               jtype, ioldsd
                  info = abs( iinfo )
                  IF( iinfo.LT.0 ) THEN
                     RETURN
                  ELSE
                     result( 3 ) = ulpinv
                     GO TO 150
                  END IF
               END IF
               ntest = 4
*
*              Do tests 3 and 4
*
               CALL chbt21( 'Lower', n, k, 1, a, lda, sd, se, u, ldu,
     $                      work, rwork, result( 3 ) )
*
*              DSYTRD_SB2ST Lower case is used to compute D3.
*              Note to set SD and SE to zero to be sure not reusing
*              the one from above. Compare it with D1 computed
*              using the DSBTRD.
*
               CALL slaset( 'Full', n, 1, zero, zero, sd, n )
               CALL slaset( 'Full', n, 1, zero, zero, se, n )
               CALL clacpy( ' ', k+1, n, a, lda, u, ldu )
               lh = max(1, 4*n)
               lw = lwork - lh
               CALL chetrd_hb2st( 'N', 'N', "L", n, k, u, ldu, sd, se,
     $                      work, lh, work( lh+1 ), lw, iinfo )
*
*              Compute D3 from the 2-stage Upper case
*
               CALL scopy( n, sd, 1, d3, 1 )
               IF( n.GT.0 )
     $            CALL scopy( n-1, se, 1, rwork, 1 )
*
               CALL csteqr( 'N', n, d3, rwork, work, ldu,
     $                      rwork( n+1 ), iinfo )
               IF( iinfo.NE.0 ) THEN
                  WRITE( nounit, fmt = 9999 )'CSTEQR(N)', iinfo, n,
     $               jtype, ioldsd
                  info = abs( iinfo )
                  IF( iinfo.LT.0 ) THEN
                     RETURN
                  ELSE
                     result( 6 ) = ulpinv
                     GO TO 150
                  END IF
               END IF
*
*
*              Do Tests 3 and 4 which are similar to 11 and 12 but with the
*              D1 computed using the standard 1-stage reduction as reference
*
               ntest = 6
               temp1 = zero
               temp2 = zero
               temp3 = zero
               temp4 = zero
*
               DO 151 j = 1, n
                  temp1 = max( temp1, abs( d1( j ) ), abs( d2( j ) ) )
                  temp2 = max( temp2, abs( d1( j )-d2( j ) ) )
                  temp3 = max( temp3, abs( d1( j ) ), abs( d3( j ) ) )
                  temp4 = max( temp4, abs( d1( j )-d3( j ) ) )
  151          CONTINUE
*
               result(5) = temp2 / max( unfl, ulp*max( temp1, temp2 ) )
               result(6) = temp4 / max( unfl, ulp*max( temp3, temp4 ) )
*
*              End of Loop -- Check for RESULT(j) > THRESH
*
  150          CONTINUE
               ntestt = ntestt + ntest
*
*              Print out tests which fail.
*
               DO 160 jr = 1, ntest
                  IF( result( jr ).GE.thresh ) THEN
*
*                    If this is the first test to fail,
*                    print a header to the data file.
*
                     IF( nerrs.EQ.0 ) THEN
                        WRITE( nounit, fmt = 9998 )'CHB'
                        WRITE( nounit, fmt = 9997 )
                        WRITE( nounit, fmt = 9996 )
                        WRITE( nounit, fmt = 9995 )'Hermitian'
                        WRITE( nounit, fmt = 9994 )'unitary', '*',
     $                     'conjugate transpose', ( '*', j = 1, 6 )
                     END IF
                     nerrs = nerrs + 1
                     WRITE( nounit, fmt = 9993 )n, k, ioldsd, jtype,
     $                  jr, result( jr )
                  END IF
  160          CONTINUE
*
  170       CONTINUE
  180    CONTINUE
  190 CONTINUE
*
*     Summary
*
      CALL slasum( 'CHB', nounit, nerrs, ntestt )
      RETURN
*
 9999 FORMAT( ' CCHKHB2STG: ', a, ' returned INFO=', i6, '.', / 9x,
     $      'N=', i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ), i5,
     $      ')' )
 9998 FORMAT( / 1x, a3,
     $     ' -- Complex Hermitian Banded Tridiagonal Reduction Routines'
     $       )
 9997 FORMAT( ' Matrix types (see SCHK23 for details): ' )
*
 9996 FORMAT( / ' Special Matrices:',
     $      / '  1=Zero matrix.                        ',
     $      '  5=Diagonal: clustered entries.',
     $      / '  2=Identity matrix.                    ',
     $      '  6=Diagonal: large, evenly spaced.',
     $      / '  3=Diagonal: evenly spaced entries.    ',
     $      '  7=Diagonal: small, evenly spaced.',
     $      / '  4=Diagonal: geometr. spaced entries.' )
 9995 FORMAT( ' Dense ', a, ' Banded Matrices:',
     $      / '  8=Evenly spaced eigenvals.            ',
     $      ' 12=Small, evenly spaced eigenvals.',
     $      / '  9=Geometrically spaced eigenvals.     ',
     $      ' 13=Matrix with random O(1) entries.',
     $      / ' 10=Clustered eigenvalues.              ',
     $      ' 14=Matrix with large random entries.',
     $      / ' 11=Large, evenly spaced eigenvals.     ',
     $      ' 15=Matrix with small random entries.' )
*
 9994 FORMAT( / ' Tests performed:   (S is Tridiag,  U is ', a, ',',
     $      / 20x, a, ' means ', a, '.', / ' UPLO=''U'':',
     $      / '  1= | A - U S U', a1, ' | / ( |A| n ulp )     ',
     $      '  2= | I - U U', a1, ' | / ( n ulp )', / ' UPLO=''L'':',
     $      / '  3= | A - U S U', a1, ' | / ( |A| n ulp )     ',
     $      '  4= | I - U U', a1, ' | / ( n ulp )' / ' Eig check:',
     $      /'  5= | D1 - D2', '', ' | / ( |D1| ulp )         ',
     $      '  6= | D1 - D3', '', ' | / ( |D1| ulp )          ' )
 9993 FORMAT( ' N=', i5, ', K=', i4, ', seed=', 4( i4, ',' ), ' type ',
     $      i2, ', test(', i2, ')=', g10.3 )
*
*     End of CCHKHB2STG
*

Here is the call graph for this function:

Here is the caller graph for this function: