 LAPACK  3.10.0 LAPACK: Linear Algebra PACKage

## ◆ claed7()

 subroutine claed7 ( integer N, integer CUTPNT, integer QSIZ, integer TLVLS, integer CURLVL, integer CURPBM, real, dimension( * ) D, complex, dimension( ldq, * ) Q, integer LDQ, real RHO, integer, dimension( * ) INDXQ, real, dimension( * ) QSTORE, integer, dimension( * ) QPTR, integer, dimension( * ) PRMPTR, integer, dimension( * ) PERM, integer, dimension( * ) GIVPTR, integer, dimension( 2, * ) GIVCOL, real, dimension( 2, * ) GIVNUM, complex, dimension( * ) WORK, real, dimension( * ) RWORK, integer, dimension( * ) IWORK, integer INFO )

CLAED7 used by CSTEDC. Computes the updated eigensystem of a diagonal matrix after modification by a rank-one symmetric matrix. Used when the original matrix is dense.

Purpose:
``` CLAED7 computes the updated eigensystem of a diagonal
matrix after modification by a rank-one symmetric matrix. This
routine is used only for the eigenproblem which requires all
eigenvalues and optionally eigenvectors of a dense or banded
Hermitian matrix that has been reduced to tridiagonal form.

T = Q(in) ( D(in) + RHO * Z*Z**H ) Q**H(in) = Q(out) * D(out) * Q**H(out)

where Z = Q**Hu, u is a vector of length N with ones in the
CUTPNT and CUTPNT + 1 th elements and zeros elsewhere.

The eigenvectors of the original matrix are stored in Q, and the
eigenvalues are in D.  The algorithm consists of three stages:

The first stage consists of deflating the size of the problem
when there are multiple eigenvalues or if there is a zero in
the Z vector.  For each such occurrence the dimension of the
secular equation problem is reduced by one.  This stage is
performed by the routine SLAED2.

The second stage consists of calculating the updated
eigenvalues. This is done by finding the roots of the secular
equation via the routine SLAED4 (as called by SLAED3).
This routine also calculates the eigenvectors of the current
problem.

The final stage consists of computing the updated eigenvectors
directly using the updated eigenvalues.  The eigenvectors for
the current problem are multiplied with the eigenvectors from
the overall problem.```
Parameters
 [in] N ``` N is INTEGER The dimension of the symmetric tridiagonal matrix. N >= 0.``` [in] CUTPNT ``` CUTPNT is INTEGER Contains the location of the last eigenvalue in the leading sub-matrix. min(1,N) <= CUTPNT <= N.``` [in] QSIZ ``` QSIZ is INTEGER The dimension of the unitary matrix used to reduce the full matrix to tridiagonal form. QSIZ >= N.``` [in] TLVLS ``` TLVLS is INTEGER The total number of merging levels in the overall divide and conquer tree.``` [in] CURLVL ``` CURLVL is INTEGER The current level in the overall merge routine, 0 <= curlvl <= tlvls.``` [in] CURPBM ``` CURPBM is INTEGER The current problem in the current level in the overall merge routine (counting from upper left to lower right).``` [in,out] D ``` D is REAL array, dimension (N) On entry, the eigenvalues of the rank-1-perturbed matrix. On exit, the eigenvalues of the repaired matrix.``` [in,out] Q ``` Q is COMPLEX array, dimension (LDQ,N) On entry, the eigenvectors of the rank-1-perturbed matrix. On exit, the eigenvectors of the repaired tridiagonal matrix.``` [in] LDQ ``` LDQ is INTEGER The leading dimension of the array Q. LDQ >= max(1,N).``` [in] RHO ``` RHO is REAL Contains the subdiagonal element used to create the rank-1 modification.``` [out] INDXQ ``` INDXQ is INTEGER array, dimension (N) This contains the permutation which will reintegrate the subproblem just solved back into sorted order, ie. D( INDXQ( I = 1, N ) ) will be in ascending order.``` [out] IWORK ` IWORK is INTEGER array, dimension (4*N)` [out] RWORK ``` RWORK is REAL array, dimension (3*N+2*QSIZ*N)``` [out] WORK ` WORK is COMPLEX array, dimension (QSIZ*N)` [in,out] QSTORE ``` QSTORE is REAL array, dimension (N**2+1) Stores eigenvectors of submatrices encountered during divide and conquer, packed together. QPTR points to beginning of the submatrices.``` [in,out] QPTR ``` QPTR is INTEGER array, dimension (N+2) List of indices pointing to beginning of submatrices stored in QSTORE. The submatrices are numbered starting at the bottom left of the divide and conquer tree, from left to right and bottom to top.``` [in] PRMPTR ``` PRMPTR is INTEGER array, dimension (N lg N) Contains a list of pointers which indicate where in PERM a level's permutation is stored. PRMPTR(i+1) - PRMPTR(i) indicates the size of the permutation and also the size of the full, non-deflated problem.``` [in] PERM ``` PERM is INTEGER array, dimension (N lg N) Contains the permutations (from deflation and sorting) to be applied to each eigenblock.``` [in] GIVPTR ``` GIVPTR is INTEGER array, dimension (N lg N) Contains a list of pointers which indicate where in GIVCOL a level's Givens rotations are stored. GIVPTR(i+1) - GIVPTR(i) indicates the number of Givens rotations.``` [in] GIVCOL ``` GIVCOL is INTEGER array, dimension (2, N lg N) Each pair of numbers indicates a pair of columns to take place in a Givens rotation.``` [in] GIVNUM ``` GIVNUM is REAL array, dimension (2, N lg N) Each number indicates the S value to be used in the corresponding Givens rotation.``` [out] INFO ``` INFO is INTEGER = 0: successful exit. < 0: if INFO = -i, the i-th argument had an illegal value. > 0: if INFO = 1, an eigenvalue did not converge```

Definition at line 245 of file claed7.f.

249 *
250 * -- LAPACK computational routine --
251 * -- LAPACK is a software package provided by Univ. of Tennessee, --
252 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
253 *
254 * .. Scalar Arguments ..
255  INTEGER CURLVL, CURPBM, CUTPNT, INFO, LDQ, N, QSIZ,
256  \$ TLVLS
257  REAL RHO
258 * ..
259 * .. Array Arguments ..
260  INTEGER GIVCOL( 2, * ), GIVPTR( * ), INDXQ( * ),
261  \$ IWORK( * ), PERM( * ), PRMPTR( * ), QPTR( * )
262  REAL D( * ), GIVNUM( 2, * ), QSTORE( * ), RWORK( * )
263  COMPLEX Q( LDQ, * ), WORK( * )
264 * ..
265 *
266 * =====================================================================
267 *
268 * .. Local Scalars ..
269  INTEGER COLTYP, CURR, I, IDLMDA, INDX,
270  \$ INDXC, INDXP, IQ, IW, IZ, K, N1, N2, PTR
271 * ..
272 * .. External Subroutines ..
273  EXTERNAL clacrm, claed8, slaed9, slaeda, slamrg, xerbla
274 * ..
275 * .. Intrinsic Functions ..
276  INTRINSIC max, min
277 * ..
278 * .. Executable Statements ..
279 *
280 * Test the input parameters.
281 *
282  info = 0
283 *
284 * IF( ICOMPQ.LT.0 .OR. ICOMPQ.GT.1 ) THEN
285 * INFO = -1
286 * ELSE IF( N.LT.0 ) THEN
287  IF( n.LT.0 ) THEN
288  info = -1
289  ELSE IF( min( 1, n ).GT.cutpnt .OR. n.LT.cutpnt ) THEN
290  info = -2
291  ELSE IF( qsiz.LT.n ) THEN
292  info = -3
293  ELSE IF( ldq.LT.max( 1, n ) ) THEN
294  info = -9
295  END IF
296  IF( info.NE.0 ) THEN
297  CALL xerbla( 'CLAED7', -info )
298  RETURN
299  END IF
300 *
301 * Quick return if possible
302 *
303  IF( n.EQ.0 )
304  \$ RETURN
305 *
306 * The following values are for bookkeeping purposes only. They are
307 * integer pointers which indicate the portion of the workspace
308 * used by a particular array in SLAED2 and SLAED3.
309 *
310  iz = 1
311  idlmda = iz + n
312  iw = idlmda + n
313  iq = iw + n
314 *
315  indx = 1
316  indxc = indx + n
317  coltyp = indxc + n
318  indxp = coltyp + n
319 *
320 * Form the z-vector which consists of the last row of Q_1 and the
321 * first row of Q_2.
322 *
323  ptr = 1 + 2**tlvls
324  DO 10 i = 1, curlvl - 1
325  ptr = ptr + 2**( tlvls-i )
326  10 CONTINUE
327  curr = ptr + curpbm
328  CALL slaeda( n, tlvls, curlvl, curpbm, prmptr, perm, givptr,
329  \$ givcol, givnum, qstore, qptr, rwork( iz ),
330  \$ rwork( iz+n ), info )
331 *
332 * When solving the final problem, we no longer need the stored data,
333 * so we will overwrite the data from this level onto the previously
334 * used storage space.
335 *
336  IF( curlvl.EQ.tlvls ) THEN
337  qptr( curr ) = 1
338  prmptr( curr ) = 1
339  givptr( curr ) = 1
340  END IF
341 *
342 * Sort and Deflate eigenvalues.
343 *
344  CALL claed8( k, n, qsiz, q, ldq, d, rho, cutpnt, rwork( iz ),
345  \$ rwork( idlmda ), work, qsiz, rwork( iw ),
346  \$ iwork( indxp ), iwork( indx ), indxq,
347  \$ perm( prmptr( curr ) ), givptr( curr+1 ),
348  \$ givcol( 1, givptr( curr ) ),
349  \$ givnum( 1, givptr( curr ) ), info )
350  prmptr( curr+1 ) = prmptr( curr ) + n
351  givptr( curr+1 ) = givptr( curr+1 ) + givptr( curr )
352 *
353 * Solve Secular Equation.
354 *
355  IF( k.NE.0 ) THEN
356  CALL slaed9( k, 1, k, n, d, rwork( iq ), k, rho,
357  \$ rwork( idlmda ), rwork( iw ),
358  \$ qstore( qptr( curr ) ), k, info )
359  CALL clacrm( qsiz, k, work, qsiz, qstore( qptr( curr ) ), k, q,
360  \$ ldq, rwork( iq ) )
361  qptr( curr+1 ) = qptr( curr ) + k**2
362  IF( info.NE.0 ) THEN
363  RETURN
364  END IF
365 *
366 * Prepare the INDXQ sorting premutation.
367 *
368  n1 = k
369  n2 = n - k
370  CALL slamrg( n1, n2, d, 1, -1, indxq )
371  ELSE
372  qptr( curr+1 ) = qptr( curr )
373  DO 20 i = 1, n
374  indxq( i ) = i
375  20 CONTINUE
376  END IF
377 *
378  RETURN
379 *
380 * End of CLAED7
381 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine slamrg(N1, N2, A, STRD1, STRD2, INDEX)
SLAMRG creates a permutation list to merge the entries of two independently sorted sets into a single...
Definition: slamrg.f:99
subroutine slaed9(K, KSTART, KSTOP, N, D, Q, LDQ, RHO, DLAMDA, W, S, LDS, INFO)
SLAED9 used by SSTEDC. Finds the roots of the secular equation and updates the eigenvectors....
Definition: slaed9.f:156
subroutine slaeda(N, TLVLS, CURLVL, CURPBM, PRMPTR, PERM, GIVPTR, GIVCOL, GIVNUM, Q, QPTR, Z, ZTEMP, INFO)
SLAEDA used by SSTEDC. Computes the Z vector determining the rank-one modification of the diagonal ma...
Definition: slaeda.f:166
subroutine clacrm(M, N, A, LDA, B, LDB, C, LDC, RWORK)
CLACRM multiplies a complex matrix by a square real matrix.
Definition: clacrm.f:114
subroutine claed8(K, N, QSIZ, Q, LDQ, D, RHO, CUTPNT, Z, DLAMDA, Q2, LDQ2, W, INDXP, INDX, INDXQ, PERM, GIVPTR, GIVCOL, GIVNUM, INFO)
CLAED8 used by CSTEDC. Merges eigenvalues and deflates secular equation. Used when the original matri...
Definition: claed8.f:228
Here is the call graph for this function:
Here is the caller graph for this function: