LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
dtbsv.f
Go to the documentation of this file.
1*> \brief \b DTBSV
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* SUBROUTINE DTBSV(UPLO,TRANS,DIAG,N,K,A,LDA,X,INCX)
12*
13* .. Scalar Arguments ..
14* INTEGER INCX,K,LDA,N
15* CHARACTER DIAG,TRANS,UPLO
16* ..
17* .. Array Arguments ..
18* DOUBLE PRECISION A(LDA,*),X(*)
19* ..
20*
21*
22*> \par Purpose:
23* =============
24*>
25*> \verbatim
26*>
27*> DTBSV solves one of the systems of equations
28*>
29*> A*x = b, or A**T*x = b,
30*>
31*> where b and x are n element vectors and A is an n by n unit, or
32*> non-unit, upper or lower triangular band matrix, with ( k + 1 )
33*> diagonals.
34*>
35*> No test for singularity or near-singularity is included in this
36*> routine. Such tests must be performed before calling this routine.
37*> \endverbatim
38*
39* Arguments:
40* ==========
41*
42*> \param[in] UPLO
43*> \verbatim
44*> UPLO is CHARACTER*1
45*> On entry, UPLO specifies whether the matrix is an upper or
46*> lower triangular matrix as follows:
47*>
48*> UPLO = 'U' or 'u' A is an upper triangular matrix.
49*>
50*> UPLO = 'L' or 'l' A is a lower triangular matrix.
51*> \endverbatim
52*>
53*> \param[in] TRANS
54*> \verbatim
55*> TRANS is CHARACTER*1
56*> On entry, TRANS specifies the equations to be solved as
57*> follows:
58*>
59*> TRANS = 'N' or 'n' A*x = b.
60*>
61*> TRANS = 'T' or 't' A**T*x = b.
62*>
63*> TRANS = 'C' or 'c' A**T*x = b.
64*> \endverbatim
65*>
66*> \param[in] DIAG
67*> \verbatim
68*> DIAG is CHARACTER*1
69*> On entry, DIAG specifies whether or not A is unit
70*> triangular as follows:
71*>
72*> DIAG = 'U' or 'u' A is assumed to be unit triangular.
73*>
74*> DIAG = 'N' or 'n' A is not assumed to be unit
75*> triangular.
76*> \endverbatim
77*>
78*> \param[in] N
79*> \verbatim
80*> N is INTEGER
81*> On entry, N specifies the order of the matrix A.
82*> N must be at least zero.
83*> \endverbatim
84*>
85*> \param[in] K
86*> \verbatim
87*> K is INTEGER
88*> On entry with UPLO = 'U' or 'u', K specifies the number of
89*> super-diagonals of the matrix A.
90*> On entry with UPLO = 'L' or 'l', K specifies the number of
91*> sub-diagonals of the matrix A.
92*> K must satisfy 0 .le. K.
93*> \endverbatim
94*>
95*> \param[in] A
96*> \verbatim
97*> A is DOUBLE PRECISION array, dimension ( LDA, N )
98*> Before entry with UPLO = 'U' or 'u', the leading ( k + 1 )
99*> by n part of the array A must contain the upper triangular
100*> band part of the matrix of coefficients, supplied column by
101*> column, with the leading diagonal of the matrix in row
102*> ( k + 1 ) of the array, the first super-diagonal starting at
103*> position 2 in row k, and so on. The top left k by k triangle
104*> of the array A is not referenced.
105*> The following program segment will transfer an upper
106*> triangular band matrix from conventional full matrix storage
107*> to band storage:
108*>
109*> DO 20, J = 1, N
110*> M = K + 1 - J
111*> DO 10, I = MAX( 1, J - K ), J
112*> A( M + I, J ) = matrix( I, J )
113*> 10 CONTINUE
114*> 20 CONTINUE
115*>
116*> Before entry with UPLO = 'L' or 'l', the leading ( k + 1 )
117*> by n part of the array A must contain the lower triangular
118*> band part of the matrix of coefficients, supplied column by
119*> column, with the leading diagonal of the matrix in row 1 of
120*> the array, the first sub-diagonal starting at position 1 in
121*> row 2, and so on. The bottom right k by k triangle of the
122*> array A is not referenced.
123*> The following program segment will transfer a lower
124*> triangular band matrix from conventional full matrix storage
125*> to band storage:
126*>
127*> DO 20, J = 1, N
128*> M = 1 - J
129*> DO 10, I = J, MIN( N, J + K )
130*> A( M + I, J ) = matrix( I, J )
131*> 10 CONTINUE
132*> 20 CONTINUE
133*>
134*> Note that when DIAG = 'U' or 'u' the elements of the array A
135*> corresponding to the diagonal elements of the matrix are not
136*> referenced, but are assumed to be unity.
137*> \endverbatim
138*>
139*> \param[in] LDA
140*> \verbatim
141*> LDA is INTEGER
142*> On entry, LDA specifies the first dimension of A as declared
143*> in the calling (sub) program. LDA must be at least
144*> ( k + 1 ).
145*> \endverbatim
146*>
147*> \param[in,out] X
148*> \verbatim
149*> X is DOUBLE PRECISION array, dimension at least
150*> ( 1 + ( n - 1 )*abs( INCX ) ).
151*> Before entry, the incremented array X must contain the n
152*> element right-hand side vector b. On exit, X is overwritten
153*> with the solution vector x.
154*> \endverbatim
155*>
156*> \param[in] INCX
157*> \verbatim
158*> INCX is INTEGER
159*> On entry, INCX specifies the increment for the elements of
160*> X. INCX must not be zero.
161*> \endverbatim
162*
163* Authors:
164* ========
165*
166*> \author Univ. of Tennessee
167*> \author Univ. of California Berkeley
168*> \author Univ. of Colorado Denver
169*> \author NAG Ltd.
170*
171*> \ingroup tbsv
172*
173*> \par Further Details:
174* =====================
175*>
176*> \verbatim
177*>
178*> Level 2 Blas routine.
179*>
180*> -- Written on 22-October-1986.
181*> Jack Dongarra, Argonne National Lab.
182*> Jeremy Du Croz, Nag Central Office.
183*> Sven Hammarling, Nag Central Office.
184*> Richard Hanson, Sandia National Labs.
185*> \endverbatim
186*>
187* =====================================================================
188 SUBROUTINE dtbsv(UPLO,TRANS,DIAG,N,K,A,LDA,X,INCX)
189*
190* -- Reference BLAS level2 routine --
191* -- Reference BLAS is a software package provided by Univ. of Tennessee, --
192* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
193*
194* .. Scalar Arguments ..
195 INTEGER INCX,K,LDA,N
196 CHARACTER DIAG,TRANS,UPLO
197* ..
198* .. Array Arguments ..
199 DOUBLE PRECISION A(LDA,*),X(*)
200* ..
201*
202* =====================================================================
203*
204* .. Parameters ..
205 DOUBLE PRECISION ZERO
206 parameter(zero=0.0d+0)
207* ..
208* .. Local Scalars ..
209 DOUBLE PRECISION TEMP
210 INTEGER I,INFO,IX,J,JX,KPLUS1,KX,L
211 LOGICAL NOUNIT
212* ..
213* .. External Functions ..
214 LOGICAL LSAME
215 EXTERNAL lsame
216* ..
217* .. External Subroutines ..
218 EXTERNAL xerbla
219* ..
220* .. Intrinsic Functions ..
221 INTRINSIC max,min
222* ..
223*
224* Test the input parameters.
225*
226 info = 0
227 IF (.NOT.lsame(uplo,'U') .AND. .NOT.lsame(uplo,'L')) THEN
228 info = 1
229 ELSE IF (.NOT.lsame(trans,'N') .AND.
230 + .NOT.lsame(trans,'T') .AND.
231 + .NOT.lsame(trans,'C')) THEN
232 info = 2
233 ELSE IF (.NOT.lsame(diag,'U') .AND.
234 + .NOT.lsame(diag,'N')) THEN
235 info = 3
236 ELSE IF (n.LT.0) THEN
237 info = 4
238 ELSE IF (k.LT.0) THEN
239 info = 5
240 ELSE IF (lda.LT. (k+1)) THEN
241 info = 7
242 ELSE IF (incx.EQ.0) THEN
243 info = 9
244 END IF
245 IF (info.NE.0) THEN
246 CALL xerbla('DTBSV ',info)
247 RETURN
248 END IF
249*
250* Quick return if possible.
251*
252 IF (n.EQ.0) RETURN
253*
254 nounit = lsame(diag,'N')
255*
256* Set up the start point in X if the increment is not unity. This
257* will be ( N - 1 )*INCX too small for descending loops.
258*
259 IF (incx.LE.0) THEN
260 kx = 1 - (n-1)*incx
261 ELSE IF (incx.NE.1) THEN
262 kx = 1
263 END IF
264*
265* Start the operations. In this version the elements of A are
266* accessed by sequentially with one pass through A.
267*
268 IF (lsame(trans,'N')) THEN
269*
270* Form x := inv( A )*x.
271*
272 IF (lsame(uplo,'U')) THEN
273 kplus1 = k + 1
274 IF (incx.EQ.1) THEN
275 DO 20 j = n,1,-1
276 IF (x(j).NE.zero) THEN
277 l = kplus1 - j
278 IF (nounit) x(j) = x(j)/a(kplus1,j)
279 temp = x(j)
280 DO 10 i = j - 1,max(1,j-k),-1
281 x(i) = x(i) - temp*a(l+i,j)
282 10 CONTINUE
283 END IF
284 20 CONTINUE
285 ELSE
286 kx = kx + (n-1)*incx
287 jx = kx
288 DO 40 j = n,1,-1
289 kx = kx - incx
290 IF (x(jx).NE.zero) THEN
291 ix = kx
292 l = kplus1 - j
293 IF (nounit) x(jx) = x(jx)/a(kplus1,j)
294 temp = x(jx)
295 DO 30 i = j - 1,max(1,j-k),-1
296 x(ix) = x(ix) - temp*a(l+i,j)
297 ix = ix - incx
298 30 CONTINUE
299 END IF
300 jx = jx - incx
301 40 CONTINUE
302 END IF
303 ELSE
304 IF (incx.EQ.1) THEN
305 DO 60 j = 1,n
306 IF (x(j).NE.zero) THEN
307 l = 1 - j
308 IF (nounit) x(j) = x(j)/a(1,j)
309 temp = x(j)
310 DO 50 i = j + 1,min(n,j+k)
311 x(i) = x(i) - temp*a(l+i,j)
312 50 CONTINUE
313 END IF
314 60 CONTINUE
315 ELSE
316 jx = kx
317 DO 80 j = 1,n
318 kx = kx + incx
319 IF (x(jx).NE.zero) THEN
320 ix = kx
321 l = 1 - j
322 IF (nounit) x(jx) = x(jx)/a(1,j)
323 temp = x(jx)
324 DO 70 i = j + 1,min(n,j+k)
325 x(ix) = x(ix) - temp*a(l+i,j)
326 ix = ix + incx
327 70 CONTINUE
328 END IF
329 jx = jx + incx
330 80 CONTINUE
331 END IF
332 END IF
333 ELSE
334*
335* Form x := inv( A**T)*x.
336*
337 IF (lsame(uplo,'U')) THEN
338 kplus1 = k + 1
339 IF (incx.EQ.1) THEN
340 DO 100 j = 1,n
341 temp = x(j)
342 l = kplus1 - j
343 DO 90 i = max(1,j-k),j - 1
344 temp = temp - a(l+i,j)*x(i)
345 90 CONTINUE
346 IF (nounit) temp = temp/a(kplus1,j)
347 x(j) = temp
348 100 CONTINUE
349 ELSE
350 jx = kx
351 DO 120 j = 1,n
352 temp = x(jx)
353 ix = kx
354 l = kplus1 - j
355 DO 110 i = max(1,j-k),j - 1
356 temp = temp - a(l+i,j)*x(ix)
357 ix = ix + incx
358 110 CONTINUE
359 IF (nounit) temp = temp/a(kplus1,j)
360 x(jx) = temp
361 jx = jx + incx
362 IF (j.GT.k) kx = kx + incx
363 120 CONTINUE
364 END IF
365 ELSE
366 IF (incx.EQ.1) THEN
367 DO 140 j = n,1,-1
368 temp = x(j)
369 l = 1 - j
370 DO 130 i = min(n,j+k),j + 1,-1
371 temp = temp - a(l+i,j)*x(i)
372 130 CONTINUE
373 IF (nounit) temp = temp/a(1,j)
374 x(j) = temp
375 140 CONTINUE
376 ELSE
377 kx = kx + (n-1)*incx
378 jx = kx
379 DO 160 j = n,1,-1
380 temp = x(jx)
381 ix = kx
382 l = 1 - j
383 DO 150 i = min(n,j+k),j + 1,-1
384 temp = temp - a(l+i,j)*x(ix)
385 ix = ix - incx
386 150 CONTINUE
387 IF (nounit) temp = temp/a(1,j)
388 x(jx) = temp
389 jx = jx - incx
390 IF ((n-j).GE.k) kx = kx - incx
391 160 CONTINUE
392 END IF
393 END IF
394 END IF
395*
396 RETURN
397*
398* End of DTBSV
399*
400 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine dtbsv(uplo, trans, diag, n, k, a, lda, x, incx)
DTBSV
Definition dtbsv.f:189