LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
dlaqr2.f
Go to the documentation of this file.
1 *> \brief \b DLAQR2 performs the orthogonal similarity transformation of a Hessenberg matrix to detect and deflate fully converged eigenvalues from a trailing principal submatrix (aggressive early deflation).
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download DLAQR2 + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlaqr2.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlaqr2.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlaqr2.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE DLAQR2( WANTT, WANTZ, N, KTOP, KBOT, NW, H, LDH, ILOZ,
22 * IHIZ, Z, LDZ, NS, ND, SR, SI, V, LDV, NH, T,
23 * LDT, NV, WV, LDWV, WORK, LWORK )
24 *
25 * .. Scalar Arguments ..
26 * INTEGER IHIZ, ILOZ, KBOT, KTOP, LDH, LDT, LDV, LDWV,
27 * $ LDZ, LWORK, N, ND, NH, NS, NV, NW
28 * LOGICAL WANTT, WANTZ
29 * ..
30 * .. Array Arguments ..
31 * DOUBLE PRECISION H( LDH, * ), SI( * ), SR( * ), T( LDT, * ),
32 * $ V( LDV, * ), WORK( * ), WV( LDWV, * ),
33 * $ Z( LDZ, * )
34 * ..
35 *
36 *
37 *> \par Purpose:
38 * =============
39 *>
40 *> \verbatim
41 *>
42 *> DLAQR2 is identical to DLAQR3 except that it avoids
43 *> recursion by calling DLAHQR instead of DLAQR4.
44 *>
45 *> Aggressive early deflation:
46 *>
47 *> This subroutine accepts as input an upper Hessenberg matrix
48 *> H and performs an orthogonal similarity transformation
49 *> designed to detect and deflate fully converged eigenvalues from
50 *> a trailing principal submatrix. On output H has been over-
51 *> written by a new Hessenberg matrix that is a perturbation of
52 *> an orthogonal similarity transformation of H. It is to be
53 *> hoped that the final version of H has many zero subdiagonal
54 *> entries.
55 *> \endverbatim
56 *
57 * Arguments:
58 * ==========
59 *
60 *> \param[in] WANTT
61 *> \verbatim
62 *> WANTT is LOGICAL
63 *> If .TRUE., then the Hessenberg matrix H is fully updated
64 *> so that the quasi-triangular Schur factor may be
65 *> computed (in cooperation with the calling subroutine).
66 *> If .FALSE., then only enough of H is updated to preserve
67 *> the eigenvalues.
68 *> \endverbatim
69 *>
70 *> \param[in] WANTZ
71 *> \verbatim
72 *> WANTZ is LOGICAL
73 *> If .TRUE., then the orthogonal matrix Z is updated so
74 *> so that the orthogonal Schur factor may be computed
75 *> (in cooperation with the calling subroutine).
76 *> If .FALSE., then Z is not referenced.
77 *> \endverbatim
78 *>
79 *> \param[in] N
80 *> \verbatim
81 *> N is INTEGER
82 *> The order of the matrix H and (if WANTZ is .TRUE.) the
83 *> order of the orthogonal matrix Z.
84 *> \endverbatim
85 *>
86 *> \param[in] KTOP
87 *> \verbatim
88 *> KTOP is INTEGER
89 *> It is assumed that either KTOP = 1 or H(KTOP,KTOP-1)=0.
90 *> KBOT and KTOP together determine an isolated block
91 *> along the diagonal of the Hessenberg matrix.
92 *> \endverbatim
93 *>
94 *> \param[in] KBOT
95 *> \verbatim
96 *> KBOT is INTEGER
97 *> It is assumed without a check that either
98 *> KBOT = N or H(KBOT+1,KBOT)=0. KBOT and KTOP together
99 *> determine an isolated block along the diagonal of the
100 *> Hessenberg matrix.
101 *> \endverbatim
102 *>
103 *> \param[in] NW
104 *> \verbatim
105 *> NW is INTEGER
106 *> Deflation window size. 1 <= NW <= (KBOT-KTOP+1).
107 *> \endverbatim
108 *>
109 *> \param[in,out] H
110 *> \verbatim
111 *> H is DOUBLE PRECISION array, dimension (LDH,N)
112 *> On input the initial N-by-N section of H stores the
113 *> Hessenberg matrix undergoing aggressive early deflation.
114 *> On output H has been transformed by an orthogonal
115 *> similarity transformation, perturbed, and the returned
116 *> to Hessenberg form that (it is to be hoped) has some
117 *> zero subdiagonal entries.
118 *> \endverbatim
119 *>
120 *> \param[in] LDH
121 *> \verbatim
122 *> LDH is INTEGER
123 *> Leading dimension of H just as declared in the calling
124 *> subroutine. N <= LDH
125 *> \endverbatim
126 *>
127 *> \param[in] ILOZ
128 *> \verbatim
129 *> ILOZ is INTEGER
130 *> \endverbatim
131 *>
132 *> \param[in] IHIZ
133 *> \verbatim
134 *> IHIZ is INTEGER
135 *> Specify the rows of Z to which transformations must be
136 *> applied if WANTZ is .TRUE.. 1 <= ILOZ <= IHIZ <= N.
137 *> \endverbatim
138 *>
139 *> \param[in,out] Z
140 *> \verbatim
141 *> Z is DOUBLE PRECISION array, dimension (LDZ,N)
142 *> IF WANTZ is .TRUE., then on output, the orthogonal
143 *> similarity transformation mentioned above has been
144 *> accumulated into Z(ILOZ:IHIZ,ILOZ:IHIZ) from the right.
145 *> If WANTZ is .FALSE., then Z is unreferenced.
146 *> \endverbatim
147 *>
148 *> \param[in] LDZ
149 *> \verbatim
150 *> LDZ is INTEGER
151 *> The leading dimension of Z just as declared in the
152 *> calling subroutine. 1 <= LDZ.
153 *> \endverbatim
154 *>
155 *> \param[out] NS
156 *> \verbatim
157 *> NS is INTEGER
158 *> The number of unconverged (ie approximate) eigenvalues
159 *> returned in SR and SI that may be used as shifts by the
160 *> calling subroutine.
161 *> \endverbatim
162 *>
163 *> \param[out] ND
164 *> \verbatim
165 *> ND is INTEGER
166 *> The number of converged eigenvalues uncovered by this
167 *> subroutine.
168 *> \endverbatim
169 *>
170 *> \param[out] SR
171 *> \verbatim
172 *> SR is DOUBLE PRECISION array, dimension (KBOT)
173 *> \endverbatim
174 *>
175 *> \param[out] SI
176 *> \verbatim
177 *> SI is DOUBLE PRECISION array, dimension (KBOT)
178 *> On output, the real and imaginary parts of approximate
179 *> eigenvalues that may be used for shifts are stored in
180 *> SR(KBOT-ND-NS+1) through SR(KBOT-ND) and
181 *> SI(KBOT-ND-NS+1) through SI(KBOT-ND), respectively.
182 *> The real and imaginary parts of converged eigenvalues
183 *> are stored in SR(KBOT-ND+1) through SR(KBOT) and
184 *> SI(KBOT-ND+1) through SI(KBOT), respectively.
185 *> \endverbatim
186 *>
187 *> \param[out] V
188 *> \verbatim
189 *> V is DOUBLE PRECISION array, dimension (LDV,NW)
190 *> An NW-by-NW work array.
191 *> \endverbatim
192 *>
193 *> \param[in] LDV
194 *> \verbatim
195 *> LDV is INTEGER
196 *> The leading dimension of V just as declared in the
197 *> calling subroutine. NW <= LDV
198 *> \endverbatim
199 *>
200 *> \param[in] NH
201 *> \verbatim
202 *> NH is INTEGER
203 *> The number of columns of T. NH >= NW.
204 *> \endverbatim
205 *>
206 *> \param[out] T
207 *> \verbatim
208 *> T is DOUBLE PRECISION array, dimension (LDT,NW)
209 *> \endverbatim
210 *>
211 *> \param[in] LDT
212 *> \verbatim
213 *> LDT is INTEGER
214 *> The leading dimension of T just as declared in the
215 *> calling subroutine. NW <= LDT
216 *> \endverbatim
217 *>
218 *> \param[in] NV
219 *> \verbatim
220 *> NV is INTEGER
221 *> The number of rows of work array WV available for
222 *> workspace. NV >= NW.
223 *> \endverbatim
224 *>
225 *> \param[out] WV
226 *> \verbatim
227 *> WV is DOUBLE PRECISION array, dimension (LDWV,NW)
228 *> \endverbatim
229 *>
230 *> \param[in] LDWV
231 *> \verbatim
232 *> LDWV is INTEGER
233 *> The leading dimension of W just as declared in the
234 *> calling subroutine. NW <= LDV
235 *> \endverbatim
236 *>
237 *> \param[out] WORK
238 *> \verbatim
239 *> WORK is DOUBLE PRECISION array, dimension (LWORK)
240 *> On exit, WORK(1) is set to an estimate of the optimal value
241 *> of LWORK for the given values of N, NW, KTOP and KBOT.
242 *> \endverbatim
243 *>
244 *> \param[in] LWORK
245 *> \verbatim
246 *> LWORK is INTEGER
247 *> The dimension of the work array WORK. LWORK = 2*NW
248 *> suffices, but greater efficiency may result from larger
249 *> values of LWORK.
250 *>
251 *> If LWORK = -1, then a workspace query is assumed; DLAQR2
252 *> only estimates the optimal workspace size for the given
253 *> values of N, NW, KTOP and KBOT. The estimate is returned
254 *> in WORK(1). No error message related to LWORK is issued
255 *> by XERBLA. Neither H nor Z are accessed.
256 *> \endverbatim
257 *
258 * Authors:
259 * ========
260 *
261 *> \author Univ. of Tennessee
262 *> \author Univ. of California Berkeley
263 *> \author Univ. of Colorado Denver
264 *> \author NAG Ltd.
265 *
266 *> \ingroup doubleOTHERauxiliary
267 *
268 *> \par Contributors:
269 * ==================
270 *>
271 *> Karen Braman and Ralph Byers, Department of Mathematics,
272 *> University of Kansas, USA
273 *>
274 * =====================================================================
275  SUBROUTINE dlaqr2( WANTT, WANTZ, N, KTOP, KBOT, NW, H, LDH, ILOZ,
276  $ IHIZ, Z, LDZ, NS, ND, SR, SI, V, LDV, NH, T,
277  $ LDT, NV, WV, LDWV, WORK, LWORK )
278 *
279 * -- LAPACK auxiliary routine --
280 * -- LAPACK is a software package provided by Univ. of Tennessee, --
281 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
282 *
283 * .. Scalar Arguments ..
284  INTEGER IHIZ, ILOZ, KBOT, KTOP, LDH, LDT, LDV, LDWV,
285  $ LDZ, LWORK, N, ND, NH, NS, NV, NW
286  LOGICAL WANTT, WANTZ
287 * ..
288 * .. Array Arguments ..
289  DOUBLE PRECISION H( LDH, * ), SI( * ), SR( * ), T( LDT, * ),
290  $ V( LDV, * ), WORK( * ), WV( LDWV, * ),
291  $ z( ldz, * )
292 * ..
293 *
294 * ================================================================
295 * .. Parameters ..
296  DOUBLE PRECISION ZERO, ONE
297  PARAMETER ( ZERO = 0.0d0, one = 1.0d0 )
298 * ..
299 * .. Local Scalars ..
300  DOUBLE PRECISION AA, BB, BETA, CC, CS, DD, EVI, EVK, FOO, S,
301  $ SAFMAX, SAFMIN, SMLNUM, SN, TAU, ULP
302  INTEGER I, IFST, ILST, INFO, INFQR, J, JW, K, KCOL,
303  $ KEND, KLN, KROW, KWTOP, LTOP, LWK1, LWK2,
304  $ lwkopt
305  LOGICAL BULGE, SORTED
306 * ..
307 * .. External Functions ..
308  DOUBLE PRECISION DLAMCH
309  EXTERNAL DLAMCH
310 * ..
311 * .. External Subroutines ..
312  EXTERNAL dcopy, dgehrd, dgemm, dlabad, dlacpy, dlahqr,
314 * ..
315 * .. Intrinsic Functions ..
316  INTRINSIC abs, dble, int, max, min, sqrt
317 * ..
318 * .. Executable Statements ..
319 *
320 * ==== Estimate optimal workspace. ====
321 *
322  jw = min( nw, kbot-ktop+1 )
323  IF( jw.LE.2 ) THEN
324  lwkopt = 1
325  ELSE
326 *
327 * ==== Workspace query call to DGEHRD ====
328 *
329  CALL dgehrd( jw, 1, jw-1, t, ldt, work, work, -1, info )
330  lwk1 = int( work( 1 ) )
331 *
332 * ==== Workspace query call to DORMHR ====
333 *
334  CALL dormhr( 'R', 'N', jw, jw, 1, jw-1, t, ldt, work, v, ldv,
335  $ work, -1, info )
336  lwk2 = int( work( 1 ) )
337 *
338 * ==== Optimal workspace ====
339 *
340  lwkopt = jw + max( lwk1, lwk2 )
341  END IF
342 *
343 * ==== Quick return in case of workspace query. ====
344 *
345  IF( lwork.EQ.-1 ) THEN
346  work( 1 ) = dble( lwkopt )
347  RETURN
348  END IF
349 *
350 * ==== Nothing to do ...
351 * ... for an empty active block ... ====
352  ns = 0
353  nd = 0
354  work( 1 ) = one
355  IF( ktop.GT.kbot )
356  $ RETURN
357 * ... nor for an empty deflation window. ====
358  IF( nw.LT.1 )
359  $ RETURN
360 *
361 * ==== Machine constants ====
362 *
363  safmin = dlamch( 'SAFE MINIMUM' )
364  safmax = one / safmin
365  CALL dlabad( safmin, safmax )
366  ulp = dlamch( 'PRECISION' )
367  smlnum = safmin*( dble( n ) / ulp )
368 *
369 * ==== Setup deflation window ====
370 *
371  jw = min( nw, kbot-ktop+1 )
372  kwtop = kbot - jw + 1
373  IF( kwtop.EQ.ktop ) THEN
374  s = zero
375  ELSE
376  s = h( kwtop, kwtop-1 )
377  END IF
378 *
379  IF( kbot.EQ.kwtop ) THEN
380 *
381 * ==== 1-by-1 deflation window: not much to do ====
382 *
383  sr( kwtop ) = h( kwtop, kwtop )
384  si( kwtop ) = zero
385  ns = 1
386  nd = 0
387  IF( abs( s ).LE.max( smlnum, ulp*abs( h( kwtop, kwtop ) ) ) )
388  $ THEN
389  ns = 0
390  nd = 1
391  IF( kwtop.GT.ktop )
392  $ h( kwtop, kwtop-1 ) = zero
393  END IF
394  work( 1 ) = one
395  RETURN
396  END IF
397 *
398 * ==== Convert to spike-triangular form. (In case of a
399 * . rare QR failure, this routine continues to do
400 * . aggressive early deflation using that part of
401 * . the deflation window that converged using INFQR
402 * . here and there to keep track.) ====
403 *
404  CALL dlacpy( 'U', jw, jw, h( kwtop, kwtop ), ldh, t, ldt )
405  CALL dcopy( jw-1, h( kwtop+1, kwtop ), ldh+1, t( 2, 1 ), ldt+1 )
406 *
407  CALL dlaset( 'A', jw, jw, zero, one, v, ldv )
408  CALL dlahqr( .true., .true., jw, 1, jw, t, ldt, sr( kwtop ),
409  $ si( kwtop ), 1, jw, v, ldv, infqr )
410 *
411 * ==== DTREXC needs a clean margin near the diagonal ====
412 *
413  DO 10 j = 1, jw - 3
414  t( j+2, j ) = zero
415  t( j+3, j ) = zero
416  10 CONTINUE
417  IF( jw.GT.2 )
418  $ t( jw, jw-2 ) = zero
419 *
420 * ==== Deflation detection loop ====
421 *
422  ns = jw
423  ilst = infqr + 1
424  20 CONTINUE
425  IF( ilst.LE.ns ) THEN
426  IF( ns.EQ.1 ) THEN
427  bulge = .false.
428  ELSE
429  bulge = t( ns, ns-1 ).NE.zero
430  END IF
431 *
432 * ==== Small spike tip test for deflation ====
433 *
434  IF( .NOT.bulge ) THEN
435 *
436 * ==== Real eigenvalue ====
437 *
438  foo = abs( t( ns, ns ) )
439  IF( foo.EQ.zero )
440  $ foo = abs( s )
441  IF( abs( s*v( 1, ns ) ).LE.max( smlnum, ulp*foo ) ) THEN
442 *
443 * ==== Deflatable ====
444 *
445  ns = ns - 1
446  ELSE
447 *
448 * ==== Undeflatable. Move it up out of the way.
449 * . (DTREXC can not fail in this case.) ====
450 *
451  ifst = ns
452  CALL dtrexc( 'V', jw, t, ldt, v, ldv, ifst, ilst, work,
453  $ info )
454  ilst = ilst + 1
455  END IF
456  ELSE
457 *
458 * ==== Complex conjugate pair ====
459 *
460  foo = abs( t( ns, ns ) ) + sqrt( abs( t( ns, ns-1 ) ) )*
461  $ sqrt( abs( t( ns-1, ns ) ) )
462  IF( foo.EQ.zero )
463  $ foo = abs( s )
464  IF( max( abs( s*v( 1, ns ) ), abs( s*v( 1, ns-1 ) ) ).LE.
465  $ max( smlnum, ulp*foo ) ) THEN
466 *
467 * ==== Deflatable ====
468 *
469  ns = ns - 2
470  ELSE
471 *
472 * ==== Undeflatable. Move them up out of the way.
473 * . Fortunately, DTREXC does the right thing with
474 * . ILST in case of a rare exchange failure. ====
475 *
476  ifst = ns
477  CALL dtrexc( 'V', jw, t, ldt, v, ldv, ifst, ilst, work,
478  $ info )
479  ilst = ilst + 2
480  END IF
481  END IF
482 *
483 * ==== End deflation detection loop ====
484 *
485  GO TO 20
486  END IF
487 *
488 * ==== Return to Hessenberg form ====
489 *
490  IF( ns.EQ.0 )
491  $ s = zero
492 *
493  IF( ns.LT.jw ) THEN
494 *
495 * ==== sorting diagonal blocks of T improves accuracy for
496 * . graded matrices. Bubble sort deals well with
497 * . exchange failures. ====
498 *
499  sorted = .false.
500  i = ns + 1
501  30 CONTINUE
502  IF( sorted )
503  $ GO TO 50
504  sorted = .true.
505 *
506  kend = i - 1
507  i = infqr + 1
508  IF( i.EQ.ns ) THEN
509  k = i + 1
510  ELSE IF( t( i+1, i ).EQ.zero ) THEN
511  k = i + 1
512  ELSE
513  k = i + 2
514  END IF
515  40 CONTINUE
516  IF( k.LE.kend ) THEN
517  IF( k.EQ.i+1 ) THEN
518  evi = abs( t( i, i ) )
519  ELSE
520  evi = abs( t( i, i ) ) + sqrt( abs( t( i+1, i ) ) )*
521  $ sqrt( abs( t( i, i+1 ) ) )
522  END IF
523 *
524  IF( k.EQ.kend ) THEN
525  evk = abs( t( k, k ) )
526  ELSE IF( t( k+1, k ).EQ.zero ) THEN
527  evk = abs( t( k, k ) )
528  ELSE
529  evk = abs( t( k, k ) ) + sqrt( abs( t( k+1, k ) ) )*
530  $ sqrt( abs( t( k, k+1 ) ) )
531  END IF
532 *
533  IF( evi.GE.evk ) THEN
534  i = k
535  ELSE
536  sorted = .false.
537  ifst = i
538  ilst = k
539  CALL dtrexc( 'V', jw, t, ldt, v, ldv, ifst, ilst, work,
540  $ info )
541  IF( info.EQ.0 ) THEN
542  i = ilst
543  ELSE
544  i = k
545  END IF
546  END IF
547  IF( i.EQ.kend ) THEN
548  k = i + 1
549  ELSE IF( t( i+1, i ).EQ.zero ) THEN
550  k = i + 1
551  ELSE
552  k = i + 2
553  END IF
554  GO TO 40
555  END IF
556  GO TO 30
557  50 CONTINUE
558  END IF
559 *
560 * ==== Restore shift/eigenvalue array from T ====
561 *
562  i = jw
563  60 CONTINUE
564  IF( i.GE.infqr+1 ) THEN
565  IF( i.EQ.infqr+1 ) THEN
566  sr( kwtop+i-1 ) = t( i, i )
567  si( kwtop+i-1 ) = zero
568  i = i - 1
569  ELSE IF( t( i, i-1 ).EQ.zero ) THEN
570  sr( kwtop+i-1 ) = t( i, i )
571  si( kwtop+i-1 ) = zero
572  i = i - 1
573  ELSE
574  aa = t( i-1, i-1 )
575  cc = t( i, i-1 )
576  bb = t( i-1, i )
577  dd = t( i, i )
578  CALL dlanv2( aa, bb, cc, dd, sr( kwtop+i-2 ),
579  $ si( kwtop+i-2 ), sr( kwtop+i-1 ),
580  $ si( kwtop+i-1 ), cs, sn )
581  i = i - 2
582  END IF
583  GO TO 60
584  END IF
585 *
586  IF( ns.LT.jw .OR. s.EQ.zero ) THEN
587  IF( ns.GT.1 .AND. s.NE.zero ) THEN
588 *
589 * ==== Reflect spike back into lower triangle ====
590 *
591  CALL dcopy( ns, v, ldv, work, 1 )
592  beta = work( 1 )
593  CALL dlarfg( ns, beta, work( 2 ), 1, tau )
594  work( 1 ) = one
595 *
596  CALL dlaset( 'L', jw-2, jw-2, zero, zero, t( 3, 1 ), ldt )
597 *
598  CALL dlarf( 'L', ns, jw, work, 1, tau, t, ldt,
599  $ work( jw+1 ) )
600  CALL dlarf( 'R', ns, ns, work, 1, tau, t, ldt,
601  $ work( jw+1 ) )
602  CALL dlarf( 'R', jw, ns, work, 1, tau, v, ldv,
603  $ work( jw+1 ) )
604 *
605  CALL dgehrd( jw, 1, ns, t, ldt, work, work( jw+1 ),
606  $ lwork-jw, info )
607  END IF
608 *
609 * ==== Copy updated reduced window into place ====
610 *
611  IF( kwtop.GT.1 )
612  $ h( kwtop, kwtop-1 ) = s*v( 1, 1 )
613  CALL dlacpy( 'U', jw, jw, t, ldt, h( kwtop, kwtop ), ldh )
614  CALL dcopy( jw-1, t( 2, 1 ), ldt+1, h( kwtop+1, kwtop ),
615  $ ldh+1 )
616 *
617 * ==== Accumulate orthogonal matrix in order update
618 * . H and Z, if requested. ====
619 *
620  IF( ns.GT.1 .AND. s.NE.zero )
621  $ CALL dormhr( 'R', 'N', jw, ns, 1, ns, t, ldt, work, v, ldv,
622  $ work( jw+1 ), lwork-jw, info )
623 *
624 * ==== Update vertical slab in H ====
625 *
626  IF( wantt ) THEN
627  ltop = 1
628  ELSE
629  ltop = ktop
630  END IF
631  DO 70 krow = ltop, kwtop - 1, nv
632  kln = min( nv, kwtop-krow )
633  CALL dgemm( 'N', 'N', kln, jw, jw, one, h( krow, kwtop ),
634  $ ldh, v, ldv, zero, wv, ldwv )
635  CALL dlacpy( 'A', kln, jw, wv, ldwv, h( krow, kwtop ), ldh )
636  70 CONTINUE
637 *
638 * ==== Update horizontal slab in H ====
639 *
640  IF( wantt ) THEN
641  DO 80 kcol = kbot + 1, n, nh
642  kln = min( nh, n-kcol+1 )
643  CALL dgemm( 'C', 'N', jw, kln, jw, one, v, ldv,
644  $ h( kwtop, kcol ), ldh, zero, t, ldt )
645  CALL dlacpy( 'A', jw, kln, t, ldt, h( kwtop, kcol ),
646  $ ldh )
647  80 CONTINUE
648  END IF
649 *
650 * ==== Update vertical slab in Z ====
651 *
652  IF( wantz ) THEN
653  DO 90 krow = iloz, ihiz, nv
654  kln = min( nv, ihiz-krow+1 )
655  CALL dgemm( 'N', 'N', kln, jw, jw, one, z( krow, kwtop ),
656  $ ldz, v, ldv, zero, wv, ldwv )
657  CALL dlacpy( 'A', kln, jw, wv, ldwv, z( krow, kwtop ),
658  $ ldz )
659  90 CONTINUE
660  END IF
661  END IF
662 *
663 * ==== Return the number of deflations ... ====
664 *
665  nd = jw - ns
666 *
667 * ==== ... and the number of shifts. (Subtracting
668 * . INFQR from the spike length takes care
669 * . of the case of a rare QR failure while
670 * . calculating eigenvalues of the deflation
671 * . window.) ====
672 *
673  ns = ns - infqr
674 *
675 * ==== Return optimal workspace. ====
676 *
677  work( 1 ) = dble( lwkopt )
678 *
679 * ==== End of DLAQR2 ====
680 *
681  END
subroutine dlabad(SMALL, LARGE)
DLABAD
Definition: dlabad.f:74
subroutine dlacpy(UPLO, M, N, A, LDA, B, LDB)
DLACPY copies all or part of one two-dimensional array to another.
Definition: dlacpy.f:103
subroutine dlaset(UPLO, M, N, ALPHA, BETA, A, LDA)
DLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition: dlaset.f:110
subroutine dcopy(N, DX, INCX, DY, INCY)
DCOPY
Definition: dcopy.f:82
subroutine dgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
DGEMM
Definition: dgemm.f:187
subroutine dgehrd(N, ILO, IHI, A, LDA, TAU, WORK, LWORK, INFO)
DGEHRD
Definition: dgehrd.f:167
subroutine dlanv2(A, B, C, D, RT1R, RT1I, RT2R, RT2I, CS, SN)
DLANV2 computes the Schur factorization of a real 2-by-2 nonsymmetric matrix in standard form.
Definition: dlanv2.f:127
subroutine dlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
DLARF applies an elementary reflector to a general rectangular matrix.
Definition: dlarf.f:124
subroutine dlaqr2(WANTT, WANTZ, N, KTOP, KBOT, NW, H, LDH, ILOZ, IHIZ, Z, LDZ, NS, ND, SR, SI, V, LDV, NH, T, LDT, NV, WV, LDWV, WORK, LWORK)
DLAQR2 performs the orthogonal similarity transformation of a Hessenberg matrix to detect and deflate...
Definition: dlaqr2.f:278
subroutine dlahqr(WANTT, WANTZ, N, ILO, IHI, H, LDH, WR, WI, ILOZ, IHIZ, Z, LDZ, INFO)
DLAHQR computes the eigenvalues and Schur factorization of an upper Hessenberg matrix,...
Definition: dlahqr.f:207
subroutine dlarfg(N, ALPHA, X, INCX, TAU)
DLARFG generates an elementary reflector (Householder matrix).
Definition: dlarfg.f:106
subroutine dtrexc(COMPQ, N, T, LDT, Q, LDQ, IFST, ILST, WORK, INFO)
DTREXC
Definition: dtrexc.f:148
subroutine dormhr(SIDE, TRANS, M, N, ILO, IHI, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
DORMHR
Definition: dormhr.f:178