schkbl.f

Go to the documentation of this file.

*> \brief \b SCHKBL
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE SCHKBL( NIN, NOUT )
*
*       .. Scalar Arguments ..
*       INTEGER            NIN, NOUT
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SCHKBL tests SGEBAL, a routine for balancing a general real
*> matrix and isolating some of its eigenvalues.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] NIN
*> \verbatim
*>          NIN is INTEGER
*>          The logical unit number for input.  NIN > 0.
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The logical unit number for output.  NOUT > 0.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup single_eig
*
*  =====================================================================
      SUBROUTINE schkbl( NIN, NOUT )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            NIN, NOUT
*     ..
*
* ======================================================================
*
*     .. Parameters ..
      INTEGER            LDA
      parameter( lda = 20 )
      REAL               ZERO
      parameter( zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IHI, IHIIN, ILO, ILOIN, INFO, J, KNT, N,
     $                   NINFO
      REAL               ANORM, MEPS, RMAX, SFMIN, TEMP, VMAX
*     ..
*     .. Local Arrays ..
      INTEGER            LMAX( 3 )
      REAL               A( LDA, LDA ), AIN( LDA, LDA ), DUMMY( 1 ),
     $                   SCALE( LDA ), SCALIN( LDA )
*     ..
*     .. External Functions ..
      REAL               SLAMCH, SLANGE
      EXTERNAL           slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgebal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Executable Statements ..
*
      lmax( 1 ) = 0
      lmax( 2 ) = 0
      lmax( 3 ) = 0
      ninfo = 0
      knt = 0
      rmax = zero
      vmax = zero
      sfmin = slamch( 'S' )
      meps = slamch( 'E' )
*
   10 CONTINUE
*
      READ( nin, fmt = * )n
      IF( n.EQ.0 )
     $   GO TO 70
      DO 20 i = 1, n
         READ( nin, fmt = * )( a( i, j ), j = 1, n )
   20 CONTINUE
*
      READ( nin, fmt = * )iloin, ihiin
      DO 30 i = 1, n
         READ( nin, fmt = * )( ain( i, j ), j = 1, n )
   30 CONTINUE
      READ( nin, fmt = * )( scalin( i ), i = 1, n )
*
      anorm = slange( 'M', n, n, a, lda, dummy )
      knt = knt + 1
*
      CALL sgebal( 'B', n, a, lda, ilo, ihi, scale, info )
*
      IF( info.NE.0 ) THEN
         ninfo = ninfo + 1
         lmax( 1 ) = knt
      END IF
*
      IF( ilo.NE.iloin .OR. ihi.NE.ihiin ) THEN
         ninfo = ninfo + 1
         lmax( 2 ) = knt
      END IF
*
      DO 50 i = 1, n
         DO 40 j = 1, n
            temp = max( a( i, j ), ain( i, j ) )
            temp = max( temp, sfmin )
            vmax = max( vmax, abs( a( i, j )-ain( i, j ) ) / temp )
   40    CONTINUE
   50 CONTINUE
*
      DO 60 i = 1, n
         temp = max( scale( i ), scalin( i ) )
         temp = max( temp, sfmin )
         vmax = max( vmax, abs( scale( i )-scalin( i ) ) / temp )
   60 CONTINUE
*
*
      IF( vmax.GT.rmax ) THEN
         lmax( 3 ) = knt
         rmax = vmax
      END IF
*
      GO TO 10
*
   70 CONTINUE
*
      WRITE( nout, fmt = 9999 )
 9999 FORMAT( 1x, '.. test output of SGEBAL .. ' )
*
      WRITE( nout, fmt = 9998 )rmax
 9998 FORMAT( 1x, 'value of largest test error            = ', e12.3 )
      WRITE( nout, fmt = 9997 )lmax( 1 )
 9997 FORMAT( 1x, 'example number where info is not zero  = ', i4 )
      WRITE( nout, fmt = 9996 )lmax( 2 )
 9996 FORMAT( 1x, 'example number where ILO or IHI wrong  = ', i4 )
      WRITE( nout, fmt = 9995 )lmax( 3 )
 9995 FORMAT( 1x, 'example number having largest error    = ', i4 )
      WRITE( nout, fmt = 9994 )ninfo
 9994 FORMAT( 1x, 'number of examples where info is not 0 = ', i4 )
      WRITE( nout, fmt = 9993 )knt
 9993 FORMAT( 1x, 'total number of examples tested        = ', i4 )
*
      RETURN
*
*     End of SCHKBL
*
      END