LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ clanhp()

real function clanhp ( character  NORM,
character  UPLO,
integer  N,
complex, dimension( * )  AP,
real, dimension( * )  WORK 
)

CLANHP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix supplied in packed form.

Download CLANHP + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CLANHP  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the  element of  largest absolute value  of a
 complex hermitian matrix A,  supplied in packed form.
Returns
CLANHP
    CLANHP = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in CLANHP as described
          above.
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the upper or lower triangular part of the
          hermitian matrix A is supplied.
          = 'U':  Upper triangular part of A is supplied
          = 'L':  Lower triangular part of A is supplied
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.  When N = 0, CLANHP is
          set to zero.
[in]AP
          AP is COMPLEX array, dimension (N*(N+1)/2)
          The upper or lower triangle of the hermitian matrix A, packed
          columnwise in a linear array.  The j-th column of A is stored
          in the array AP as follows:
          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
          Note that the  imaginary parts of the diagonal elements need
          not be set and are assumed to be zero.
[out]WORK
          WORK is REAL array, dimension (MAX(1,LWORK)),
          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
          WORK is not referenced.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 116 of file clanhp.f.

117 *
118 * -- LAPACK auxiliary routine --
119 * -- LAPACK is a software package provided by Univ. of Tennessee, --
120 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
121 *
122  IMPLICIT NONE
123 * .. Scalar Arguments ..
124  CHARACTER NORM, UPLO
125  INTEGER N
126 * ..
127 * .. Array Arguments ..
128  REAL WORK( * )
129  COMPLEX AP( * )
130 * ..
131 *
132 * =====================================================================
133 *
134 * .. Parameters ..
135  REAL ONE, ZERO
136  parameter( one = 1.0e+0, zero = 0.0e+0 )
137 * ..
138 * .. Local Scalars ..
139  INTEGER I, J, K
140  REAL ABSA, SUM, VALUE
141 * ..
142 * .. Local Arrays ..
143  REAL SSQ( 2 ), COLSSQ( 2 )
144 * ..
145 * .. External Functions ..
146  LOGICAL LSAME, SISNAN
147  EXTERNAL lsame, sisnan
148 * ..
149 * .. External Subroutines ..
150  EXTERNAL classq, scombssq
151 * ..
152 * .. Intrinsic Functions ..
153  INTRINSIC abs, real, sqrt
154 * ..
155 * .. Executable Statements ..
156 *
157  IF( n.EQ.0 ) THEN
158  VALUE = zero
159  ELSE IF( lsame( norm, 'M' ) ) THEN
160 *
161 * Find max(abs(A(i,j))).
162 *
163  VALUE = zero
164  IF( lsame( uplo, 'U' ) ) THEN
165  k = 0
166  DO 20 j = 1, n
167  DO 10 i = k + 1, k + j - 1
168  sum = abs( ap( i ) )
169  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
170  10 CONTINUE
171  k = k + j
172  sum = abs( real( ap( k ) ) )
173  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
174  20 CONTINUE
175  ELSE
176  k = 1
177  DO 40 j = 1, n
178  sum = abs( real( ap( k ) ) )
179  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
180  DO 30 i = k + 1, k + n - j
181  sum = abs( ap( i ) )
182  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
183  30 CONTINUE
184  k = k + n - j + 1
185  40 CONTINUE
186  END IF
187  ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
188  $ ( norm.EQ.'1' ) ) THEN
189 *
190 * Find normI(A) ( = norm1(A), since A is hermitian).
191 *
192  VALUE = zero
193  k = 1
194  IF( lsame( uplo, 'U' ) ) THEN
195  DO 60 j = 1, n
196  sum = zero
197  DO 50 i = 1, j - 1
198  absa = abs( ap( k ) )
199  sum = sum + absa
200  work( i ) = work( i ) + absa
201  k = k + 1
202  50 CONTINUE
203  work( j ) = sum + abs( real( ap( k ) ) )
204  k = k + 1
205  60 CONTINUE
206  DO 70 i = 1, n
207  sum = work( i )
208  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
209  70 CONTINUE
210  ELSE
211  DO 80 i = 1, n
212  work( i ) = zero
213  80 CONTINUE
214  DO 100 j = 1, n
215  sum = work( j ) + abs( real( ap( k ) ) )
216  k = k + 1
217  DO 90 i = j + 1, n
218  absa = abs( ap( k ) )
219  sum = sum + absa
220  work( i ) = work( i ) + absa
221  k = k + 1
222  90 CONTINUE
223  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
224  100 CONTINUE
225  END IF
226  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
227 *
228 * Find normF(A).
229 * SSQ(1) is scale
230 * SSQ(2) is sum-of-squares
231 * For better accuracy, sum each column separately.
232 *
233  ssq( 1 ) = zero
234  ssq( 2 ) = one
235 *
236 * Sum off-diagonals
237 *
238  k = 2
239  IF( lsame( uplo, 'U' ) ) THEN
240  DO 110 j = 2, n
241  colssq( 1 ) = zero
242  colssq( 2 ) = one
243  CALL classq( j-1, ap( k ), 1, colssq( 1 ), colssq( 2 ) )
244  CALL scombssq( ssq, colssq )
245  k = k + j
246  110 CONTINUE
247  ELSE
248  DO 120 j = 1, n - 1
249  colssq( 1 ) = zero
250  colssq( 2 ) = one
251  CALL classq( n-j, ap( k ), 1, colssq( 1 ), colssq( 2 ) )
252  CALL scombssq( ssq, colssq )
253  k = k + n - j + 1
254  120 CONTINUE
255  END IF
256  ssq( 2 ) = 2*ssq( 2 )
257 *
258 * Sum diagonal
259 *
260  k = 1
261  colssq( 1 ) = zero
262  colssq( 2 ) = one
263  DO 130 i = 1, n
264  IF( real( ap( k ) ).NE.zero ) THEN
265  absa = abs( real( ap( k ) ) )
266  IF( colssq( 1 ).LT.absa ) THEN
267  colssq( 2 ) = one + colssq(2)*( colssq(1) / absa )**2
268  colssq( 1 ) = absa
269  ELSE
270  colssq( 2 ) = colssq( 2 ) + ( absa / colssq( 1 ) )**2
271  END IF
272  END IF
273  IF( lsame( uplo, 'U' ) ) THEN
274  k = k + i + 1
275  ELSE
276  k = k + n - i + 1
277  END IF
278  130 CONTINUE
279  CALL scombssq( ssq, colssq )
280  VALUE = ssq( 1 )*sqrt( ssq( 2 ) )
281  END IF
282 *
283  clanhp = VALUE
284  RETURN
285 *
286 * End of CLANHP
287 *
subroutine scombssq(V1, V2)
SCOMBSSQ adds two scaled sum of squares quantities
Definition: scombssq.f:60
subroutine classq(n, x, incx, scl, sumsq)
CLASSQ updates a sum of squares represented in scaled form.
Definition: classq.f90:126
logical function sisnan(SIN)
SISNAN tests input for NaN.
Definition: sisnan.f:59
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
real function clanhp(NORM, UPLO, N, AP, WORK)
CLANHP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: clanhp.f:117
Here is the call graph for this function: