LAPACK  3.9.1
LAPACK: Linear Algebra PACKage
ctbmv.f
Go to the documentation of this file.
1 *> \brief \b CTBMV
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 * Definition:
9 * ===========
10 *
11 * SUBROUTINE CTBMV(UPLO,TRANS,DIAG,N,K,A,LDA,X,INCX)
12 *
13 * .. Scalar Arguments ..
14 * INTEGER INCX,K,LDA,N
15 * CHARACTER DIAG,TRANS,UPLO
16 * ..
17 * .. Array Arguments ..
18 * COMPLEX A(LDA,*),X(*)
19 * ..
20 *
21 *
22 *> \par Purpose:
23 * =============
24 *>
25 *> \verbatim
26 *>
27 *> CTBMV performs one of the matrix-vector operations
28 *>
29 *> x := A*x, or x := A**T*x, or x := A**H*x,
30 *>
31 *> where x is an n element vector and A is an n by n unit, or non-unit,
32 *> upper or lower triangular band matrix, with ( k + 1 ) diagonals.
33 *> \endverbatim
34 *
35 * Arguments:
36 * ==========
37 *
38 *> \param[in] UPLO
39 *> \verbatim
40 *> UPLO is CHARACTER*1
41 *> On entry, UPLO specifies whether the matrix is an upper or
42 *> lower triangular matrix as follows:
43 *>
44 *> UPLO = 'U' or 'u' A is an upper triangular matrix.
45 *>
46 *> UPLO = 'L' or 'l' A is a lower triangular matrix.
47 *> \endverbatim
48 *>
49 *> \param[in] TRANS
50 *> \verbatim
51 *> TRANS is CHARACTER*1
52 *> On entry, TRANS specifies the operation to be performed as
53 *> follows:
54 *>
55 *> TRANS = 'N' or 'n' x := A*x.
56 *>
57 *> TRANS = 'T' or 't' x := A**T*x.
58 *>
59 *> TRANS = 'C' or 'c' x := A**H*x.
60 *> \endverbatim
61 *>
62 *> \param[in] DIAG
63 *> \verbatim
64 *> DIAG is CHARACTER*1
65 *> On entry, DIAG specifies whether or not A is unit
66 *> triangular as follows:
67 *>
68 *> DIAG = 'U' or 'u' A is assumed to be unit triangular.
69 *>
70 *> DIAG = 'N' or 'n' A is not assumed to be unit
71 *> triangular.
72 *> \endverbatim
73 *>
74 *> \param[in] N
75 *> \verbatim
76 *> N is INTEGER
77 *> On entry, N specifies the order of the matrix A.
78 *> N must be at least zero.
79 *> \endverbatim
80 *>
81 *> \param[in] K
82 *> \verbatim
83 *> K is INTEGER
84 *> On entry with UPLO = 'U' or 'u', K specifies the number of
85 *> super-diagonals of the matrix A.
86 *> On entry with UPLO = 'L' or 'l', K specifies the number of
87 *> sub-diagonals of the matrix A.
88 *> K must satisfy 0 .le. K.
89 *> \endverbatim
90 *>
91 *> \param[in] A
92 *> \verbatim
93 *> A is COMPLEX array, dimension ( LDA, N ).
94 *> Before entry with UPLO = 'U' or 'u', the leading ( k + 1 )
95 *> by n part of the array A must contain the upper triangular
96 *> band part of the matrix of coefficients, supplied column by
97 *> column, with the leading diagonal of the matrix in row
98 *> ( k + 1 ) of the array, the first super-diagonal starting at
99 *> position 2 in row k, and so on. The top left k by k triangle
100 *> of the array A is not referenced.
101 *> The following program segment will transfer an upper
102 *> triangular band matrix from conventional full matrix storage
103 *> to band storage:
104 *>
105 *> DO 20, J = 1, N
106 *> M = K + 1 - J
107 *> DO 10, I = MAX( 1, J - K ), J
108 *> A( M + I, J ) = matrix( I, J )
109 *> 10 CONTINUE
110 *> 20 CONTINUE
111 *>
112 *> Before entry with UPLO = 'L' or 'l', the leading ( k + 1 )
113 *> by n part of the array A must contain the lower triangular
114 *> band part of the matrix of coefficients, supplied column by
115 *> column, with the leading diagonal of the matrix in row 1 of
116 *> the array, the first sub-diagonal starting at position 1 in
117 *> row 2, and so on. The bottom right k by k triangle of the
118 *> array A is not referenced.
119 *> The following program segment will transfer a lower
120 *> triangular band matrix from conventional full matrix storage
121 *> to band storage:
122 *>
123 *> DO 20, J = 1, N
124 *> M = 1 - J
125 *> DO 10, I = J, MIN( N, J + K )
126 *> A( M + I, J ) = matrix( I, J )
127 *> 10 CONTINUE
128 *> 20 CONTINUE
129 *>
130 *> Note that when DIAG = 'U' or 'u' the elements of the array A
131 *> corresponding to the diagonal elements of the matrix are not
132 *> referenced, but are assumed to be unity.
133 *> \endverbatim
134 *>
135 *> \param[in] LDA
136 *> \verbatim
137 *> LDA is INTEGER
138 *> On entry, LDA specifies the first dimension of A as declared
139 *> in the calling (sub) program. LDA must be at least
140 *> ( k + 1 ).
141 *> \endverbatim
142 *>
143 *> \param[in,out] X
144 *> \verbatim
145 *> X is COMPLEX array, dimension at least
146 *> ( 1 + ( n - 1 )*abs( INCX ) ).
147 *> Before entry, the incremented array X must contain the n
148 *> element vector x. On exit, X is overwritten with the
149 *> transformed vector x.
150 *> \endverbatim
151 *>
152 *> \param[in] INCX
153 *> \verbatim
154 *> INCX is INTEGER
155 *> On entry, INCX specifies the increment for the elements of
156 *> X. INCX must not be zero.
157 *> \endverbatim
158 *
159 * Authors:
160 * ========
161 *
162 *> \author Univ. of Tennessee
163 *> \author Univ. of California Berkeley
164 *> \author Univ. of Colorado Denver
165 *> \author NAG Ltd.
166 *
167 *> \ingroup complex_blas_level2
168 *
169 *> \par Further Details:
170 * =====================
171 *>
172 *> \verbatim
173 *>
174 *> Level 2 Blas routine.
175 *> The vector and matrix arguments are not referenced when N = 0, or M = 0
176 *>
177 *> -- Written on 22-October-1986.
178 *> Jack Dongarra, Argonne National Lab.
179 *> Jeremy Du Croz, Nag Central Office.
180 *> Sven Hammarling, Nag Central Office.
181 *> Richard Hanson, Sandia National Labs.
182 *> \endverbatim
183 *>
184 * =====================================================================
185  SUBROUTINE ctbmv(UPLO,TRANS,DIAG,N,K,A,LDA,X,INCX)
186 *
187 * -- Reference BLAS level2 routine --
188 * -- Reference BLAS is a software package provided by Univ. of Tennessee, --
189 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
190 *
191 * .. Scalar Arguments ..
192  INTEGER INCX,K,LDA,N
193  CHARACTER DIAG,TRANS,UPLO
194 * ..
195 * .. Array Arguments ..
196  COMPLEX A(LDA,*),X(*)
197 * ..
198 *
199 * =====================================================================
200 *
201 * .. Parameters ..
202  COMPLEX ZERO
203  parameter(zero= (0.0e+0,0.0e+0))
204 * ..
205 * .. Local Scalars ..
206  COMPLEX TEMP
207  INTEGER I,INFO,IX,J,JX,KPLUS1,KX,L
208  LOGICAL NOCONJ,NOUNIT
209 * ..
210 * .. External Functions ..
211  LOGICAL LSAME
212  EXTERNAL lsame
213 * ..
214 * .. External Subroutines ..
215  EXTERNAL xerbla
216 * ..
217 * .. Intrinsic Functions ..
218  INTRINSIC conjg,max,min
219 * ..
220 *
221 * Test the input parameters.
222 *
223  info = 0
224  IF (.NOT.lsame(uplo,'U') .AND. .NOT.lsame(uplo,'L')) THEN
225  info = 1
226  ELSE IF (.NOT.lsame(trans,'N') .AND. .NOT.lsame(trans,'T') .AND.
227  + .NOT.lsame(trans,'C')) THEN
228  info = 2
229  ELSE IF (.NOT.lsame(diag,'U') .AND. .NOT.lsame(diag,'N')) THEN
230  info = 3
231  ELSE IF (n.LT.0) THEN
232  info = 4
233  ELSE IF (k.LT.0) THEN
234  info = 5
235  ELSE IF (lda.LT. (k+1)) THEN
236  info = 7
237  ELSE IF (incx.EQ.0) THEN
238  info = 9
239  END IF
240  IF (info.NE.0) THEN
241  CALL xerbla('CTBMV ',info)
242  RETURN
243  END IF
244 *
245 * Quick return if possible.
246 *
247  IF (n.EQ.0) RETURN
248 *
249  noconj = lsame(trans,'T')
250  nounit = lsame(diag,'N')
251 *
252 * Set up the start point in X if the increment is not unity. This
253 * will be ( N - 1 )*INCX too small for descending loops.
254 *
255  IF (incx.LE.0) THEN
256  kx = 1 - (n-1)*incx
257  ELSE IF (incx.NE.1) THEN
258  kx = 1
259  END IF
260 *
261 * Start the operations. In this version the elements of A are
262 * accessed sequentially with one pass through A.
263 *
264  IF (lsame(trans,'N')) THEN
265 *
266 * Form x := A*x.
267 *
268  IF (lsame(uplo,'U')) THEN
269  kplus1 = k + 1
270  IF (incx.EQ.1) THEN
271  DO 20 j = 1,n
272  IF (x(j).NE.zero) THEN
273  temp = x(j)
274  l = kplus1 - j
275  DO 10 i = max(1,j-k),j - 1
276  x(i) = x(i) + temp*a(l+i,j)
277  10 CONTINUE
278  IF (nounit) x(j) = x(j)*a(kplus1,j)
279  END IF
280  20 CONTINUE
281  ELSE
282  jx = kx
283  DO 40 j = 1,n
284  IF (x(jx).NE.zero) THEN
285  temp = x(jx)
286  ix = kx
287  l = kplus1 - j
288  DO 30 i = max(1,j-k),j - 1
289  x(ix) = x(ix) + temp*a(l+i,j)
290  ix = ix + incx
291  30 CONTINUE
292  IF (nounit) x(jx) = x(jx)*a(kplus1,j)
293  END IF
294  jx = jx + incx
295  IF (j.GT.k) kx = kx + incx
296  40 CONTINUE
297  END IF
298  ELSE
299  IF (incx.EQ.1) THEN
300  DO 60 j = n,1,-1
301  IF (x(j).NE.zero) THEN
302  temp = x(j)
303  l = 1 - j
304  DO 50 i = min(n,j+k),j + 1,-1
305  x(i) = x(i) + temp*a(l+i,j)
306  50 CONTINUE
307  IF (nounit) x(j) = x(j)*a(1,j)
308  END IF
309  60 CONTINUE
310  ELSE
311  kx = kx + (n-1)*incx
312  jx = kx
313  DO 80 j = n,1,-1
314  IF (x(jx).NE.zero) THEN
315  temp = x(jx)
316  ix = kx
317  l = 1 - j
318  DO 70 i = min(n,j+k),j + 1,-1
319  x(ix) = x(ix) + temp*a(l+i,j)
320  ix = ix - incx
321  70 CONTINUE
322  IF (nounit) x(jx) = x(jx)*a(1,j)
323  END IF
324  jx = jx - incx
325  IF ((n-j).GE.k) kx = kx - incx
326  80 CONTINUE
327  END IF
328  END IF
329  ELSE
330 *
331 * Form x := A**T*x or x := A**H*x.
332 *
333  IF (lsame(uplo,'U')) THEN
334  kplus1 = k + 1
335  IF (incx.EQ.1) THEN
336  DO 110 j = n,1,-1
337  temp = x(j)
338  l = kplus1 - j
339  IF (noconj) THEN
340  IF (nounit) temp = temp*a(kplus1,j)
341  DO 90 i = j - 1,max(1,j-k),-1
342  temp = temp + a(l+i,j)*x(i)
343  90 CONTINUE
344  ELSE
345  IF (nounit) temp = temp*conjg(a(kplus1,j))
346  DO 100 i = j - 1,max(1,j-k),-1
347  temp = temp + conjg(a(l+i,j))*x(i)
348  100 CONTINUE
349  END IF
350  x(j) = temp
351  110 CONTINUE
352  ELSE
353  kx = kx + (n-1)*incx
354  jx = kx
355  DO 140 j = n,1,-1
356  temp = x(jx)
357  kx = kx - incx
358  ix = kx
359  l = kplus1 - j
360  IF (noconj) THEN
361  IF (nounit) temp = temp*a(kplus1,j)
362  DO 120 i = j - 1,max(1,j-k),-1
363  temp = temp + a(l+i,j)*x(ix)
364  ix = ix - incx
365  120 CONTINUE
366  ELSE
367  IF (nounit) temp = temp*conjg(a(kplus1,j))
368  DO 130 i = j - 1,max(1,j-k),-1
369  temp = temp + conjg(a(l+i,j))*x(ix)
370  ix = ix - incx
371  130 CONTINUE
372  END IF
373  x(jx) = temp
374  jx = jx - incx
375  140 CONTINUE
376  END IF
377  ELSE
378  IF (incx.EQ.1) THEN
379  DO 170 j = 1,n
380  temp = x(j)
381  l = 1 - j
382  IF (noconj) THEN
383  IF (nounit) temp = temp*a(1,j)
384  DO 150 i = j + 1,min(n,j+k)
385  temp = temp + a(l+i,j)*x(i)
386  150 CONTINUE
387  ELSE
388  IF (nounit) temp = temp*conjg(a(1,j))
389  DO 160 i = j + 1,min(n,j+k)
390  temp = temp + conjg(a(l+i,j))*x(i)
391  160 CONTINUE
392  END IF
393  x(j) = temp
394  170 CONTINUE
395  ELSE
396  jx = kx
397  DO 200 j = 1,n
398  temp = x(jx)
399  kx = kx + incx
400  ix = kx
401  l = 1 - j
402  IF (noconj) THEN
403  IF (nounit) temp = temp*a(1,j)
404  DO 180 i = j + 1,min(n,j+k)
405  temp = temp + a(l+i,j)*x(ix)
406  ix = ix + incx
407  180 CONTINUE
408  ELSE
409  IF (nounit) temp = temp*conjg(a(1,j))
410  DO 190 i = j + 1,min(n,j+k)
411  temp = temp + conjg(a(l+i,j))*x(ix)
412  ix = ix + incx
413  190 CONTINUE
414  END IF
415  x(jx) = temp
416  jx = jx + incx
417  200 CONTINUE
418  END IF
419  END IF
420  END IF
421 *
422  RETURN
423 *
424 * End of CTBMV .
425 *
426  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine ctbmv(UPLO, TRANS, DIAG, N, K, A, LDA, X, INCX)
CTBMV
Definition: ctbmv.f:186