LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ clarf()

subroutine clarf ( character  SIDE,
integer  M,
integer  N,
complex, dimension( * )  V,
integer  INCV,
complex  TAU,
complex, dimension( ldc, * )  C,
integer  LDC,
complex, dimension( * )  WORK 
)

CLARF applies an elementary reflector to a general rectangular matrix.

Download CLARF + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CLARF applies a complex elementary reflector H to a complex M-by-N
 matrix C, from either the left or the right. H is represented in the
 form

       H = I - tau * v * v**H

 where tau is a complex scalar and v is a complex vector.

 If tau = 0, then H is taken to be the unit matrix.

 To apply H**H (the conjugate transpose of H), supply conjg(tau) instead
 tau.
Parameters
[in]SIDE
          SIDE is CHARACTER*1
          = 'L': form  H * C
          = 'R': form  C * H
[in]M
          M is INTEGER
          The number of rows of the matrix C.
[in]N
          N is INTEGER
          The number of columns of the matrix C.
[in]V
          V is COMPLEX array, dimension
                     (1 + (M-1)*abs(INCV)) if SIDE = 'L'
                  or (1 + (N-1)*abs(INCV)) if SIDE = 'R'
          The vector v in the representation of H. V is not used if
          TAU = 0.
[in]INCV
          INCV is INTEGER
          The increment between elements of v. INCV <> 0.
[in]TAU
          TAU is COMPLEX
          The value tau in the representation of H.
[in,out]C
          C is COMPLEX array, dimension (LDC,N)
          On entry, the M-by-N matrix C.
          On exit, C is overwritten by the matrix H * C if SIDE = 'L',
          or C * H if SIDE = 'R'.
[in]LDC
          LDC is INTEGER
          The leading dimension of the array C. LDC >= max(1,M).
[out]WORK
          WORK is COMPLEX array, dimension
                         (N) if SIDE = 'L'
                      or (M) if SIDE = 'R'
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 127 of file clarf.f.

128 *
129 * -- LAPACK auxiliary routine --
130 * -- LAPACK is a software package provided by Univ. of Tennessee, --
131 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
132 *
133 * .. Scalar Arguments ..
134  CHARACTER SIDE
135  INTEGER INCV, LDC, M, N
136  COMPLEX TAU
137 * ..
138 * .. Array Arguments ..
139  COMPLEX C( LDC, * ), V( * ), WORK( * )
140 * ..
141 *
142 * =====================================================================
143 *
144 * .. Parameters ..
145  COMPLEX ONE, ZERO
146  parameter( one = ( 1.0e+0, 0.0e+0 ),
147  $ zero = ( 0.0e+0, 0.0e+0 ) )
148 * ..
149 * .. Local Scalars ..
150  LOGICAL APPLYLEFT
151  INTEGER I, LASTV, LASTC
152 * ..
153 * .. External Subroutines ..
154  EXTERNAL cgemv, cgerc
155 * ..
156 * .. External Functions ..
157  LOGICAL LSAME
158  INTEGER ILACLR, ILACLC
159  EXTERNAL lsame, ilaclr, ilaclc
160 * ..
161 * .. Executable Statements ..
162 *
163  applyleft = lsame( side, 'L' )
164  lastv = 0
165  lastc = 0
166  IF( tau.NE.zero ) THEN
167 ! Set up variables for scanning V. LASTV begins pointing to the end
168 ! of V.
169  IF( applyleft ) THEN
170  lastv = m
171  ELSE
172  lastv = n
173  END IF
174  IF( incv.GT.0 ) THEN
175  i = 1 + (lastv-1) * incv
176  ELSE
177  i = 1
178  END IF
179 ! Look for the last non-zero row in V.
180  DO WHILE( lastv.GT.0 .AND. v( i ).EQ.zero )
181  lastv = lastv - 1
182  i = i - incv
183  END DO
184  IF( applyleft ) THEN
185 ! Scan for the last non-zero column in C(1:lastv,:).
186  lastc = ilaclc(lastv, n, c, ldc)
187  ELSE
188 ! Scan for the last non-zero row in C(:,1:lastv).
189  lastc = ilaclr(m, lastv, c, ldc)
190  END IF
191  END IF
192 ! Note that lastc.eq.0 renders the BLAS operations null; no special
193 ! case is needed at this level.
194  IF( applyleft ) THEN
195 *
196 * Form H * C
197 *
198  IF( lastv.GT.0 ) THEN
199 *
200 * w(1:lastc,1) := C(1:lastv,1:lastc)**H * v(1:lastv,1)
201 *
202  CALL cgemv( 'Conjugate transpose', lastv, lastc, one,
203  $ c, ldc, v, incv, zero, work, 1 )
204 *
205 * C(1:lastv,1:lastc) := C(...) - v(1:lastv,1) * w(1:lastc,1)**H
206 *
207  CALL cgerc( lastv, lastc, -tau, v, incv, work, 1, c, ldc )
208  END IF
209  ELSE
210 *
211 * Form C * H
212 *
213  IF( lastv.GT.0 ) THEN
214 *
215 * w(1:lastc,1) := C(1:lastc,1:lastv) * v(1:lastv,1)
216 *
217  CALL cgemv( 'No transpose', lastc, lastv, one, c, ldc,
218  $ v, incv, zero, work, 1 )
219 *
220 * C(1:lastc,1:lastv) := C(...) - w(1:lastc,1) * v(1:lastv,1)**H
221 *
222  CALL cgerc( lastc, lastv, -tau, work, 1, v, incv, c, ldc )
223  END IF
224  END IF
225  RETURN
226 *
227 * End of CLARF
228 *
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine cgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
CGEMV
Definition: cgemv.f:158
subroutine cgerc(M, N, ALPHA, X, INCX, Y, INCY, A, LDA)
CGERC
Definition: cgerc.f:130
integer function ilaclr(M, N, A, LDA)
ILACLR scans a matrix for its last non-zero row.
Definition: ilaclr.f:78
integer function ilaclc(M, N, A, LDA)
ILACLC scans a matrix for its last non-zero column.
Definition: ilaclc.f:78
Here is the call graph for this function:
Here is the caller graph for this function: