LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ sgges()

subroutine sgges ( character  JOBVSL,
character  JOBVSR,
character  SORT,
external  SELCTG,
integer  N,
real, dimension( lda, * )  A,
integer  LDA,
real, dimension( ldb, * )  B,
integer  LDB,
integer  SDIM,
real, dimension( * )  ALPHAR,
real, dimension( * )  ALPHAI,
real, dimension( * )  BETA,
real, dimension( ldvsl, * )  VSL,
integer  LDVSL,
real, dimension( ldvsr, * )  VSR,
integer  LDVSR,
real, dimension( * )  WORK,
integer  LWORK,
logical, dimension( * )  BWORK,
integer  INFO 
)

SGGES computes the eigenvalues, the Schur form, and, optionally, the matrix of Schur vectors for GE matrices

Download SGGES + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 SGGES computes for a pair of N-by-N real nonsymmetric matrices (A,B),
 the generalized eigenvalues, the generalized real Schur form (S,T),
 optionally, the left and/or right matrices of Schur vectors (VSL and
 VSR). This gives the generalized Schur factorization

          (A,B) = ( (VSL)*S*(VSR)**T, (VSL)*T*(VSR)**T )

 Optionally, it also orders the eigenvalues so that a selected cluster
 of eigenvalues appears in the leading diagonal blocks of the upper
 quasi-triangular matrix S and the upper triangular matrix T.The
 leading columns of VSL and VSR then form an orthonormal basis for the
 corresponding left and right eigenspaces (deflating subspaces).

 (If only the generalized eigenvalues are needed, use the driver
 SGGEV instead, which is faster.)

 A generalized eigenvalue for a pair of matrices (A,B) is a scalar w
 or a ratio alpha/beta = w, such that  A - w*B is singular.  It is
 usually represented as the pair (alpha,beta), as there is a
 reasonable interpretation for beta=0 or both being zero.

 A pair of matrices (S,T) is in generalized real Schur form if T is
 upper triangular with non-negative diagonal and S is block upper
 triangular with 1-by-1 and 2-by-2 blocks.  1-by-1 blocks correspond
 to real generalized eigenvalues, while 2-by-2 blocks of S will be
 "standardized" by making the corresponding elements of T have the
 form:
         [  a  0  ]
         [  0  b  ]

 and the pair of corresponding 2-by-2 blocks in S and T will have a
 complex conjugate pair of generalized eigenvalues.
Parameters
[in]JOBVSL
          JOBVSL is CHARACTER*1
          = 'N':  do not compute the left Schur vectors;
          = 'V':  compute the left Schur vectors.
[in]JOBVSR
          JOBVSR is CHARACTER*1
          = 'N':  do not compute the right Schur vectors;
          = 'V':  compute the right Schur vectors.
[in]SORT
          SORT is CHARACTER*1
          Specifies whether or not to order the eigenvalues on the
          diagonal of the generalized Schur form.
          = 'N':  Eigenvalues are not ordered;
          = 'S':  Eigenvalues are ordered (see SELCTG);
[in]SELCTG
          SELCTG is a LOGICAL FUNCTION of three REAL arguments
          SELCTG must be declared EXTERNAL in the calling subroutine.
          If SORT = 'N', SELCTG is not referenced.
          If SORT = 'S', SELCTG is used to select eigenvalues to sort
          to the top left of the Schur form.
          An eigenvalue (ALPHAR(j)+ALPHAI(j))/BETA(j) is selected if
          SELCTG(ALPHAR(j),ALPHAI(j),BETA(j)) is true; i.e. if either
          one of a complex conjugate pair of eigenvalues is selected,
          then both complex eigenvalues are selected.

          Note that in the ill-conditioned case, a selected complex
          eigenvalue may no longer satisfy SELCTG(ALPHAR(j),ALPHAI(j),
          BETA(j)) = .TRUE. after ordering. INFO is to be set to N+2
          in this case.
[in]N
          N is INTEGER
          The order of the matrices A, B, VSL, and VSR.  N >= 0.
[in,out]A
          A is REAL array, dimension (LDA, N)
          On entry, the first of the pair of matrices.
          On exit, A has been overwritten by its generalized Schur
          form S.
[in]LDA
          LDA is INTEGER
          The leading dimension of A.  LDA >= max(1,N).
[in,out]B
          B is REAL array, dimension (LDB, N)
          On entry, the second of the pair of matrices.
          On exit, B has been overwritten by its generalized Schur
          form T.
[in]LDB
          LDB is INTEGER
          The leading dimension of B.  LDB >= max(1,N).
[out]SDIM
          SDIM is INTEGER
          If SORT = 'N', SDIM = 0.
          If SORT = 'S', SDIM = number of eigenvalues (after sorting)
          for which SELCTG is true.  (Complex conjugate pairs for which
          SELCTG is true for either eigenvalue count as 2.)
[out]ALPHAR
          ALPHAR is REAL array, dimension (N)
[out]ALPHAI
          ALPHAI is REAL array, dimension (N)
[out]BETA
          BETA is REAL array, dimension (N)
          On exit, (ALPHAR(j) + ALPHAI(j)*i)/BETA(j), j=1,...,N, will
          be the generalized eigenvalues.  ALPHAR(j) + ALPHAI(j)*i,
          and  BETA(j),j=1,...,N are the diagonals of the complex Schur
          form (S,T) that would result if the 2-by-2 diagonal blocks of
          the real Schur form of (A,B) were further reduced to
          triangular form using 2-by-2 complex unitary transformations.
          If ALPHAI(j) is zero, then the j-th eigenvalue is real; if
          positive, then the j-th and (j+1)-st eigenvalues are a
          complex conjugate pair, with ALPHAI(j+1) negative.

          Note: the quotients ALPHAR(j)/BETA(j) and ALPHAI(j)/BETA(j)
          may easily over- or underflow, and BETA(j) may even be zero.
          Thus, the user should avoid naively computing the ratio.
          However, ALPHAR and ALPHAI will be always less than and
          usually comparable with norm(A) in magnitude, and BETA always
          less than and usually comparable with norm(B).
[out]VSL
          VSL is REAL array, dimension (LDVSL,N)
          If JOBVSL = 'V', VSL will contain the left Schur vectors.
          Not referenced if JOBVSL = 'N'.
[in]LDVSL
          LDVSL is INTEGER
          The leading dimension of the matrix VSL. LDVSL >=1, and
          if JOBVSL = 'V', LDVSL >= N.
[out]VSR
          VSR is REAL array, dimension (LDVSR,N)
          If JOBVSR = 'V', VSR will contain the right Schur vectors.
          Not referenced if JOBVSR = 'N'.
[in]LDVSR
          LDVSR is INTEGER
          The leading dimension of the matrix VSR. LDVSR >= 1, and
          if JOBVSR = 'V', LDVSR >= N.
[out]WORK
          WORK is REAL array, dimension (MAX(1,LWORK))
          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
[in]LWORK
          LWORK is INTEGER
          The dimension of the array WORK.
          If N = 0, LWORK >= 1, else LWORK >= max(8*N,6*N+16).
          For good performance , LWORK must generally be larger.

          If LWORK = -1, then a workspace query is assumed; the routine
          only calculates the optimal size of the WORK array, returns
          this value as the first entry of the WORK array, and no error
          message related to LWORK is issued by XERBLA.
[out]BWORK
          BWORK is LOGICAL array, dimension (N)
          Not referenced if SORT = 'N'.
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value.
          = 1,...,N:
                The QZ iteration failed.  (A,B) are not in Schur
                form, but ALPHAR(j), ALPHAI(j), and BETA(j) should
                be correct for j=INFO+1,...,N.
          > N:  =N+1: other than QZ iteration failed in SHGEQZ.
                =N+2: after reordering, roundoff changed values of
                      some complex eigenvalues so that leading
                      eigenvalues in the Generalized Schur form no
                      longer satisfy SELCTG=.TRUE.  This could also
                      be caused due to scaling.
                =N+3: reordering failed in STGSEN.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 281 of file sgges.f.

284 *
285 * -- LAPACK driver routine --
286 * -- LAPACK is a software package provided by Univ. of Tennessee, --
287 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
288 *
289 * .. Scalar Arguments ..
290  CHARACTER JOBVSL, JOBVSR, SORT
291  INTEGER INFO, LDA, LDB, LDVSL, LDVSR, LWORK, N, SDIM
292 * ..
293 * .. Array Arguments ..
294  LOGICAL BWORK( * )
295  REAL A( LDA, * ), ALPHAI( * ), ALPHAR( * ),
296  $ B( LDB, * ), BETA( * ), VSL( LDVSL, * ),
297  $ VSR( LDVSR, * ), WORK( * )
298 * ..
299 * .. Function Arguments ..
300  LOGICAL SELCTG
301  EXTERNAL selctg
302 * ..
303 *
304 * =====================================================================
305 *
306 * .. Parameters ..
307  REAL ZERO, ONE
308  parameter( zero = 0.0e+0, one = 1.0e+0 )
309 * ..
310 * .. Local Scalars ..
311  LOGICAL CURSL, ILASCL, ILBSCL, ILVSL, ILVSR, LASTSL,
312  $ LQUERY, LST2SL, WANTST
313  INTEGER I, ICOLS, IERR, IHI, IJOBVL, IJOBVR, ILEFT,
314  $ ILO, IP, IRIGHT, IROWS, ITAU, IWRK, MAXWRK,
315  $ MINWRK
316  REAL ANRM, ANRMTO, BIGNUM, BNRM, BNRMTO, EPS, PVSL,
317  $ PVSR, SAFMAX, SAFMIN, SMLNUM
318 * ..
319 * .. Local Arrays ..
320  INTEGER IDUM( 1 )
321  REAL DIF( 2 )
322 * ..
323 * .. External Subroutines ..
324  EXTERNAL sgeqrf, sggbak, sggbal, sgghrd, shgeqz, slabad,
326  $ xerbla
327 * ..
328 * .. External Functions ..
329  LOGICAL LSAME
330  INTEGER ILAENV
331  REAL SLAMCH, SLANGE
332  EXTERNAL lsame, ilaenv, slamch, slange
333 * ..
334 * .. Intrinsic Functions ..
335  INTRINSIC abs, max, sqrt
336 * ..
337 * .. Executable Statements ..
338 *
339 * Decode the input arguments
340 *
341  IF( lsame( jobvsl, 'N' ) ) THEN
342  ijobvl = 1
343  ilvsl = .false.
344  ELSE IF( lsame( jobvsl, 'V' ) ) THEN
345  ijobvl = 2
346  ilvsl = .true.
347  ELSE
348  ijobvl = -1
349  ilvsl = .false.
350  END IF
351 *
352  IF( lsame( jobvsr, 'N' ) ) THEN
353  ijobvr = 1
354  ilvsr = .false.
355  ELSE IF( lsame( jobvsr, 'V' ) ) THEN
356  ijobvr = 2
357  ilvsr = .true.
358  ELSE
359  ijobvr = -1
360  ilvsr = .false.
361  END IF
362 *
363  wantst = lsame( sort, 'S' )
364 *
365 * Test the input arguments
366 *
367  info = 0
368  lquery = ( lwork.EQ.-1 )
369  IF( ijobvl.LE.0 ) THEN
370  info = -1
371  ELSE IF( ijobvr.LE.0 ) THEN
372  info = -2
373  ELSE IF( ( .NOT.wantst ) .AND. ( .NOT.lsame( sort, 'N' ) ) ) THEN
374  info = -3
375  ELSE IF( n.LT.0 ) THEN
376  info = -5
377  ELSE IF( lda.LT.max( 1, n ) ) THEN
378  info = -7
379  ELSE IF( ldb.LT.max( 1, n ) ) THEN
380  info = -9
381  ELSE IF( ldvsl.LT.1 .OR. ( ilvsl .AND. ldvsl.LT.n ) ) THEN
382  info = -15
383  ELSE IF( ldvsr.LT.1 .OR. ( ilvsr .AND. ldvsr.LT.n ) ) THEN
384  info = -17
385  END IF
386 *
387 * Compute workspace
388 * (Note: Comments in the code beginning "Workspace:" describe the
389 * minimal amount of workspace needed at that point in the code,
390 * as well as the preferred amount for good performance.
391 * NB refers to the optimal block size for the immediately
392 * following subroutine, as returned by ILAENV.)
393 *
394  IF( info.EQ.0 ) THEN
395  IF( n.GT.0 )THEN
396  minwrk = max( 8*n, 6*n + 16 )
397  maxwrk = minwrk - n +
398  $ n*ilaenv( 1, 'SGEQRF', ' ', n, 1, n, 0 )
399  maxwrk = max( maxwrk, minwrk - n +
400  $ n*ilaenv( 1, 'SORMQR', ' ', n, 1, n, -1 ) )
401  IF( ilvsl ) THEN
402  maxwrk = max( maxwrk, minwrk - n +
403  $ n*ilaenv( 1, 'SORGQR', ' ', n, 1, n, -1 ) )
404  END IF
405  ELSE
406  minwrk = 1
407  maxwrk = 1
408  END IF
409  work( 1 ) = maxwrk
410 *
411  IF( lwork.LT.minwrk .AND. .NOT.lquery )
412  $ info = -19
413  END IF
414 *
415  IF( info.NE.0 ) THEN
416  CALL xerbla( 'SGGES ', -info )
417  RETURN
418  ELSE IF( lquery ) THEN
419  RETURN
420  END IF
421 *
422 * Quick return if possible
423 *
424  IF( n.EQ.0 ) THEN
425  sdim = 0
426  RETURN
427  END IF
428 *
429 * Get machine constants
430 *
431  eps = slamch( 'P' )
432  safmin = slamch( 'S' )
433  safmax = one / safmin
434  CALL slabad( safmin, safmax )
435  smlnum = sqrt( safmin ) / eps
436  bignum = one / smlnum
437 *
438 * Scale A if max element outside range [SMLNUM,BIGNUM]
439 *
440  anrm = slange( 'M', n, n, a, lda, work )
441  ilascl = .false.
442  IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
443  anrmto = smlnum
444  ilascl = .true.
445  ELSE IF( anrm.GT.bignum ) THEN
446  anrmto = bignum
447  ilascl = .true.
448  END IF
449  IF( ilascl )
450  $ CALL slascl( 'G', 0, 0, anrm, anrmto, n, n, a, lda, ierr )
451 *
452 * Scale B if max element outside range [SMLNUM,BIGNUM]
453 *
454  bnrm = slange( 'M', n, n, b, ldb, work )
455  ilbscl = .false.
456  IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
457  bnrmto = smlnum
458  ilbscl = .true.
459  ELSE IF( bnrm.GT.bignum ) THEN
460  bnrmto = bignum
461  ilbscl = .true.
462  END IF
463  IF( ilbscl )
464  $ CALL slascl( 'G', 0, 0, bnrm, bnrmto, n, n, b, ldb, ierr )
465 *
466 * Permute the matrix to make it more nearly triangular
467 * (Workspace: need 6*N + 2*N space for storing balancing factors)
468 *
469  ileft = 1
470  iright = n + 1
471  iwrk = iright + n
472  CALL sggbal( 'P', n, a, lda, b, ldb, ilo, ihi, work( ileft ),
473  $ work( iright ), work( iwrk ), ierr )
474 *
475 * Reduce B to triangular form (QR decomposition of B)
476 * (Workspace: need N, prefer N*NB)
477 *
478  irows = ihi + 1 - ilo
479  icols = n + 1 - ilo
480  itau = iwrk
481  iwrk = itau + irows
482  CALL sgeqrf( irows, icols, b( ilo, ilo ), ldb, work( itau ),
483  $ work( iwrk ), lwork+1-iwrk, ierr )
484 *
485 * Apply the orthogonal transformation to matrix A
486 * (Workspace: need N, prefer N*NB)
487 *
488  CALL sormqr( 'L', 'T', irows, icols, irows, b( ilo, ilo ), ldb,
489  $ work( itau ), a( ilo, ilo ), lda, work( iwrk ),
490  $ lwork+1-iwrk, ierr )
491 *
492 * Initialize VSL
493 * (Workspace: need N, prefer N*NB)
494 *
495  IF( ilvsl ) THEN
496  CALL slaset( 'Full', n, n, zero, one, vsl, ldvsl )
497  IF( irows.GT.1 ) THEN
498  CALL slacpy( 'L', irows-1, irows-1, b( ilo+1, ilo ), ldb,
499  $ vsl( ilo+1, ilo ), ldvsl )
500  END IF
501  CALL sorgqr( irows, irows, irows, vsl( ilo, ilo ), ldvsl,
502  $ work( itau ), work( iwrk ), lwork+1-iwrk, ierr )
503  END IF
504 *
505 * Initialize VSR
506 *
507  IF( ilvsr )
508  $ CALL slaset( 'Full', n, n, zero, one, vsr, ldvsr )
509 *
510 * Reduce to generalized Hessenberg form
511 * (Workspace: none needed)
512 *
513  CALL sgghrd( jobvsl, jobvsr, n, ilo, ihi, a, lda, b, ldb, vsl,
514  $ ldvsl, vsr, ldvsr, ierr )
515 *
516 * Perform QZ algorithm, computing Schur vectors if desired
517 * (Workspace: need N)
518 *
519  iwrk = itau
520  CALL shgeqz( 'S', jobvsl, jobvsr, n, ilo, ihi, a, lda, b, ldb,
521  $ alphar, alphai, beta, vsl, ldvsl, vsr, ldvsr,
522  $ work( iwrk ), lwork+1-iwrk, ierr )
523  IF( ierr.NE.0 ) THEN
524  IF( ierr.GT.0 .AND. ierr.LE.n ) THEN
525  info = ierr
526  ELSE IF( ierr.GT.n .AND. ierr.LE.2*n ) THEN
527  info = ierr - n
528  ELSE
529  info = n + 1
530  END IF
531  GO TO 40
532  END IF
533 *
534 * Sort eigenvalues ALPHA/BETA if desired
535 * (Workspace: need 4*N+16 )
536 *
537  sdim = 0
538  IF( wantst ) THEN
539 *
540 * Undo scaling on eigenvalues before SELCTGing
541 *
542  IF( ilascl ) THEN
543  CALL slascl( 'G', 0, 0, anrmto, anrm, n, 1, alphar, n,
544  $ ierr )
545  CALL slascl( 'G', 0, 0, anrmto, anrm, n, 1, alphai, n,
546  $ ierr )
547  END IF
548  IF( ilbscl )
549  $ CALL slascl( 'G', 0, 0, bnrmto, bnrm, n, 1, beta, n, ierr )
550 *
551 * Select eigenvalues
552 *
553  DO 10 i = 1, n
554  bwork( i ) = selctg( alphar( i ), alphai( i ), beta( i ) )
555  10 CONTINUE
556 *
557  CALL stgsen( 0, ilvsl, ilvsr, bwork, n, a, lda, b, ldb, alphar,
558  $ alphai, beta, vsl, ldvsl, vsr, ldvsr, sdim, pvsl,
559  $ pvsr, dif, work( iwrk ), lwork-iwrk+1, idum, 1,
560  $ ierr )
561  IF( ierr.EQ.1 )
562  $ info = n + 3
563 *
564  END IF
565 *
566 * Apply back-permutation to VSL and VSR
567 * (Workspace: none needed)
568 *
569  IF( ilvsl )
570  $ CALL sggbak( 'P', 'L', n, ilo, ihi, work( ileft ),
571  $ work( iright ), n, vsl, ldvsl, ierr )
572 *
573  IF( ilvsr )
574  $ CALL sggbak( 'P', 'R', n, ilo, ihi, work( ileft ),
575  $ work( iright ), n, vsr, ldvsr, ierr )
576 *
577 * Check if unscaling would cause over/underflow, if so, rescale
578 * (ALPHAR(I),ALPHAI(I),BETA(I)) so BETA(I) is on the order of
579 * B(I,I) and ALPHAR(I) and ALPHAI(I) are on the order of A(I,I)
580 *
581  IF( ilascl )THEN
582  DO 50 i = 1, n
583  IF( alphai( i ).NE.zero ) THEN
584  IF( ( alphar( i )/safmax ).GT.( anrmto/anrm ) .OR.
585  $ ( safmin/alphar( i ) ).GT.( anrm/anrmto ) ) THEN
586  work( 1 ) = abs( a( i, i )/alphar( i ) )
587  beta( i ) = beta( i )*work( 1 )
588  alphar( i ) = alphar( i )*work( 1 )
589  alphai( i ) = alphai( i )*work( 1 )
590  ELSE IF( ( alphai( i )/safmax ).GT.( anrmto/anrm ) .OR.
591  $ ( safmin/alphai( i ) ).GT.( anrm/anrmto ) ) THEN
592  work( 1 ) = abs( a( i, i+1 )/alphai( i ) )
593  beta( i ) = beta( i )*work( 1 )
594  alphar( i ) = alphar( i )*work( 1 )
595  alphai( i ) = alphai( i )*work( 1 )
596  END IF
597  END IF
598  50 CONTINUE
599  END IF
600 *
601  IF( ilbscl )THEN
602  DO 60 i = 1, n
603  IF( alphai( i ).NE.zero ) THEN
604  IF( ( beta( i )/safmax ).GT.( bnrmto/bnrm ) .OR.
605  $ ( safmin/beta( i ) ).GT.( bnrm/bnrmto ) ) THEN
606  work( 1 ) = abs(b( i, i )/beta( i ))
607  beta( i ) = beta( i )*work( 1 )
608  alphar( i ) = alphar( i )*work( 1 )
609  alphai( i ) = alphai( i )*work( 1 )
610  END IF
611  END IF
612  60 CONTINUE
613  END IF
614 *
615 * Undo scaling
616 *
617  IF( ilascl ) THEN
618  CALL slascl( 'H', 0, 0, anrmto, anrm, n, n, a, lda, ierr )
619  CALL slascl( 'G', 0, 0, anrmto, anrm, n, 1, alphar, n, ierr )
620  CALL slascl( 'G', 0, 0, anrmto, anrm, n, 1, alphai, n, ierr )
621  END IF
622 *
623  IF( ilbscl ) THEN
624  CALL slascl( 'U', 0, 0, bnrmto, bnrm, n, n, b, ldb, ierr )
625  CALL slascl( 'G', 0, 0, bnrmto, bnrm, n, 1, beta, n, ierr )
626  END IF
627 *
628  IF( wantst ) THEN
629 *
630 * Check if reordering is correct
631 *
632  lastsl = .true.
633  lst2sl = .true.
634  sdim = 0
635  ip = 0
636  DO 30 i = 1, n
637  cursl = selctg( alphar( i ), alphai( i ), beta( i ) )
638  IF( alphai( i ).EQ.zero ) THEN
639  IF( cursl )
640  $ sdim = sdim + 1
641  ip = 0
642  IF( cursl .AND. .NOT.lastsl )
643  $ info = n + 2
644  ELSE
645  IF( ip.EQ.1 ) THEN
646 *
647 * Last eigenvalue of conjugate pair
648 *
649  cursl = cursl .OR. lastsl
650  lastsl = cursl
651  IF( cursl )
652  $ sdim = sdim + 2
653  ip = -1
654  IF( cursl .AND. .NOT.lst2sl )
655  $ info = n + 2
656  ELSE
657 *
658 * First eigenvalue of conjugate pair
659 *
660  ip = 1
661  END IF
662  END IF
663  lst2sl = lastsl
664  lastsl = cursl
665  30 CONTINUE
666 *
667  END IF
668 *
669  40 CONTINUE
670 *
671  work( 1 ) = maxwrk
672 *
673  RETURN
674 *
675 * End of SGGES
676 *
subroutine slabad(SMALL, LARGE)
SLABAD
Definition: slabad.f:74
subroutine slascl(TYPE, KL, KU, CFROM, CTO, M, N, A, LDA, INFO)
SLASCL multiplies a general rectangular matrix by a real scalar defined as cto/cfrom.
Definition: slascl.f:143
subroutine slaset(UPLO, M, N, ALPHA, BETA, A, LDA)
SLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition: slaset.f:110
subroutine slacpy(UPLO, M, N, A, LDA, B, LDB)
SLACPY copies all or part of one two-dimensional array to another.
Definition: slacpy.f:103
integer function ilaenv(ISPEC, NAME, OPTS, N1, N2, N3, N4)
ILAENV
Definition: ilaenv.f:162
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine sggbak(JOB, SIDE, N, ILO, IHI, LSCALE, RSCALE, M, V, LDV, INFO)
SGGBAK
Definition: sggbak.f:147
subroutine sggbal(JOB, N, A, LDA, B, LDB, ILO, IHI, LSCALE, RSCALE, WORK, INFO)
SGGBAL
Definition: sggbal.f:177
real function slange(NORM, M, N, A, LDA, WORK)
SLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: slange.f:114
subroutine sgeqrf(M, N, A, LDA, TAU, WORK, LWORK, INFO)
SGEQRF
Definition: sgeqrf.f:145
subroutine shgeqz(JOB, COMPQ, COMPZ, N, ILO, IHI, H, LDH, T, LDT, ALPHAR, ALPHAI, BETA, Q, LDQ, Z, LDZ, WORK, LWORK, INFO)
SHGEQZ
Definition: shgeqz.f:304
subroutine stgsen(IJOB, WANTQ, WANTZ, SELECT, N, A, LDA, B, LDB, ALPHAR, ALPHAI, BETA, Q, LDQ, Z, LDZ, M, PL, PR, DIF, WORK, LWORK, IWORK, LIWORK, INFO)
STGSEN
Definition: stgsen.f:451
subroutine sorgqr(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
SORGQR
Definition: sorgqr.f:128
subroutine sormqr(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
SORMQR
Definition: sormqr.f:168
subroutine sgghrd(COMPQ, COMPZ, N, ILO, IHI, A, LDA, B, LDB, Q, LDQ, Z, LDZ, INFO)
SGGHRD
Definition: sgghrd.f:207
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:68
Here is the call graph for this function:
Here is the caller graph for this function: