LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ cunml2()

subroutine cunml2 ( character  SIDE,
character  TRANS,
integer  M,
integer  N,
integer  K,
complex, dimension( lda, * )  A,
integer  LDA,
complex, dimension( * )  TAU,
complex, dimension( ldc, * )  C,
integer  LDC,
complex, dimension( * )  WORK,
integer  INFO 
)

CUNML2 multiplies a general matrix by the unitary matrix from a LQ factorization determined by cgelqf (unblocked algorithm).

Download CUNML2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CUNML2 overwrites the general complex m-by-n matrix C with

       Q * C  if SIDE = 'L' and TRANS = 'N', or

       Q**H* C  if SIDE = 'L' and TRANS = 'C', or

       C * Q  if SIDE = 'R' and TRANS = 'N', or

       C * Q**H if SIDE = 'R' and TRANS = 'C',

 where Q is a complex unitary matrix defined as the product of k
 elementary reflectors

       Q = H(k)**H . . . H(2)**H H(1)**H

 as returned by CGELQF. Q is of order m if SIDE = 'L' and of order n
 if SIDE = 'R'.
Parameters
[in]SIDE
          SIDE is CHARACTER*1
          = 'L': apply Q or Q**H from the Left
          = 'R': apply Q or Q**H from the Right
[in]TRANS
          TRANS is CHARACTER*1
          = 'N': apply Q  (No transpose)
          = 'C': apply Q**H (Conjugate transpose)
[in]M
          M is INTEGER
          The number of rows of the matrix C. M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix C. N >= 0.
[in]K
          K is INTEGER
          The number of elementary reflectors whose product defines
          the matrix Q.
          If SIDE = 'L', M >= K >= 0;
          if SIDE = 'R', N >= K >= 0.
[in]A
          A is COMPLEX array, dimension
                               (LDA,M) if SIDE = 'L',
                               (LDA,N) if SIDE = 'R'
          The i-th row must contain the vector which defines the
          elementary reflector H(i), for i = 1,2,...,k, as returned by
          CGELQF in the first k rows of its array argument A.
          A is modified by the routine but restored on exit.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A. LDA >= max(1,K).
[in]TAU
          TAU is COMPLEX array, dimension (K)
          TAU(i) must contain the scalar factor of the elementary
          reflector H(i), as returned by CGELQF.
[in,out]C
          C is COMPLEX array, dimension (LDC,N)
          On entry, the m-by-n matrix C.
          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
[in]LDC
          LDC is INTEGER
          The leading dimension of the array C. LDC >= max(1,M).
[out]WORK
          WORK is COMPLEX array, dimension
                                   (N) if SIDE = 'L',
                                   (M) if SIDE = 'R'
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 157 of file cunml2.f.

159 *
160 * -- LAPACK computational routine --
161 * -- LAPACK is a software package provided by Univ. of Tennessee, --
162 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
163 *
164 * .. Scalar Arguments ..
165  CHARACTER SIDE, TRANS
166  INTEGER INFO, K, LDA, LDC, M, N
167 * ..
168 * .. Array Arguments ..
169  COMPLEX A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
170 * ..
171 *
172 * =====================================================================
173 *
174 * .. Parameters ..
175  COMPLEX ONE
176  parameter( one = ( 1.0e+0, 0.0e+0 ) )
177 * ..
178 * .. Local Scalars ..
179  LOGICAL LEFT, NOTRAN
180  INTEGER I, I1, I2, I3, IC, JC, MI, NI, NQ
181  COMPLEX AII, TAUI
182 * ..
183 * .. External Functions ..
184  LOGICAL LSAME
185  EXTERNAL lsame
186 * ..
187 * .. External Subroutines ..
188  EXTERNAL clacgv, clarf, xerbla
189 * ..
190 * .. Intrinsic Functions ..
191  INTRINSIC conjg, max
192 * ..
193 * .. Executable Statements ..
194 *
195 * Test the input arguments
196 *
197  info = 0
198  left = lsame( side, 'L' )
199  notran = lsame( trans, 'N' )
200 *
201 * NQ is the order of Q
202 *
203  IF( left ) THEN
204  nq = m
205  ELSE
206  nq = n
207  END IF
208  IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
209  info = -1
210  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
211  info = -2
212  ELSE IF( m.LT.0 ) THEN
213  info = -3
214  ELSE IF( n.LT.0 ) THEN
215  info = -4
216  ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
217  info = -5
218  ELSE IF( lda.LT.max( 1, k ) ) THEN
219  info = -7
220  ELSE IF( ldc.LT.max( 1, m ) ) THEN
221  info = -10
222  END IF
223  IF( info.NE.0 ) THEN
224  CALL xerbla( 'CUNML2', -info )
225  RETURN
226  END IF
227 *
228 * Quick return if possible
229 *
230  IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 )
231  $ RETURN
232 *
233  IF( ( left .AND. notran .OR. .NOT.left .AND. .NOT.notran ) ) THEN
234  i1 = 1
235  i2 = k
236  i3 = 1
237  ELSE
238  i1 = k
239  i2 = 1
240  i3 = -1
241  END IF
242 *
243  IF( left ) THEN
244  ni = n
245  jc = 1
246  ELSE
247  mi = m
248  ic = 1
249  END IF
250 *
251  DO 10 i = i1, i2, i3
252  IF( left ) THEN
253 *
254 * H(i) or H(i)**H is applied to C(i:m,1:n)
255 *
256  mi = m - i + 1
257  ic = i
258  ELSE
259 *
260 * H(i) or H(i)**H is applied to C(1:m,i:n)
261 *
262  ni = n - i + 1
263  jc = i
264  END IF
265 *
266 * Apply H(i) or H(i)**H
267 *
268  IF( notran ) THEN
269  taui = conjg( tau( i ) )
270  ELSE
271  taui = tau( i )
272  END IF
273  IF( i.LT.nq )
274  $ CALL clacgv( nq-i, a( i, i+1 ), lda )
275  aii = a( i, i )
276  a( i, i ) = one
277  CALL clarf( side, mi, ni, a( i, i ), lda, taui, c( ic, jc ),
278  $ ldc, work )
279  a( i, i ) = aii
280  IF( i.LT.nq )
281  $ CALL clacgv( nq-i, a( i, i+1 ), lda )
282  10 CONTINUE
283  RETURN
284 *
285 * End of CUNML2
286 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine clacgv(N, X, INCX)
CLACGV conjugates a complex vector.
Definition: clacgv.f:74
subroutine clarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
CLARF applies an elementary reflector to a general rectangular matrix.
Definition: clarf.f:128
Here is the call graph for this function:
Here is the caller graph for this function: