 LAPACK  3.10.0 LAPACK: Linear Algebra PACKage

## ◆ cptt01()

 subroutine cptt01 ( integer N, real, dimension( * ) D, complex, dimension( * ) E, real, dimension( * ) DF, complex, dimension( * ) EF, complex, dimension( * ) WORK, real RESID )

CPTT01

Purpose:
``` CPTT01 reconstructs a tridiagonal matrix A from its L*D*L'
factorization and computes the residual
norm(L*D*L' - A) / ( n * norm(A) * EPS ),
where EPS is the machine epsilon.```
Parameters
 [in] N ``` N is INTEGTER The order of the matrix A.``` [in] D ``` D is REAL array, dimension (N) The n diagonal elements of the tridiagonal matrix A.``` [in] E ``` E is COMPLEX array, dimension (N-1) The (n-1) subdiagonal elements of the tridiagonal matrix A.``` [in] DF ``` DF is REAL array, dimension (N) The n diagonal elements of the factor L from the L*D*L' factorization of A.``` [in] EF ``` EF is COMPLEX array, dimension (N-1) The (n-1) subdiagonal elements of the factor L from the L*D*L' factorization of A.``` [out] WORK ` WORK is COMPLEX array, dimension (2*N)` [out] RESID ``` RESID is REAL norm(L*D*L' - A) / (n * norm(A) * EPS)```

Definition at line 91 of file cptt01.f.

92 *
93 * -- LAPACK test routine --
94 * -- LAPACK is a software package provided by Univ. of Tennessee, --
95 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
96 *
97 * .. Scalar Arguments ..
98  INTEGER N
99  REAL RESID
100 * ..
101 * .. Array Arguments ..
102  REAL D( * ), DF( * )
103  COMPLEX E( * ), EF( * ), WORK( * )
104 * ..
105 *
106 * =====================================================================
107 *
108 * .. Parameters ..
109  REAL ONE, ZERO
110  parameter( one = 1.0e+0, zero = 0.0e+0 )
111 * ..
112 * .. Local Scalars ..
113  INTEGER I
114  REAL ANORM, EPS
115  COMPLEX DE
116 * ..
117 * .. External Functions ..
118  REAL SLAMCH
119  EXTERNAL slamch
120 * ..
121 * .. Intrinsic Functions ..
122  INTRINSIC abs, conjg, max, real
123 * ..
124 * .. Executable Statements ..
125 *
126 * Quick return if possible
127 *
128  IF( n.LE.0 ) THEN
129  resid = zero
130  RETURN
131  END IF
132 *
133  eps = slamch( 'Epsilon' )
134 *
135 * Construct the difference L*D*L' - A.
136 *
137  work( 1 ) = df( 1 ) - d( 1 )
138  DO 10 i = 1, n - 1
139  de = df( i )*ef( i )
140  work( n+i ) = de - e( i )
141  work( 1+i ) = de*conjg( ef( i ) ) + df( i+1 ) - d( i+1 )
142  10 CONTINUE
143 *
144 * Compute the 1-norms of the tridiagonal matrices A and WORK.
145 *
146  IF( n.EQ.1 ) THEN
147  anorm = d( 1 )
148  resid = abs( work( 1 ) )
149  ELSE
150  anorm = max( d( 1 )+abs( e( 1 ) ), d( n )+abs( e( n-1 ) ) )
151  resid = max( abs( work( 1 ) )+abs( work( n+1 ) ),
152  \$ abs( work( n ) )+abs( work( 2*n-1 ) ) )
153  DO 20 i = 2, n - 1
154  anorm = max( anorm, d( i )+abs( e( i ) )+abs( e( i-1 ) ) )
155  resid = max( resid, abs( work( i ) )+abs( work( n+i-1 ) )+
156  \$ abs( work( n+i ) ) )
157  20 CONTINUE
158  END IF
159 *
160 * Compute norm(L*D*L' - A) / (n * norm(A) * EPS)
161 *
162  IF( anorm.LE.zero ) THEN
163  IF( resid.NE.zero )
164  \$ resid = one / eps
165  ELSE
166  resid = ( ( resid / real( n ) ) / anorm ) / eps
167  END IF
168 *
169  RETURN
170 *
171 * End of CPTT01
172 *
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:68
Here is the caller graph for this function: