LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ clarzb()

subroutine clarzb ( character  SIDE,
character  TRANS,
character  DIRECT,
character  STOREV,
integer  M,
integer  N,
integer  K,
integer  L,
complex, dimension( ldv, * )  V,
integer  LDV,
complex, dimension( ldt, * )  T,
integer  LDT,
complex, dimension( ldc, * )  C,
integer  LDC,
complex, dimension( ldwork, * )  WORK,
integer  LDWORK 
)

CLARZB applies a block reflector or its conjugate-transpose to a general matrix.

Download CLARZB + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CLARZB applies a complex block reflector H or its transpose H**H
 to a complex distributed M-by-N  C from the left or the right.

 Currently, only STOREV = 'R' and DIRECT = 'B' are supported.
Parameters
[in]SIDE
          SIDE is CHARACTER*1
          = 'L': apply H or H**H from the Left
          = 'R': apply H or H**H from the Right
[in]TRANS
          TRANS is CHARACTER*1
          = 'N': apply H (No transpose)
          = 'C': apply H**H (Conjugate transpose)
[in]DIRECT
          DIRECT is CHARACTER*1
          Indicates how H is formed from a product of elementary
          reflectors
          = 'F': H = H(1) H(2) . . . H(k) (Forward, not supported yet)
          = 'B': H = H(k) . . . H(2) H(1) (Backward)
[in]STOREV
          STOREV is CHARACTER*1
          Indicates how the vectors which define the elementary
          reflectors are stored:
          = 'C': Columnwise                        (not supported yet)
          = 'R': Rowwise
[in]M
          M is INTEGER
          The number of rows of the matrix C.
[in]N
          N is INTEGER
          The number of columns of the matrix C.
[in]K
          K is INTEGER
          The order of the matrix T (= the number of elementary
          reflectors whose product defines the block reflector).
[in]L
          L is INTEGER
          The number of columns of the matrix V containing the
          meaningful part of the Householder reflectors.
          If SIDE = 'L', M >= L >= 0, if SIDE = 'R', N >= L >= 0.
[in]V
          V is COMPLEX array, dimension (LDV,NV).
          If STOREV = 'C', NV = K; if STOREV = 'R', NV = L.
[in]LDV
          LDV is INTEGER
          The leading dimension of the array V.
          If STOREV = 'C', LDV >= L; if STOREV = 'R', LDV >= K.
[in]T
          T is COMPLEX array, dimension (LDT,K)
          The triangular K-by-K matrix T in the representation of the
          block reflector.
[in]LDT
          LDT is INTEGER
          The leading dimension of the array T. LDT >= K.
[in,out]C
          C is COMPLEX array, dimension (LDC,N)
          On entry, the M-by-N matrix C.
          On exit, C is overwritten by H*C or H**H*C or C*H or C*H**H.
[in]LDC
          LDC is INTEGER
          The leading dimension of the array C. LDC >= max(1,M).
[out]WORK
          WORK is COMPLEX array, dimension (LDWORK,K)
[in]LDWORK
          LDWORK is INTEGER
          The leading dimension of the array WORK.
          If SIDE = 'L', LDWORK >= max(1,N);
          if SIDE = 'R', LDWORK >= max(1,M).
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Contributors:
A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA
Further Details:
 

Definition at line 181 of file clarzb.f.

183 *
184 * -- LAPACK computational routine --
185 * -- LAPACK is a software package provided by Univ. of Tennessee, --
186 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
187 *
188 * .. Scalar Arguments ..
189  CHARACTER DIRECT, SIDE, STOREV, TRANS
190  INTEGER K, L, LDC, LDT, LDV, LDWORK, M, N
191 * ..
192 * .. Array Arguments ..
193  COMPLEX C( LDC, * ), T( LDT, * ), V( LDV, * ),
194  $ WORK( LDWORK, * )
195 * ..
196 *
197 * =====================================================================
198 *
199 * .. Parameters ..
200  COMPLEX ONE
201  parameter( one = ( 1.0e+0, 0.0e+0 ) )
202 * ..
203 * .. Local Scalars ..
204  CHARACTER TRANST
205  INTEGER I, INFO, J
206 * ..
207 * .. External Functions ..
208  LOGICAL LSAME
209  EXTERNAL lsame
210 * ..
211 * .. External Subroutines ..
212  EXTERNAL ccopy, cgemm, clacgv, ctrmm, xerbla
213 * ..
214 * .. Executable Statements ..
215 *
216 * Quick return if possible
217 *
218  IF( m.LE.0 .OR. n.LE.0 )
219  $ RETURN
220 *
221 * Check for currently supported options
222 *
223  info = 0
224  IF( .NOT.lsame( direct, 'B' ) ) THEN
225  info = -3
226  ELSE IF( .NOT.lsame( storev, 'R' ) ) THEN
227  info = -4
228  END IF
229  IF( info.NE.0 ) THEN
230  CALL xerbla( 'CLARZB', -info )
231  RETURN
232  END IF
233 *
234  IF( lsame( trans, 'N' ) ) THEN
235  transt = 'C'
236  ELSE
237  transt = 'N'
238  END IF
239 *
240  IF( lsame( side, 'L' ) ) THEN
241 *
242 * Form H * C or H**H * C
243 *
244 * W( 1:n, 1:k ) = C( 1:k, 1:n )**H
245 *
246  DO 10 j = 1, k
247  CALL ccopy( n, c( j, 1 ), ldc, work( 1, j ), 1 )
248  10 CONTINUE
249 *
250 * W( 1:n, 1:k ) = W( 1:n, 1:k ) + ...
251 * C( m-l+1:m, 1:n )**H * V( 1:k, 1:l )**T
252 *
253  IF( l.GT.0 )
254  $ CALL cgemm( 'Transpose', 'Conjugate transpose', n, k, l,
255  $ one, c( m-l+1, 1 ), ldc, v, ldv, one, work,
256  $ ldwork )
257 *
258 * W( 1:n, 1:k ) = W( 1:n, 1:k ) * T**T or W( 1:m, 1:k ) * T
259 *
260  CALL ctrmm( 'Right', 'Lower', transt, 'Non-unit', n, k, one, t,
261  $ ldt, work, ldwork )
262 *
263 * C( 1:k, 1:n ) = C( 1:k, 1:n ) - W( 1:n, 1:k )**H
264 *
265  DO 30 j = 1, n
266  DO 20 i = 1, k
267  c( i, j ) = c( i, j ) - work( j, i )
268  20 CONTINUE
269  30 CONTINUE
270 *
271 * C( m-l+1:m, 1:n ) = C( m-l+1:m, 1:n ) - ...
272 * V( 1:k, 1:l )**H * W( 1:n, 1:k )**H
273 *
274  IF( l.GT.0 )
275  $ CALL cgemm( 'Transpose', 'Transpose', l, n, k, -one, v, ldv,
276  $ work, ldwork, one, c( m-l+1, 1 ), ldc )
277 *
278  ELSE IF( lsame( side, 'R' ) ) THEN
279 *
280 * Form C * H or C * H**H
281 *
282 * W( 1:m, 1:k ) = C( 1:m, 1:k )
283 *
284  DO 40 j = 1, k
285  CALL ccopy( m, c( 1, j ), 1, work( 1, j ), 1 )
286  40 CONTINUE
287 *
288 * W( 1:m, 1:k ) = W( 1:m, 1:k ) + ...
289 * C( 1:m, n-l+1:n ) * V( 1:k, 1:l )**H
290 *
291  IF( l.GT.0 )
292  $ CALL cgemm( 'No transpose', 'Transpose', m, k, l, one,
293  $ c( 1, n-l+1 ), ldc, v, ldv, one, work, ldwork )
294 *
295 * W( 1:m, 1:k ) = W( 1:m, 1:k ) * conjg( T ) or
296 * W( 1:m, 1:k ) * T**H
297 *
298  DO 50 j = 1, k
299  CALL clacgv( k-j+1, t( j, j ), 1 )
300  50 CONTINUE
301  CALL ctrmm( 'Right', 'Lower', trans, 'Non-unit', m, k, one, t,
302  $ ldt, work, ldwork )
303  DO 60 j = 1, k
304  CALL clacgv( k-j+1, t( j, j ), 1 )
305  60 CONTINUE
306 *
307 * C( 1:m, 1:k ) = C( 1:m, 1:k ) - W( 1:m, 1:k )
308 *
309  DO 80 j = 1, k
310  DO 70 i = 1, m
311  c( i, j ) = c( i, j ) - work( i, j )
312  70 CONTINUE
313  80 CONTINUE
314 *
315 * C( 1:m, n-l+1:n ) = C( 1:m, n-l+1:n ) - ...
316 * W( 1:m, 1:k ) * conjg( V( 1:k, 1:l ) )
317 *
318  DO 90 j = 1, l
319  CALL clacgv( k, v( 1, j ), 1 )
320  90 CONTINUE
321  IF( l.GT.0 )
322  $ CALL cgemm( 'No transpose', 'No transpose', m, l, k, -one,
323  $ work, ldwork, v, ldv, one, c( 1, n-l+1 ), ldc )
324  DO 100 j = 1, l
325  CALL clacgv( k, v( 1, j ), 1 )
326  100 CONTINUE
327 *
328  END IF
329 *
330  RETURN
331 *
332 * End of CLARZB
333 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine ccopy(N, CX, INCX, CY, INCY)
CCOPY
Definition: ccopy.f:81
subroutine cgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
CGEMM
Definition: cgemm.f:187
subroutine ctrmm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
CTRMM
Definition: ctrmm.f:177
subroutine clacgv(N, X, INCX)
CLACGV conjugates a complex vector.
Definition: clacgv.f:74
Here is the call graph for this function:
Here is the caller graph for this function: