LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
dorgr2.f
Go to the documentation of this file.
1*> \brief \b DORGR2 generates all or part of the orthogonal matrix Q from an RQ factorization determined by sgerqf (unblocked algorithm).
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> Download DORGR2 + dependencies
9*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dorgr2.f">
10*> [TGZ]</a>
11*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dorgr2.f">
12*> [ZIP]</a>
13*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dorgr2.f">
14*> [TXT]</a>
15*
16* Definition:
17* ===========
18*
19* SUBROUTINE DORGR2( M, N, K, A, LDA, TAU, WORK, INFO )
20*
21* .. Scalar Arguments ..
22* INTEGER INFO, K, LDA, M, N
23* ..
24* .. Array Arguments ..
25* DOUBLE PRECISION A( LDA, * ), TAU( * ), WORK( * )
26* ..
27*
28*
29*> \par Purpose:
30* =============
31*>
32*> \verbatim
33*>
34*> DORGR2 generates an m by n real matrix Q with orthonormal rows,
35*> which is defined as the last m rows of a product of k elementary
36*> reflectors of order n
37*>
38*> Q = H(1) H(2) . . . H(k)
39*>
40*> as returned by DGERQF.
41*> \endverbatim
42*
43* Arguments:
44* ==========
45*
46*> \param[in] M
47*> \verbatim
48*> M is INTEGER
49*> The number of rows of the matrix Q. M >= 0.
50*> \endverbatim
51*>
52*> \param[in] N
53*> \verbatim
54*> N is INTEGER
55*> The number of columns of the matrix Q. N >= M.
56*> \endverbatim
57*>
58*> \param[in] K
59*> \verbatim
60*> K is INTEGER
61*> The number of elementary reflectors whose product defines the
62*> matrix Q. M >= K >= 0.
63*> \endverbatim
64*>
65*> \param[in,out] A
66*> \verbatim
67*> A is DOUBLE PRECISION array, dimension (LDA,N)
68*> On entry, the (m-k+i)-th row must contain the vector which
69*> defines the elementary reflector H(i), for i = 1,2,...,k, as
70*> returned by DGERQF in the last k rows of its array argument
71*> A.
72*> On exit, the m by n matrix Q.
73*> \endverbatim
74*>
75*> \param[in] LDA
76*> \verbatim
77*> LDA is INTEGER
78*> The first dimension of the array A. LDA >= max(1,M).
79*> \endverbatim
80*>
81*> \param[in] TAU
82*> \verbatim
83*> TAU is DOUBLE PRECISION array, dimension (K)
84*> TAU(i) must contain the scalar factor of the elementary
85*> reflector H(i), as returned by DGERQF.
86*> \endverbatim
87*>
88*> \param[out] WORK
89*> \verbatim
90*> WORK is DOUBLE PRECISION array, dimension (M)
91*> \endverbatim
92*>
93*> \param[out] INFO
94*> \verbatim
95*> INFO is INTEGER
96*> = 0: successful exit
97*> < 0: if INFO = -i, the i-th argument has an illegal value
98*> \endverbatim
99*
100* Authors:
101* ========
102*
103*> \author Univ. of Tennessee
104*> \author Univ. of California Berkeley
105*> \author Univ. of Colorado Denver
106*> \author NAG Ltd.
107*
108*> \ingroup ungr2
109*
110* =====================================================================
111 SUBROUTINE dorgr2( M, N, K, A, LDA, TAU, WORK, INFO )
112*
113* -- LAPACK computational routine --
114* -- LAPACK is a software package provided by Univ. of Tennessee, --
115* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
116*
117* .. Scalar Arguments ..
118 INTEGER INFO, K, LDA, M, N
119* ..
120* .. Array Arguments ..
121 DOUBLE PRECISION A( LDA, * ), TAU( * ), WORK( * )
122* ..
123*
124* =====================================================================
125*
126* .. Parameters ..
127 DOUBLE PRECISION ONE, ZERO
128 parameter( one = 1.0d+0, zero = 0.0d+0 )
129* ..
130* .. Local Scalars ..
131 INTEGER I, II, J, L
132* ..
133* .. External Subroutines ..
134 EXTERNAL dlarf, dscal, xerbla
135* ..
136* .. Intrinsic Functions ..
137 INTRINSIC max
138* ..
139* .. Executable Statements ..
140*
141* Test the input arguments
142*
143 info = 0
144 IF( m.LT.0 ) THEN
145 info = -1
146 ELSE IF( n.LT.m ) THEN
147 info = -2
148 ELSE IF( k.LT.0 .OR. k.GT.m ) THEN
149 info = -3
150 ELSE IF( lda.LT.max( 1, m ) ) THEN
151 info = -5
152 END IF
153 IF( info.NE.0 ) THEN
154 CALL xerbla( 'DORGR2', -info )
155 RETURN
156 END IF
157*
158* Quick return if possible
159*
160 IF( m.LE.0 )
161 $ RETURN
162*
163 IF( k.LT.m ) THEN
164*
165* Initialise rows 1:m-k to rows of the unit matrix
166*
167 DO 20 j = 1, n
168 DO 10 l = 1, m - k
169 a( l, j ) = zero
170 10 CONTINUE
171 IF( j.GT.n-m .AND. j.LE.n-k )
172 $ a( m-n+j, j ) = one
173 20 CONTINUE
174 END IF
175*
176 DO 40 i = 1, k
177 ii = m - k + i
178*
179* Apply H(i) to A(1:m-k+i,1:n-k+i) from the right
180*
181 !A( II, N-M+II ) = ONE
182 CALL dlarf1l( 'Right', ii-1, n-m+ii, a( ii, 1 ), lda,
183 $ tau( i ),
184 $ a, lda, work )
185 CALL dscal( n-m+ii-1, -tau( i ), a( ii, 1 ), lda )
186 a( ii, n-m+ii ) = one - tau( i )
187*
188* Set A(m-k+i,n-k+i+1:n) to zero
189*
190 DO 30 l = n - m + ii + 1, n
191 a( ii, l ) = zero
192 30 CONTINUE
193 40 CONTINUE
194 RETURN
195*
196* End of DORGR2
197*
198 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine dlarf1l(side, m, n, v, incv, tau, c, ldc, work)
DLARF1L applies an elementary reflector to a general rectangular
Definition dlarf1l.f:124
subroutine dlarf(side, m, n, v, incv, tau, c, ldc, work)
DLARF applies an elementary reflector to a general rectangular matrix.
Definition dlarf.f:122
subroutine dscal(n, da, dx, incx)
DSCAL
Definition dscal.f:79
subroutine dorgr2(m, n, k, a, lda, tau, work, info)
DORGR2 generates all or part of the orthogonal matrix Q from an RQ factorization determined by sgerqf...
Definition dorgr2.f:112