LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ ctrti2()

subroutine ctrti2 ( character  UPLO,
character  DIAG,
integer  N,
complex, dimension( lda, * )  A,
integer  LDA,
integer  INFO 
)

CTRTI2 computes the inverse of a triangular matrix (unblocked algorithm).

Download CTRTI2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CTRTI2 computes the inverse of a complex upper or lower triangular
 matrix.

 This is the Level 2 BLAS version of the algorithm.
Parameters
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the matrix A is upper or lower triangular.
          = 'U':  Upper triangular
          = 'L':  Lower triangular
[in]DIAG
          DIAG is CHARACTER*1
          Specifies whether or not the matrix A is unit triangular.
          = 'N':  Non-unit triangular
          = 'U':  Unit triangular
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in,out]A
          A is COMPLEX array, dimension (LDA,N)
          On entry, the triangular matrix A.  If UPLO = 'U', the
          leading n by n upper triangular part of the array A contains
          the upper triangular matrix, and the strictly lower
          triangular part of A is not referenced.  If UPLO = 'L', the
          leading n by n lower triangular part of the array A contains
          the lower triangular matrix, and the strictly upper
          triangular part of A is not referenced.  If DIAG = 'U', the
          diagonal elements of A are also not referenced and are
          assumed to be 1.

          On exit, the (triangular) inverse of the original matrix, in
          the same storage format.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -k, the k-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 109 of file ctrti2.f.

110 *
111 * -- LAPACK computational routine --
112 * -- LAPACK is a software package provided by Univ. of Tennessee, --
113 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
114 *
115 * .. Scalar Arguments ..
116  CHARACTER DIAG, UPLO
117  INTEGER INFO, LDA, N
118 * ..
119 * .. Array Arguments ..
120  COMPLEX A( LDA, * )
121 * ..
122 *
123 * =====================================================================
124 *
125 * .. Parameters ..
126  COMPLEX ONE
127  parameter( one = ( 1.0e+0, 0.0e+0 ) )
128 * ..
129 * .. Local Scalars ..
130  LOGICAL NOUNIT, UPPER
131  INTEGER J
132  COMPLEX AJJ
133 * ..
134 * .. External Functions ..
135  LOGICAL LSAME
136  EXTERNAL lsame
137 * ..
138 * .. External Subroutines ..
139  EXTERNAL cscal, ctrmv, xerbla
140 * ..
141 * .. Intrinsic Functions ..
142  INTRINSIC max
143 * ..
144 * .. Executable Statements ..
145 *
146 * Test the input parameters.
147 *
148  info = 0
149  upper = lsame( uplo, 'U' )
150  nounit = lsame( diag, 'N' )
151  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
152  info = -1
153  ELSE IF( .NOT.nounit .AND. .NOT.lsame( diag, 'U' ) ) THEN
154  info = -2
155  ELSE IF( n.LT.0 ) THEN
156  info = -3
157  ELSE IF( lda.LT.max( 1, n ) ) THEN
158  info = -5
159  END IF
160  IF( info.NE.0 ) THEN
161  CALL xerbla( 'CTRTI2', -info )
162  RETURN
163  END IF
164 *
165  IF( upper ) THEN
166 *
167 * Compute inverse of upper triangular matrix.
168 *
169  DO 10 j = 1, n
170  IF( nounit ) THEN
171  a( j, j ) = one / a( j, j )
172  ajj = -a( j, j )
173  ELSE
174  ajj = -one
175  END IF
176 *
177 * Compute elements 1:j-1 of j-th column.
178 *
179  CALL ctrmv( 'Upper', 'No transpose', diag, j-1, a, lda,
180  $ a( 1, j ), 1 )
181  CALL cscal( j-1, ajj, a( 1, j ), 1 )
182  10 CONTINUE
183  ELSE
184 *
185 * Compute inverse of lower triangular matrix.
186 *
187  DO 20 j = n, 1, -1
188  IF( nounit ) THEN
189  a( j, j ) = one / a( j, j )
190  ajj = -a( j, j )
191  ELSE
192  ajj = -one
193  END IF
194  IF( j.LT.n ) THEN
195 *
196 * Compute elements j+1:n of j-th column.
197 *
198  CALL ctrmv( 'Lower', 'No transpose', diag, n-j,
199  $ a( j+1, j+1 ), lda, a( j+1, j ), 1 )
200  CALL cscal( n-j, ajj, a( j+1, j ), 1 )
201  END IF
202  20 CONTINUE
203  END IF
204 *
205  RETURN
206 *
207 * End of CTRTI2
208 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine cscal(N, CA, CX, INCX)
CSCAL
Definition: cscal.f:78
subroutine ctrmv(UPLO, TRANS, DIAG, N, A, LDA, X, INCX)
CTRMV
Definition: ctrmv.f:147
Here is the call graph for this function:
Here is the caller graph for this function: