LAPACK  3.10.1
LAPACK: Linear Algebra PACKage
zporfs.f
Go to the documentation of this file.
1 *> \brief \b ZPORFS
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download ZPORFS + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zporfs.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zporfs.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zporfs.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE ZPORFS( UPLO, N, NRHS, A, LDA, AF, LDAF, B, LDB, X,
22 * LDX, FERR, BERR, WORK, RWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER UPLO
26 * INTEGER INFO, LDA, LDAF, LDB, LDX, N, NRHS
27 * ..
28 * .. Array Arguments ..
29 * DOUBLE PRECISION BERR( * ), FERR( * ), RWORK( * )
30 * COMPLEX*16 A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
31 * $ WORK( * ), X( LDX, * )
32 * ..
33 *
34 *
35 *> \par Purpose:
36 * =============
37 *>
38 *> \verbatim
39 *>
40 *> ZPORFS improves the computed solution to a system of linear
41 *> equations when the coefficient matrix is Hermitian positive definite,
42 *> and provides error bounds and backward error estimates for the
43 *> solution.
44 *> \endverbatim
45 *
46 * Arguments:
47 * ==========
48 *
49 *> \param[in] UPLO
50 *> \verbatim
51 *> UPLO is CHARACTER*1
52 *> = 'U': Upper triangle of A is stored;
53 *> = 'L': Lower triangle of A is stored.
54 *> \endverbatim
55 *>
56 *> \param[in] N
57 *> \verbatim
58 *> N is INTEGER
59 *> The order of the matrix A. N >= 0.
60 *> \endverbatim
61 *>
62 *> \param[in] NRHS
63 *> \verbatim
64 *> NRHS is INTEGER
65 *> The number of right hand sides, i.e., the number of columns
66 *> of the matrices B and X. NRHS >= 0.
67 *> \endverbatim
68 *>
69 *> \param[in] A
70 *> \verbatim
71 *> A is COMPLEX*16 array, dimension (LDA,N)
72 *> The Hermitian matrix A. If UPLO = 'U', the leading N-by-N
73 *> upper triangular part of A contains the upper triangular part
74 *> of the matrix A, and the strictly lower triangular part of A
75 *> is not referenced. If UPLO = 'L', the leading N-by-N lower
76 *> triangular part of A contains the lower triangular part of
77 *> the matrix A, and the strictly upper triangular part of A is
78 *> not referenced.
79 *> \endverbatim
80 *>
81 *> \param[in] LDA
82 *> \verbatim
83 *> LDA is INTEGER
84 *> The leading dimension of the array A. LDA >= max(1,N).
85 *> \endverbatim
86 *>
87 *> \param[in] AF
88 *> \verbatim
89 *> AF is COMPLEX*16 array, dimension (LDAF,N)
90 *> The triangular factor U or L from the Cholesky factorization
91 *> A = U**H*U or A = L*L**H, as computed by ZPOTRF.
92 *> \endverbatim
93 *>
94 *> \param[in] LDAF
95 *> \verbatim
96 *> LDAF is INTEGER
97 *> The leading dimension of the array AF. LDAF >= max(1,N).
98 *> \endverbatim
99 *>
100 *> \param[in] B
101 *> \verbatim
102 *> B is COMPLEX*16 array, dimension (LDB,NRHS)
103 *> The right hand side matrix B.
104 *> \endverbatim
105 *>
106 *> \param[in] LDB
107 *> \verbatim
108 *> LDB is INTEGER
109 *> The leading dimension of the array B. LDB >= max(1,N).
110 *> \endverbatim
111 *>
112 *> \param[in,out] X
113 *> \verbatim
114 *> X is COMPLEX*16 array, dimension (LDX,NRHS)
115 *> On entry, the solution matrix X, as computed by ZPOTRS.
116 *> On exit, the improved solution matrix X.
117 *> \endverbatim
118 *>
119 *> \param[in] LDX
120 *> \verbatim
121 *> LDX is INTEGER
122 *> The leading dimension of the array X. LDX >= max(1,N).
123 *> \endverbatim
124 *>
125 *> \param[out] FERR
126 *> \verbatim
127 *> FERR is DOUBLE PRECISION array, dimension (NRHS)
128 *> The estimated forward error bound for each solution vector
129 *> X(j) (the j-th column of the solution matrix X).
130 *> If XTRUE is the true solution corresponding to X(j), FERR(j)
131 *> is an estimated upper bound for the magnitude of the largest
132 *> element in (X(j) - XTRUE) divided by the magnitude of the
133 *> largest element in X(j). The estimate is as reliable as
134 *> the estimate for RCOND, and is almost always a slight
135 *> overestimate of the true error.
136 *> \endverbatim
137 *>
138 *> \param[out] BERR
139 *> \verbatim
140 *> BERR is DOUBLE PRECISION array, dimension (NRHS)
141 *> The componentwise relative backward error of each solution
142 *> vector X(j) (i.e., the smallest relative change in
143 *> any element of A or B that makes X(j) an exact solution).
144 *> \endverbatim
145 *>
146 *> \param[out] WORK
147 *> \verbatim
148 *> WORK is COMPLEX*16 array, dimension (2*N)
149 *> \endverbatim
150 *>
151 *> \param[out] RWORK
152 *> \verbatim
153 *> RWORK is DOUBLE PRECISION array, dimension (N)
154 *> \endverbatim
155 *>
156 *> \param[out] INFO
157 *> \verbatim
158 *> INFO is INTEGER
159 *> = 0: successful exit
160 *> < 0: if INFO = -i, the i-th argument had an illegal value
161 *> \endverbatim
162 *
163 *> \par Internal Parameters:
164 * =========================
165 *>
166 *> \verbatim
167 *> ITMAX is the maximum number of steps of iterative refinement.
168 *> \endverbatim
169 *
170 * Authors:
171 * ========
172 *
173 *> \author Univ. of Tennessee
174 *> \author Univ. of California Berkeley
175 *> \author Univ. of Colorado Denver
176 *> \author NAG Ltd.
177 *
178 *> \ingroup complex16POcomputational
179 *
180 * =====================================================================
181  SUBROUTINE zporfs( UPLO, N, NRHS, A, LDA, AF, LDAF, B, LDB, X,
182  $ LDX, FERR, BERR, WORK, RWORK, INFO )
183 *
184 * -- LAPACK computational routine --
185 * -- LAPACK is a software package provided by Univ. of Tennessee, --
186 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
187 *
188 * .. Scalar Arguments ..
189  CHARACTER UPLO
190  INTEGER INFO, LDA, LDAF, LDB, LDX, N, NRHS
191 * ..
192 * .. Array Arguments ..
193  DOUBLE PRECISION BERR( * ), FERR( * ), RWORK( * )
194  COMPLEX*16 A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
195  $ work( * ), x( ldx, * )
196 * ..
197 *
198 * ====================================================================
199 *
200 * .. Parameters ..
201  INTEGER ITMAX
202  parameter( itmax = 5 )
203  DOUBLE PRECISION ZERO
204  parameter( zero = 0.0d+0 )
205  COMPLEX*16 ONE
206  parameter( one = ( 1.0d+0, 0.0d+0 ) )
207  DOUBLE PRECISION TWO
208  parameter( two = 2.0d+0 )
209  DOUBLE PRECISION THREE
210  parameter( three = 3.0d+0 )
211 * ..
212 * .. Local Scalars ..
213  LOGICAL UPPER
214  INTEGER COUNT, I, J, K, KASE, NZ
215  DOUBLE PRECISION EPS, LSTRES, S, SAFE1, SAFE2, SAFMIN, XK
216  COMPLEX*16 ZDUM
217 * ..
218 * .. Local Arrays ..
219  INTEGER ISAVE( 3 )
220 * ..
221 * .. External Subroutines ..
222  EXTERNAL xerbla, zaxpy, zcopy, zhemv, zlacn2, zpotrs
223 * ..
224 * .. Intrinsic Functions ..
225  INTRINSIC abs, dble, dimag, max
226 * ..
227 * .. External Functions ..
228  LOGICAL LSAME
229  DOUBLE PRECISION DLAMCH
230  EXTERNAL lsame, dlamch
231 * ..
232 * .. Statement Functions ..
233  DOUBLE PRECISION CABS1
234 * ..
235 * .. Statement Function definitions ..
236  cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )
237 * ..
238 * .. Executable Statements ..
239 *
240 * Test the input parameters.
241 *
242  info = 0
243  upper = lsame( uplo, 'U' )
244  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
245  info = -1
246  ELSE IF( n.LT.0 ) THEN
247  info = -2
248  ELSE IF( nrhs.LT.0 ) THEN
249  info = -3
250  ELSE IF( lda.LT.max( 1, n ) ) THEN
251  info = -5
252  ELSE IF( ldaf.LT.max( 1, n ) ) THEN
253  info = -7
254  ELSE IF( ldb.LT.max( 1, n ) ) THEN
255  info = -9
256  ELSE IF( ldx.LT.max( 1, n ) ) THEN
257  info = -11
258  END IF
259  IF( info.NE.0 ) THEN
260  CALL xerbla( 'ZPORFS', -info )
261  RETURN
262  END IF
263 *
264 * Quick return if possible
265 *
266  IF( n.EQ.0 .OR. nrhs.EQ.0 ) THEN
267  DO 10 j = 1, nrhs
268  ferr( j ) = zero
269  berr( j ) = zero
270  10 CONTINUE
271  RETURN
272  END IF
273 *
274 * NZ = maximum number of nonzero elements in each row of A, plus 1
275 *
276  nz = n + 1
277  eps = dlamch( 'Epsilon' )
278  safmin = dlamch( 'Safe minimum' )
279  safe1 = nz*safmin
280  safe2 = safe1 / eps
281 *
282 * Do for each right hand side
283 *
284  DO 140 j = 1, nrhs
285 *
286  count = 1
287  lstres = three
288  20 CONTINUE
289 *
290 * Loop until stopping criterion is satisfied.
291 *
292 * Compute residual R = B - A * X
293 *
294  CALL zcopy( n, b( 1, j ), 1, work, 1 )
295  CALL zhemv( uplo, n, -one, a, lda, x( 1, j ), 1, one, work, 1 )
296 *
297 * Compute componentwise relative backward error from formula
298 *
299 * max(i) ( abs(R(i)) / ( abs(A)*abs(X) + abs(B) )(i) )
300 *
301 * where abs(Z) is the componentwise absolute value of the matrix
302 * or vector Z. If the i-th component of the denominator is less
303 * than SAFE2, then SAFE1 is added to the i-th components of the
304 * numerator and denominator before dividing.
305 *
306  DO 30 i = 1, n
307  rwork( i ) = cabs1( b( i, j ) )
308  30 CONTINUE
309 *
310 * Compute abs(A)*abs(X) + abs(B).
311 *
312  IF( upper ) THEN
313  DO 50 k = 1, n
314  s = zero
315  xk = cabs1( x( k, j ) )
316  DO 40 i = 1, k - 1
317  rwork( i ) = rwork( i ) + cabs1( a( i, k ) )*xk
318  s = s + cabs1( a( i, k ) )*cabs1( x( i, j ) )
319  40 CONTINUE
320  rwork( k ) = rwork( k ) + abs( dble( a( k, k ) ) )*xk + s
321  50 CONTINUE
322  ELSE
323  DO 70 k = 1, n
324  s = zero
325  xk = cabs1( x( k, j ) )
326  rwork( k ) = rwork( k ) + abs( dble( a( k, k ) ) )*xk
327  DO 60 i = k + 1, n
328  rwork( i ) = rwork( i ) + cabs1( a( i, k ) )*xk
329  s = s + cabs1( a( i, k ) )*cabs1( x( i, j ) )
330  60 CONTINUE
331  rwork( k ) = rwork( k ) + s
332  70 CONTINUE
333  END IF
334  s = zero
335  DO 80 i = 1, n
336  IF( rwork( i ).GT.safe2 ) THEN
337  s = max( s, cabs1( work( i ) ) / rwork( i ) )
338  ELSE
339  s = max( s, ( cabs1( work( i ) )+safe1 ) /
340  $ ( rwork( i )+safe1 ) )
341  END IF
342  80 CONTINUE
343  berr( j ) = s
344 *
345 * Test stopping criterion. Continue iterating if
346 * 1) The residual BERR(J) is larger than machine epsilon, and
347 * 2) BERR(J) decreased by at least a factor of 2 during the
348 * last iteration, and
349 * 3) At most ITMAX iterations tried.
350 *
351  IF( berr( j ).GT.eps .AND. two*berr( j ).LE.lstres .AND.
352  $ count.LE.itmax ) THEN
353 *
354 * Update solution and try again.
355 *
356  CALL zpotrs( uplo, n, 1, af, ldaf, work, n, info )
357  CALL zaxpy( n, one, work, 1, x( 1, j ), 1 )
358  lstres = berr( j )
359  count = count + 1
360  GO TO 20
361  END IF
362 *
363 * Bound error from formula
364 *
365 * norm(X - XTRUE) / norm(X) .le. FERR =
366 * norm( abs(inv(A))*
367 * ( abs(R) + NZ*EPS*( abs(A)*abs(X)+abs(B) ))) / norm(X)
368 *
369 * where
370 * norm(Z) is the magnitude of the largest component of Z
371 * inv(A) is the inverse of A
372 * abs(Z) is the componentwise absolute value of the matrix or
373 * vector Z
374 * NZ is the maximum number of nonzeros in any row of A, plus 1
375 * EPS is machine epsilon
376 *
377 * The i-th component of abs(R)+NZ*EPS*(abs(A)*abs(X)+abs(B))
378 * is incremented by SAFE1 if the i-th component of
379 * abs(A)*abs(X) + abs(B) is less than SAFE2.
380 *
381 * Use ZLACN2 to estimate the infinity-norm of the matrix
382 * inv(A) * diag(W),
383 * where W = abs(R) + NZ*EPS*( abs(A)*abs(X)+abs(B) )))
384 *
385  DO 90 i = 1, n
386  IF( rwork( i ).GT.safe2 ) THEN
387  rwork( i ) = cabs1( work( i ) ) + nz*eps*rwork( i )
388  ELSE
389  rwork( i ) = cabs1( work( i ) ) + nz*eps*rwork( i ) +
390  $ safe1
391  END IF
392  90 CONTINUE
393 *
394  kase = 0
395  100 CONTINUE
396  CALL zlacn2( n, work( n+1 ), work, ferr( j ), kase, isave )
397  IF( kase.NE.0 ) THEN
398  IF( kase.EQ.1 ) THEN
399 *
400 * Multiply by diag(W)*inv(A**H).
401 *
402  CALL zpotrs( uplo, n, 1, af, ldaf, work, n, info )
403  DO 110 i = 1, n
404  work( i ) = rwork( i )*work( i )
405  110 CONTINUE
406  ELSE IF( kase.EQ.2 ) THEN
407 *
408 * Multiply by inv(A)*diag(W).
409 *
410  DO 120 i = 1, n
411  work( i ) = rwork( i )*work( i )
412  120 CONTINUE
413  CALL zpotrs( uplo, n, 1, af, ldaf, work, n, info )
414  END IF
415  GO TO 100
416  END IF
417 *
418 * Normalize error.
419 *
420  lstres = zero
421  DO 130 i = 1, n
422  lstres = max( lstres, cabs1( x( i, j ) ) )
423  130 CONTINUE
424  IF( lstres.NE.zero )
425  $ ferr( j ) = ferr( j ) / lstres
426 *
427  140 CONTINUE
428 *
429  RETURN
430 *
431 * End of ZPORFS
432 *
433  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine zaxpy(N, ZA, ZX, INCX, ZY, INCY)
ZAXPY
Definition: zaxpy.f:88
subroutine zcopy(N, ZX, INCX, ZY, INCY)
ZCOPY
Definition: zcopy.f:81
subroutine zhemv(UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
ZHEMV
Definition: zhemv.f:154
subroutine zlacn2(N, V, X, EST, KASE, ISAVE)
ZLACN2 estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vec...
Definition: zlacn2.f:133
subroutine zpotrs(UPLO, N, NRHS, A, LDA, B, LDB, INFO)
ZPOTRS
Definition: zpotrs.f:110
subroutine zporfs(UPLO, N, NRHS, A, LDA, AF, LDAF, B, LDB, X, LDX, FERR, BERR, WORK, RWORK, INFO)
ZPORFS
Definition: zporfs.f:183