LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ ctpcon()

subroutine ctpcon ( character  NORM,
character  UPLO,
character  DIAG,
integer  N,
complex, dimension( * )  AP,
real  RCOND,
complex, dimension( * )  WORK,
real, dimension( * )  RWORK,
integer  INFO 
)

CTPCON

Download CTPCON + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CTPCON estimates the reciprocal of the condition number of a packed
 triangular matrix A, in either the 1-norm or the infinity-norm.

 The norm of A is computed and an estimate is obtained for
 norm(inv(A)), then the reciprocal of the condition number is
 computed as
    RCOND = 1 / ( norm(A) * norm(inv(A)) ).
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies whether the 1-norm condition number or the
          infinity-norm condition number is required:
          = '1' or 'O':  1-norm;
          = 'I':         Infinity-norm.
[in]UPLO
          UPLO is CHARACTER*1
          = 'U':  A is upper triangular;
          = 'L':  A is lower triangular.
[in]DIAG
          DIAG is CHARACTER*1
          = 'N':  A is non-unit triangular;
          = 'U':  A is unit triangular.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in]AP
          AP is COMPLEX array, dimension (N*(N+1)/2)
          The upper or lower triangular matrix A, packed columnwise in
          a linear array.  The j-th column of A is stored in the array
          AP as follows:
          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
          If DIAG = 'U', the diagonal elements of A are not referenced
          and are assumed to be 1.
[out]RCOND
          RCOND is REAL
          The reciprocal of the condition number of the matrix A,
          computed as RCOND = 1/(norm(A) * norm(inv(A))).
[out]WORK
          WORK is COMPLEX array, dimension (2*N)
[out]RWORK
          RWORK is REAL array, dimension (N)
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 128 of file ctpcon.f.

130 *
131 * -- LAPACK computational routine --
132 * -- LAPACK is a software package provided by Univ. of Tennessee, --
133 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
134 *
135 * .. Scalar Arguments ..
136  CHARACTER DIAG, NORM, UPLO
137  INTEGER INFO, N
138  REAL RCOND
139 * ..
140 * .. Array Arguments ..
141  REAL RWORK( * )
142  COMPLEX AP( * ), WORK( * )
143 * ..
144 *
145 * =====================================================================
146 *
147 * .. Parameters ..
148  REAL ONE, ZERO
149  parameter( one = 1.0e+0, zero = 0.0e+0 )
150 * ..
151 * .. Local Scalars ..
152  LOGICAL NOUNIT, ONENRM, UPPER
153  CHARACTER NORMIN
154  INTEGER IX, KASE, KASE1
155  REAL AINVNM, ANORM, SCALE, SMLNUM, XNORM
156  COMPLEX ZDUM
157 * ..
158 * .. Local Arrays ..
159  INTEGER ISAVE( 3 )
160 * ..
161 * .. External Functions ..
162  LOGICAL LSAME
163  INTEGER ICAMAX
164  REAL CLANTP, SLAMCH
165  EXTERNAL lsame, icamax, clantp, slamch
166 * ..
167 * .. External Subroutines ..
168  EXTERNAL clacn2, clatps, csrscl, xerbla
169 * ..
170 * .. Intrinsic Functions ..
171  INTRINSIC abs, aimag, max, real
172 * ..
173 * .. Statement Functions ..
174  REAL CABS1
175 * ..
176 * .. Statement Function definitions ..
177  cabs1( zdum ) = abs( real( zdum ) ) + abs( aimag( zdum ) )
178 * ..
179 * .. Executable Statements ..
180 *
181 * Test the input parameters.
182 *
183  info = 0
184  upper = lsame( uplo, 'U' )
185  onenrm = norm.EQ.'1' .OR. lsame( norm, 'O' )
186  nounit = lsame( diag, 'N' )
187 *
188  IF( .NOT.onenrm .AND. .NOT.lsame( norm, 'I' ) ) THEN
189  info = -1
190  ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
191  info = -2
192  ELSE IF( .NOT.nounit .AND. .NOT.lsame( diag, 'U' ) ) THEN
193  info = -3
194  ELSE IF( n.LT.0 ) THEN
195  info = -4
196  END IF
197  IF( info.NE.0 ) THEN
198  CALL xerbla( 'CTPCON', -info )
199  RETURN
200  END IF
201 *
202 * Quick return if possible
203 *
204  IF( n.EQ.0 ) THEN
205  rcond = one
206  RETURN
207  END IF
208 *
209  rcond = zero
210  smlnum = slamch( 'Safe minimum' )*real( max( 1, n ) )
211 *
212 * Compute the norm of the triangular matrix A.
213 *
214  anorm = clantp( norm, uplo, diag, n, ap, rwork )
215 *
216 * Continue only if ANORM > 0.
217 *
218  IF( anorm.GT.zero ) THEN
219 *
220 * Estimate the norm of the inverse of A.
221 *
222  ainvnm = zero
223  normin = 'N'
224  IF( onenrm ) THEN
225  kase1 = 1
226  ELSE
227  kase1 = 2
228  END IF
229  kase = 0
230  10 CONTINUE
231  CALL clacn2( n, work( n+1 ), work, ainvnm, kase, isave )
232  IF( kase.NE.0 ) THEN
233  IF( kase.EQ.kase1 ) THEN
234 *
235 * Multiply by inv(A).
236 *
237  CALL clatps( uplo, 'No transpose', diag, normin, n, ap,
238  $ work, scale, rwork, info )
239  ELSE
240 *
241 * Multiply by inv(A**H).
242 *
243  CALL clatps( uplo, 'Conjugate transpose', diag, normin,
244  $ n, ap, work, scale, rwork, info )
245  END IF
246  normin = 'Y'
247 *
248 * Multiply by 1/SCALE if doing so will not cause overflow.
249 *
250  IF( scale.NE.one ) THEN
251  ix = icamax( n, work, 1 )
252  xnorm = cabs1( work( ix ) )
253  IF( scale.LT.xnorm*smlnum .OR. scale.EQ.zero )
254  $ GO TO 20
255  CALL csrscl( n, scale, work, 1 )
256  END IF
257  GO TO 10
258  END IF
259 *
260 * Compute the estimate of the reciprocal condition number.
261 *
262  IF( ainvnm.NE.zero )
263  $ rcond = ( one / anorm ) / ainvnm
264  END IF
265 *
266  20 CONTINUE
267  RETURN
268 *
269 * End of CTPCON
270 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
integer function icamax(N, CX, INCX)
ICAMAX
Definition: icamax.f:71
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine csrscl(N, SA, SX, INCX)
CSRSCL multiplies a vector by the reciprocal of a real scalar.
Definition: csrscl.f:84
subroutine clatps(UPLO, TRANS, DIAG, NORMIN, N, AP, X, SCALE, CNORM, INFO)
CLATPS solves a triangular system of equations with the matrix held in packed storage.
Definition: clatps.f:231
real function clantp(NORM, UPLO, DIAG, N, AP, WORK)
CLANTP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: clantp.f:125
subroutine clacn2(N, V, X, EST, KASE, ISAVE)
CLACN2 estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vec...
Definition: clacn2.f:133
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:68
Here is the call graph for this function:
Here is the caller graph for this function: