LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ chet01_aa()

subroutine chet01_aa ( character  UPLO,
integer  N,
complex, dimension( lda, * )  A,
integer  LDA,
complex, dimension( ldafac, * )  AFAC,
integer  LDAFAC,
integer, dimension( * )  IPIV,
complex, dimension( ldc, * )  C,
integer  LDC,
real, dimension( * )  RWORK,
real  RESID 
)

CHET01_AA

Purpose:
 CHET01_AA reconstructs a hermitian indefinite matrix A from its
 block L*D*L' or U*D*U' factorization and computes the residual
    norm( C - A ) / ( N * norm(A) * EPS ),
 where C is the reconstructed matrix and EPS is the machine epsilon.
Parameters
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the upper or lower triangular part of the
          hermitian matrix A is stored:
          = 'U':  Upper triangular
          = 'L':  Lower triangular
[in]N
          N is INTEGER
          The number of rows and columns of the matrix A.  N >= 0.
[in]A
          A is COMPLEX array, dimension (LDA,N)
          The original hermitian matrix A.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N)
[in]AFAC
          AFAC is COMPLEX array, dimension (LDAFAC,N)
          The factored form of the matrix A.  AFAC contains the block
          diagonal matrix D and the multipliers used to obtain the
          factor L or U from the block L*D*L' or U*D*U' factorization
          as computed by CHETRF.
[in]LDAFAC
          LDAFAC is INTEGER
          The leading dimension of the array AFAC.  LDAFAC >= max(1,N).
[in]IPIV
          IPIV is INTEGER array, dimension (N)
          The pivot indices from CHETRF.
[out]C
          C is COMPLEX array, dimension (LDC,N)
[in]LDC
          LDC is INTEGER
          The leading dimension of the array C.  LDC >= max(1,N).
[out]RWORK
          RWORK is COMPLEX array, dimension (N)
[out]RESID
          RESID is COMPLEX
          If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS )
          If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS )
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 122 of file chet01_aa.f.

124 *
125 * -- LAPACK test routine --
126 * -- LAPACK is a software package provided by Univ. of Tennessee, --
127 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
128 *
129 * .. Scalar Arguments ..
130  CHARACTER UPLO
131  INTEGER LDA, LDAFAC, LDC, N
132  REAL RESID
133 * ..
134 * .. Array Arguments ..
135  INTEGER IPIV( * )
136  REAL RWORK( * )
137  COMPLEX A( LDA, * ), AFAC( LDAFAC, * ), C( LDC, * )
138 * ..
139 *
140 * =====================================================================
141 *
142 * .. Parameters ..
143  COMPLEX CZERO, CONE
144  parameter( czero = ( 0.0e+0, 0.0e+0 ),
145  $ cone = ( 1.0e+0, 0.0e+0 ) )
146  REAL ZERO, ONE
147  parameter( zero = 0.0e+0, one = 1.0e+0 )
148 * ..
149 * .. Local Scalars ..
150  INTEGER I, J
151  REAL ANORM, EPS
152 * ..
153 * .. External Functions ..
154  LOGICAL LSAME
155  REAL SLAMCH, CLANHE
156  EXTERNAL lsame, slamch, clanhe
157 * ..
158 * .. External Subroutines ..
159  EXTERNAL claset, clavhe
160 * ..
161 * .. Intrinsic Functions ..
162  INTRINSIC dble
163 * ..
164 * .. Executable Statements ..
165 *
166 * Quick exit if N = 0.
167 *
168  IF( n.LE.0 ) THEN
169  resid = zero
170  RETURN
171  END IF
172 *
173 * Determine EPS and the norm of A.
174 *
175  eps = slamch( 'Epsilon' )
176  anorm = clanhe( '1', uplo, n, a, lda, rwork )
177 *
178 * Initialize C to the tridiagonal matrix T.
179 *
180  CALL claset( 'Full', n, n, czero, czero, c, ldc )
181  CALL clacpy( 'F', 1, n, afac( 1, 1 ), ldafac+1, c( 1, 1 ), ldc+1 )
182  IF( n.GT.1 ) THEN
183  IF( lsame( uplo, 'U' ) ) THEN
184  CALL clacpy( 'F', 1, n-1, afac( 1, 2 ), ldafac+1, c( 1, 2 ),
185  $ ldc+1 )
186  CALL clacpy( 'F', 1, n-1, afac( 1, 2 ), ldafac+1, c( 2, 1 ),
187  $ ldc+1 )
188  CALL clacgv( n-1, c( 2, 1 ), ldc+1 )
189  ELSE
190  CALL clacpy( 'F', 1, n-1, afac( 2, 1 ), ldafac+1, c( 1, 2 ),
191  $ ldc+1 )
192  CALL clacpy( 'F', 1, n-1, afac( 2, 1 ), ldafac+1, c( 2, 1 ),
193  $ ldc+1 )
194  CALL clacgv( n-1, c( 1, 2 ), ldc+1 )
195  ENDIF
196 *
197 * Call CTRMM to form the product U' * D (or L * D ).
198 *
199  IF( lsame( uplo, 'U' ) ) THEN
200  CALL ctrmm( 'Left', uplo, 'Conjugate transpose', 'Unit',
201  $ n-1, n, cone, afac( 1, 2 ), ldafac, c( 2, 1 ),
202  $ ldc )
203  ELSE
204  CALL ctrmm( 'Left', uplo, 'No transpose', 'Unit', n-1, n,
205  $ cone, afac( 2, 1 ), ldafac, c( 2, 1 ), ldc )
206  END IF
207 *
208 * Call CTRMM again to multiply by U (or L ).
209 *
210  IF( lsame( uplo, 'U' ) ) THEN
211  CALL ctrmm( 'Right', uplo, 'No transpose', 'Unit', n, n-1,
212  $ cone, afac( 1, 2 ), ldafac, c( 1, 2 ), ldc )
213  ELSE
214  CALL ctrmm( 'Right', uplo, 'Conjugate transpose', 'Unit', n,
215  $ n-1, cone, afac( 2, 1 ), ldafac, c( 1, 2 ),
216  $ ldc )
217  END IF
218  ENDIF
219 *
220 * Apply hermitian pivots
221 *
222  DO j = n, 1, -1
223  i = ipiv( j )
224  IF( i.NE.j )
225  $ CALL cswap( n, c( j, 1 ), ldc, c( i, 1 ), ldc )
226  END DO
227  DO j = n, 1, -1
228  i = ipiv( j )
229  IF( i.NE.j )
230  $ CALL cswap( n, c( 1, j ), 1, c( 1, i ), 1 )
231  END DO
232 *
233 *
234 * Compute the difference C - A .
235 *
236  IF( lsame( uplo, 'U' ) ) THEN
237  DO j = 1, n
238  DO i = 1, j
239  c( i, j ) = c( i, j ) - a( i, j )
240  END DO
241  END DO
242  ELSE
243  DO j = 1, n
244  DO i = j, n
245  c( i, j ) = c( i, j ) - a( i, j )
246  END DO
247  END DO
248  END IF
249 *
250 * Compute norm( C - A ) / ( N * norm(A) * EPS )
251 *
252  resid = clanhe( '1', uplo, n, c, ldc, rwork )
253 *
254  IF( anorm.LE.zero ) THEN
255  IF( resid.NE.zero )
256  $ resid = one / eps
257  ELSE
258  resid = ( ( resid / dble( n ) ) / anorm ) / eps
259  END IF
260 *
261  RETURN
262 *
263 * End of CHET01_AA
264 *
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine cswap(N, CX, INCX, CY, INCY)
CSWAP
Definition: cswap.f:81
subroutine ctrmm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
CTRMM
Definition: ctrmm.f:177
subroutine clavhe(UPLO, TRANS, DIAG, N, NRHS, A, LDA, IPIV, B, LDB, INFO)
CLAVHE
Definition: clavhe.f:153
real function clanhe(NORM, UPLO, N, A, LDA, WORK)
CLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: clanhe.f:124
subroutine clacgv(N, X, INCX)
CLACGV conjugates a complex vector.
Definition: clacgv.f:74
subroutine claset(UPLO, M, N, ALPHA, BETA, A, LDA)
CLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition: claset.f:106
subroutine clacpy(UPLO, M, N, A, LDA, B, LDB)
CLACPY copies all or part of one two-dimensional array to another.
Definition: clacpy.f:103
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:68
Here is the call graph for this function:
Here is the caller graph for this function: