LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ cung2r()

subroutine cung2r ( integer  M,
integer  N,
integer  K,
complex, dimension( lda, * )  A,
integer  LDA,
complex, dimension( * )  TAU,
complex, dimension( * )  WORK,
integer  INFO 
)

CUNG2R

Download CUNG2R + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CUNG2R generates an m by n complex matrix Q with orthonormal columns,
 which is defined as the first n columns of a product of k elementary
 reflectors of order m

       Q  =  H(1) H(2) . . . H(k)

 as returned by CGEQRF.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix Q. M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix Q. M >= N >= 0.
[in]K
          K is INTEGER
          The number of elementary reflectors whose product defines the
          matrix Q. N >= K >= 0.
[in,out]A
          A is COMPLEX array, dimension (LDA,N)
          On entry, the i-th column must contain the vector which
          defines the elementary reflector H(i), for i = 1,2,...,k, as
          returned by CGEQRF in the first k columns of its array
          argument A.
          On exit, the m by n matrix Q.
[in]LDA
          LDA is INTEGER
          The first dimension of the array A. LDA >= max(1,M).
[in]TAU
          TAU is COMPLEX array, dimension (K)
          TAU(i) must contain the scalar factor of the elementary
          reflector H(i), as returned by CGEQRF.
[out]WORK
          WORK is COMPLEX array, dimension (N)
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument has an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 113 of file cung2r.f.

114 *
115 * -- LAPACK computational routine --
116 * -- LAPACK is a software package provided by Univ. of Tennessee, --
117 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
118 *
119 * .. Scalar Arguments ..
120  INTEGER INFO, K, LDA, M, N
121 * ..
122 * .. Array Arguments ..
123  COMPLEX A( LDA, * ), TAU( * ), WORK( * )
124 * ..
125 *
126 * =====================================================================
127 *
128 * .. Parameters ..
129  COMPLEX ONE, ZERO
130  parameter( one = ( 1.0e+0, 0.0e+0 ),
131  $ zero = ( 0.0e+0, 0.0e+0 ) )
132 * ..
133 * .. Local Scalars ..
134  INTEGER I, J, L
135 * ..
136 * .. External Subroutines ..
137  EXTERNAL clarf, cscal, xerbla
138 * ..
139 * .. Intrinsic Functions ..
140  INTRINSIC max
141 * ..
142 * .. Executable Statements ..
143 *
144 * Test the input arguments
145 *
146  info = 0
147  IF( m.LT.0 ) THEN
148  info = -1
149  ELSE IF( n.LT.0 .OR. n.GT.m ) THEN
150  info = -2
151  ELSE IF( k.LT.0 .OR. k.GT.n ) THEN
152  info = -3
153  ELSE IF( lda.LT.max( 1, m ) ) THEN
154  info = -5
155  END IF
156  IF( info.NE.0 ) THEN
157  CALL xerbla( 'CUNG2R', -info )
158  RETURN
159  END IF
160 *
161 * Quick return if possible
162 *
163  IF( n.LE.0 )
164  $ RETURN
165 *
166 * Initialise columns k+1:n to columns of the unit matrix
167 *
168  DO 20 j = k + 1, n
169  DO 10 l = 1, m
170  a( l, j ) = zero
171  10 CONTINUE
172  a( j, j ) = one
173  20 CONTINUE
174 *
175  DO 40 i = k, 1, -1
176 *
177 * Apply H(i) to A(i:m,i:n) from the left
178 *
179  IF( i.LT.n ) THEN
180  a( i, i ) = one
181  CALL clarf( 'Left', m-i+1, n-i, a( i, i ), 1, tau( i ),
182  $ a( i, i+1 ), lda, work )
183  END IF
184  IF( i.LT.m )
185  $ CALL cscal( m-i, -tau( i ), a( i+1, i ), 1 )
186  a( i, i ) = one - tau( i )
187 *
188 * Set A(1:i-1,i) to zero
189 *
190  DO 30 l = 1, i - 1
191  a( l, i ) = zero
192  30 CONTINUE
193  40 CONTINUE
194  RETURN
195 *
196 * End of CUNG2R
197 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine cscal(N, CA, CX, INCX)
CSCAL
Definition: cscal.f:78
subroutine clarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
CLARF applies an elementary reflector to a general rectangular matrix.
Definition: clarf.f:128
Here is the call graph for this function:
Here is the caller graph for this function: