LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ clanhs()

real function clanhs ( character  NORM,
integer  N,
complex, dimension( lda, * )  A,
integer  LDA,
real, dimension( * )  WORK 
)

CLANHS returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of an upper Hessenberg matrix.

Download CLANHS + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CLANHS  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the  element of  largest absolute value  of a
 Hessenberg matrix A.
Returns
CLANHS
    CLANHS = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in CLANHS as described
          above.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.  When N = 0, CLANHS is
          set to zero.
[in]A
          A is COMPLEX array, dimension (LDA,N)
          The n by n upper Hessenberg matrix A; the part of A below the
          first sub-diagonal is not referenced.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(N,1).
[out]WORK
          WORK is REAL array, dimension (MAX(1,LWORK)),
          where LWORK >= N when NORM = 'I'; otherwise, WORK is not
          referenced.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 108 of file clanhs.f.

109 *
110 * -- LAPACK auxiliary routine --
111 * -- LAPACK is a software package provided by Univ. of Tennessee, --
112 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
113 *
114  IMPLICIT NONE
115 * .. Scalar Arguments ..
116  CHARACTER NORM
117  INTEGER LDA, N
118 * ..
119 * .. Array Arguments ..
120  REAL WORK( * )
121  COMPLEX A( LDA, * )
122 * ..
123 *
124 * =====================================================================
125 *
126 * .. Parameters ..
127  REAL ONE, ZERO
128  parameter( one = 1.0e+0, zero = 0.0e+0 )
129 * ..
130 * .. Local Scalars ..
131  INTEGER I, J
132  REAL SUM, VALUE
133 * ..
134 * .. Local Arrays ..
135  REAL SSQ( 2 ), COLSSQ( 2 )
136 * ..
137 * .. External Functions ..
138  LOGICAL LSAME, SISNAN
139  EXTERNAL lsame, sisnan
140 * ..
141 * .. External Subroutines ..
142  EXTERNAL classq, scombssq
143 * ..
144 * .. Intrinsic Functions ..
145  INTRINSIC abs, min, sqrt
146 * ..
147 * .. Executable Statements ..
148 *
149  IF( n.EQ.0 ) THEN
150  VALUE = zero
151  ELSE IF( lsame( norm, 'M' ) ) THEN
152 *
153 * Find max(abs(A(i,j))).
154 *
155  VALUE = zero
156  DO 20 j = 1, n
157  DO 10 i = 1, min( n, j+1 )
158  sum = abs( a( i, j ) )
159  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
160  10 CONTINUE
161  20 CONTINUE
162  ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
163 *
164 * Find norm1(A).
165 *
166  VALUE = zero
167  DO 40 j = 1, n
168  sum = zero
169  DO 30 i = 1, min( n, j+1 )
170  sum = sum + abs( a( i, j ) )
171  30 CONTINUE
172  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
173  40 CONTINUE
174  ELSE IF( lsame( norm, 'I' ) ) THEN
175 *
176 * Find normI(A).
177 *
178  DO 50 i = 1, n
179  work( i ) = zero
180  50 CONTINUE
181  DO 70 j = 1, n
182  DO 60 i = 1, min( n, j+1 )
183  work( i ) = work( i ) + abs( a( i, j ) )
184  60 CONTINUE
185  70 CONTINUE
186  VALUE = zero
187  DO 80 i = 1, n
188  sum = work( i )
189  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
190  80 CONTINUE
191  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
192 *
193 * Find normF(A).
194 * SSQ(1) is scale
195 * SSQ(2) is sum-of-squares
196 * For better accuracy, sum each column separately.
197 *
198  ssq( 1 ) = zero
199  ssq( 2 ) = one
200  DO 90 j = 1, n
201  colssq( 1 ) = zero
202  colssq( 2 ) = one
203  CALL classq( min( n, j+1 ), a( 1, j ), 1,
204  $ colssq( 1 ), colssq( 2 ) )
205  CALL scombssq( ssq, colssq )
206  90 CONTINUE
207  VALUE = ssq( 1 )*sqrt( ssq( 2 ) )
208  END IF
209 *
210  clanhs = VALUE
211  RETURN
212 *
213 * End of CLANHS
214 *
subroutine scombssq(V1, V2)
SCOMBSSQ adds two scaled sum of squares quantities
Definition: scombssq.f:60
subroutine classq(n, x, incx, scl, sumsq)
CLASSQ updates a sum of squares represented in scaled form.
Definition: classq.f90:126
logical function sisnan(SIN)
SISNAN tests input for NaN.
Definition: sisnan.f:59
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
real function clanhs(NORM, N, A, LDA, WORK)
CLANHS returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: clanhs.f:109
Here is the call graph for this function: