LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ zla_herfsx_extended()

subroutine zla_herfsx_extended ( integer  PREC_TYPE,
character  UPLO,
integer  N,
integer  NRHS,
complex*16, dimension( lda, * )  A,
integer  LDA,
complex*16, dimension( ldaf, * )  AF,
integer  LDAF,
integer, dimension( * )  IPIV,
logical  COLEQU,
double precision, dimension( * )  C,
complex*16, dimension( ldb, * )  B,
integer  LDB,
complex*16, dimension( ldy, * )  Y,
integer  LDY,
double precision, dimension( * )  BERR_OUT,
integer  N_NORMS,
double precision, dimension( nrhs, * )  ERR_BNDS_NORM,
double precision, dimension( nrhs, * )  ERR_BNDS_COMP,
complex*16, dimension( * )  RES,
double precision, dimension( * )  AYB,
complex*16, dimension( * )  DY,
complex*16, dimension( * )  Y_TAIL,
double precision  RCOND,
integer  ITHRESH,
double precision  RTHRESH,
double precision  DZ_UB,
logical  IGNORE_CWISE,
integer  INFO 
)

ZLA_HERFSX_EXTENDED improves the computed solution to a system of linear equations for Hermitian indefinite matrices by performing extra-precise iterative refinement and provides error bounds and backward error estimates for the solution.

Download ZLA_HERFSX_EXTENDED + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZLA_HERFSX_EXTENDED improves the computed solution to a system of
 linear equations by performing extra-precise iterative refinement
 and provides error bounds and backward error estimates for the solution.
 This subroutine is called by ZHERFSX to perform iterative refinement.
 In addition to normwise error bound, the code provides maximum
 componentwise error bound if possible. See comments for ERR_BNDS_NORM
 and ERR_BNDS_COMP for details of the error bounds. Note that this
 subroutine is only resonsible for setting the second fields of
 ERR_BNDS_NORM and ERR_BNDS_COMP.
Parameters
[in]PREC_TYPE
          PREC_TYPE is INTEGER
     Specifies the intermediate precision to be used in refinement.
     The value is defined by ILAPREC(P) where P is a CHARACTER and P
          = 'S':  Single
          = 'D':  Double
          = 'I':  Indigenous
          = 'X' or 'E':  Extra
[in]UPLO
          UPLO is CHARACTER*1
       = 'U':  Upper triangle of A is stored;
       = 'L':  Lower triangle of A is stored.
[in]N
          N is INTEGER
     The number of linear equations, i.e., the order of the
     matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
     The number of right-hand-sides, i.e., the number of columns of the
     matrix B.
[in]A
          A is COMPLEX*16 array, dimension (LDA,N)
     On entry, the N-by-N matrix A.
[in]LDA
          LDA is INTEGER
     The leading dimension of the array A.  LDA >= max(1,N).
[in]AF
          AF is COMPLEX*16 array, dimension (LDAF,N)
     The block diagonal matrix D and the multipliers used to
     obtain the factor U or L as computed by ZHETRF.
[in]LDAF
          LDAF is INTEGER
     The leading dimension of the array AF.  LDAF >= max(1,N).
[in]IPIV
          IPIV is INTEGER array, dimension (N)
     Details of the interchanges and the block structure of D
     as determined by ZHETRF.
[in]COLEQU
          COLEQU is LOGICAL
     If .TRUE. then column equilibration was done to A before calling
     this routine. This is needed to compute the solution and error
     bounds correctly.
[in]C
          C is DOUBLE PRECISION array, dimension (N)
     The column scale factors for A. If COLEQU = .FALSE., C
     is not accessed. If C is input, each element of C should be a power
     of the radix to ensure a reliable solution and error estimates.
     Scaling by powers of the radix does not cause rounding errors unless
     the result underflows or overflows. Rounding errors during scaling
     lead to refining with a matrix that is not equivalent to the
     input matrix, producing error estimates that may not be
     reliable.
[in]B
          B is COMPLEX*16 array, dimension (LDB,NRHS)
     The right-hand-side matrix B.
[in]LDB
          LDB is INTEGER
     The leading dimension of the array B.  LDB >= max(1,N).
[in,out]Y
          Y is COMPLEX*16 array, dimension (LDY,NRHS)
     On entry, the solution matrix X, as computed by ZHETRS.
     On exit, the improved solution matrix Y.
[in]LDY
          LDY is INTEGER
     The leading dimension of the array Y.  LDY >= max(1,N).
[out]BERR_OUT
          BERR_OUT is DOUBLE PRECISION array, dimension (NRHS)
     On exit, BERR_OUT(j) contains the componentwise relative backward
     error for right-hand-side j from the formula
         max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
     where abs(Z) is the componentwise absolute value of the matrix
     or vector Z. This is computed by ZLA_LIN_BERR.
[in]N_NORMS
          N_NORMS is INTEGER
     Determines which error bounds to return (see ERR_BNDS_NORM
     and ERR_BNDS_COMP).
     If N_NORMS >= 1 return normwise error bounds.
     If N_NORMS >= 2 return componentwise error bounds.
[in,out]ERR_BNDS_NORM
          ERR_BNDS_NORM is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     normwise relative error, which is defined as follows:

     Normwise relative error in the ith solution vector:
             max_j (abs(XTRUE(j,i) - X(j,i)))
            ------------------------------
                  max_j abs(X(j,i))

     The array is indexed by the type of error information as described
     below. There currently are up to three pieces of information
     returned.

     The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_NORM(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated normwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*A, where S scales each row by a power of the
              radix so all absolute row sums of Z are approximately 1.

     This subroutine is only responsible for setting the second field
     above.
     See Lapack Working Note 165 for further details and extra
     cautions.
[in,out]ERR_BNDS_COMP
          ERR_BNDS_COMP is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     componentwise relative error, which is defined as follows:

     Componentwise relative error in the ith solution vector:
                    abs(XTRUE(j,i) - X(j,i))
             max_j ----------------------
                         abs(X(j,i))

     The array is indexed by the right-hand side i (on which the
     componentwise relative error depends), and the type of error
     information as described below. There currently are up to three
     pieces of information returned for each right-hand side. If
     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
     ERR_BNDS_COMP is not accessed.  If N_ERR_BNDS < 3, then at most
     the first (:,N_ERR_BNDS) entries are returned.

     The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_COMP(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated componentwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*(A*diag(x)), where x is the solution for the
              current right-hand side and S scales each row of
              A*diag(x) by a power of the radix so all absolute row
              sums of Z are approximately 1.

     This subroutine is only responsible for setting the second field
     above.
     See Lapack Working Note 165 for further details and extra
     cautions.
[in]RES
          RES is COMPLEX*16 array, dimension (N)
     Workspace to hold the intermediate residual.
[in]AYB
          AYB is DOUBLE PRECISION array, dimension (N)
     Workspace.
[in]DY
          DY is COMPLEX*16 array, dimension (N)
     Workspace to hold the intermediate solution.
[in]Y_TAIL
          Y_TAIL is COMPLEX*16 array, dimension (N)
     Workspace to hold the trailing bits of the intermediate solution.
[in]RCOND
          RCOND is DOUBLE PRECISION
     Reciprocal scaled condition number.  This is an estimate of the
     reciprocal Skeel condition number of the matrix A after
     equilibration (if done).  If this is less than the machine
     precision (in particular, if it is zero), the matrix is singular
     to working precision.  Note that the error may still be small even
     if this number is very small and the matrix appears ill-
     conditioned.
[in]ITHRESH
          ITHRESH is INTEGER
     The maximum number of residual computations allowed for
     refinement. The default is 10. For 'aggressive' set to 100 to
     permit convergence using approximate factorizations or
     factorizations other than LU. If the factorization uses a
     technique other than Gaussian elimination, the guarantees in
     ERR_BNDS_NORM and ERR_BNDS_COMP may no longer be trustworthy.
[in]RTHRESH
          RTHRESH is DOUBLE PRECISION
     Determines when to stop refinement if the error estimate stops
     decreasing. Refinement will stop when the next solution no longer
     satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
     the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
     default value is 0.5. For 'aggressive' set to 0.9 to permit
     convergence on extremely ill-conditioned matrices. See LAWN 165
     for more details.
[in]DZ_UB
          DZ_UB is DOUBLE PRECISION
     Determines when to start considering componentwise convergence.
     Componentwise convergence is only considered after each component
     of the solution Y is stable, which we define as the relative
     change in each component being less than DZ_UB. The default value
     is 0.25, requiring the first bit to be stable. See LAWN 165 for
     more details.
[in]IGNORE_CWISE
          IGNORE_CWISE is LOGICAL
     If .TRUE. then ignore componentwise convergence. Default value
     is .FALSE..
[out]INFO
          INFO is INTEGER
       = 0:  Successful exit.
       < 0:  if INFO = -i, the ith argument to ZLA_HERFSX_EXTENDED had an illegal
             value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 388 of file zla_herfsx_extended.f.

395 *
396 * -- LAPACK computational routine --
397 * -- LAPACK is a software package provided by Univ. of Tennessee, --
398 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
399 *
400 * .. Scalar Arguments ..
401  INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
402  $ N_NORMS, ITHRESH
403  CHARACTER UPLO
404  LOGICAL COLEQU, IGNORE_CWISE
405  DOUBLE PRECISION RTHRESH, DZ_UB
406 * ..
407 * .. Array Arguments ..
408  INTEGER IPIV( * )
409  COMPLEX*16 A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
410  $ Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
411  DOUBLE PRECISION C( * ), AYB( * ), RCOND, BERR_OUT( * ),
412  $ ERR_BNDS_NORM( NRHS, * ),
413  $ ERR_BNDS_COMP( NRHS, * )
414 * ..
415 *
416 * =====================================================================
417 *
418 * .. Local Scalars ..
419  INTEGER UPLO2, CNT, I, J, X_STATE, Z_STATE,
420  $ Y_PREC_STATE
421  DOUBLE PRECISION YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
422  $ DZRAT, PREVNORMDX, PREV_DZ_Z, DXRATMAX,
423  $ DZRATMAX, DX_X, DZ_Z, FINAL_DX_X, FINAL_DZ_Z,
424  $ EPS, HUGEVAL, INCR_THRESH
425  LOGICAL INCR_PREC, UPPER
426  COMPLEX*16 ZDUM
427 * ..
428 * .. Parameters ..
429  INTEGER UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
430  $ NOPROG_STATE, BASE_RESIDUAL, EXTRA_RESIDUAL,
431  $ EXTRA_Y
432  parameter( unstable_state = 0, working_state = 1,
433  $ conv_state = 2, noprog_state = 3 )
434  parameter( base_residual = 0, extra_residual = 1,
435  $ extra_y = 2 )
436  INTEGER FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
437  INTEGER RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
438  INTEGER CMP_ERR_I, PIV_GROWTH_I
439  parameter( final_nrm_err_i = 1, final_cmp_err_i = 2,
440  $ berr_i = 3 )
441  parameter( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
442  parameter( cmp_rcond_i = 7, cmp_err_i = 8,
443  $ piv_growth_i = 9 )
444  INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
445  $ LA_LINRX_CWISE_I
446  parameter( la_linrx_itref_i = 1,
447  $ la_linrx_ithresh_i = 2 )
448  parameter( la_linrx_cwise_i = 3 )
449  INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
450  $ LA_LINRX_RCOND_I
451  parameter( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
452  parameter( la_linrx_rcond_i = 3 )
453 * ..
454 * .. External Functions ..
455  LOGICAL LSAME
456  EXTERNAL ilauplo
457  INTEGER ILAUPLO
458 * ..
459 * .. External Subroutines ..
460  EXTERNAL zaxpy, zcopy, zhetrs, zhemv, blas_zhemv_x,
461  $ blas_zhemv2_x, zla_heamv, zla_wwaddw,
462  $ zla_lin_berr
463  DOUBLE PRECISION DLAMCH
464 * ..
465 * .. Intrinsic Functions ..
466  INTRINSIC abs, dble, dimag, max, min
467 * ..
468 * .. Statement Functions ..
469  DOUBLE PRECISION CABS1
470 * ..
471 * .. Statement Function Definitions ..
472  cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )
473 * ..
474 * .. Executable Statements ..
475 *
476  info = 0
477  upper = lsame( uplo, 'U' )
478  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
479  info = -2
480  ELSE IF( n.LT.0 ) THEN
481  info = -3
482  ELSE IF( nrhs.LT.0 ) THEN
483  info = -4
484  ELSE IF( lda.LT.max( 1, n ) ) THEN
485  info = -6
486  ELSE IF( ldaf.LT.max( 1, n ) ) THEN
487  info = -8
488  ELSE IF( ldb.LT.max( 1, n ) ) THEN
489  info = -13
490  ELSE IF( ldy.LT.max( 1, n ) ) THEN
491  info = -15
492  END IF
493  IF( info.NE.0 ) THEN
494  CALL xerbla( 'ZLA_HERFSX_EXTENDED', -info )
495  RETURN
496  END IF
497  eps = dlamch( 'Epsilon' )
498  hugeval = dlamch( 'Overflow' )
499 * Force HUGEVAL to Inf
500  hugeval = hugeval * hugeval
501 * Using HUGEVAL may lead to spurious underflows.
502  incr_thresh = dble( n ) * eps
503 
504  IF ( lsame( uplo, 'L' ) ) THEN
505  uplo2 = ilauplo( 'L' )
506  ELSE
507  uplo2 = ilauplo( 'U' )
508  ENDIF
509 
510  DO j = 1, nrhs
511  y_prec_state = extra_residual
512  IF ( y_prec_state .EQ. extra_y ) THEN
513  DO i = 1, n
514  y_tail( i ) = 0.0d+0
515  END DO
516  END IF
517 
518  dxrat = 0.0d+0
519  dxratmax = 0.0d+0
520  dzrat = 0.0d+0
521  dzratmax = 0.0d+0
522  final_dx_x = hugeval
523  final_dz_z = hugeval
524  prevnormdx = hugeval
525  prev_dz_z = hugeval
526  dz_z = hugeval
527  dx_x = hugeval
528 
529  x_state = working_state
530  z_state = unstable_state
531  incr_prec = .false.
532 
533  DO cnt = 1, ithresh
534 *
535 * Compute residual RES = B_s - op(A_s) * Y,
536 * op(A) = A, A**T, or A**H depending on TRANS (and type).
537 *
538  CALL zcopy( n, b( 1, j ), 1, res, 1 )
539  IF ( y_prec_state .EQ. base_residual ) THEN
540  CALL zhemv( uplo, n, dcmplx(-1.0d+0), a, lda, y( 1, j ),
541  $ 1, dcmplx(1.0d+0), res, 1 )
542  ELSE IF ( y_prec_state .EQ. extra_residual ) THEN
543  CALL blas_zhemv_x( uplo2, n, dcmplx(-1.0d+0), a, lda,
544  $ y( 1, j ), 1, dcmplx(1.0d+0), res, 1, prec_type)
545  ELSE
546  CALL blas_zhemv2_x(uplo2, n, dcmplx(-1.0d+0), a, lda,
547  $ y(1, j), y_tail, 1, dcmplx(1.0d+0), res, 1,
548  $ prec_type)
549  END IF
550 
551 ! XXX: RES is no longer needed.
552  CALL zcopy( n, res, 1, dy, 1 )
553  CALL zhetrs( uplo, n, 1, af, ldaf, ipiv, dy, n, info )
554 *
555 * Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
556 *
557  normx = 0.0d+0
558  normy = 0.0d+0
559  normdx = 0.0d+0
560  dz_z = 0.0d+0
561  ymin = hugeval
562 
563  DO i = 1, n
564  yk = cabs1( y( i, j ) )
565  dyk = cabs1( dy( i ) )
566 
567  IF (yk .NE. 0.0d+0) THEN
568  dz_z = max( dz_z, dyk / yk )
569  ELSE IF ( dyk .NE. 0.0d+0 ) THEN
570  dz_z = hugeval
571  END IF
572 
573  ymin = min( ymin, yk )
574 
575  normy = max( normy, yk )
576 
577  IF ( colequ ) THEN
578  normx = max( normx, yk * c( i ) )
579  normdx = max( normdx, dyk * c( i ) )
580  ELSE
581  normx = normy
582  normdx = max( normdx, dyk )
583  END IF
584  END DO
585 
586  IF ( normx .NE. 0.0d+0 ) THEN
587  dx_x = normdx / normx
588  ELSE IF ( normdx .EQ. 0.0d+0 ) THEN
589  dx_x = 0.0d+0
590  ELSE
591  dx_x = hugeval
592  END IF
593 
594  dxrat = normdx / prevnormdx
595  dzrat = dz_z / prev_dz_z
596 *
597 * Check termination criteria.
598 *
599  IF ( ymin*rcond .LT. incr_thresh*normy
600  $ .AND. y_prec_state .LT. extra_y )
601  $ incr_prec = .true.
602 
603  IF ( x_state .EQ. noprog_state .AND. dxrat .LE. rthresh )
604  $ x_state = working_state
605  IF ( x_state .EQ. working_state ) THEN
606  IF ( dx_x .LE. eps ) THEN
607  x_state = conv_state
608  ELSE IF ( dxrat .GT. rthresh ) THEN
609  IF ( y_prec_state .NE. extra_y ) THEN
610  incr_prec = .true.
611  ELSE
612  x_state = noprog_state
613  END IF
614  ELSE
615  IF (dxrat .GT. dxratmax) dxratmax = dxrat
616  END IF
617  IF ( x_state .GT. working_state ) final_dx_x = dx_x
618  END IF
619 
620  IF ( z_state .EQ. unstable_state .AND. dz_z .LE. dz_ub )
621  $ z_state = working_state
622  IF ( z_state .EQ. noprog_state .AND. dzrat .LE. rthresh )
623  $ z_state = working_state
624  IF ( z_state .EQ. working_state ) THEN
625  IF ( dz_z .LE. eps ) THEN
626  z_state = conv_state
627  ELSE IF ( dz_z .GT. dz_ub ) THEN
628  z_state = unstable_state
629  dzratmax = 0.0d+0
630  final_dz_z = hugeval
631  ELSE IF ( dzrat .GT. rthresh ) THEN
632  IF ( y_prec_state .NE. extra_y ) THEN
633  incr_prec = .true.
634  ELSE
635  z_state = noprog_state
636  END IF
637  ELSE
638  IF ( dzrat .GT. dzratmax ) dzratmax = dzrat
639  END IF
640  IF ( z_state .GT. working_state ) final_dz_z = dz_z
641  END IF
642 
643  IF ( x_state.NE.working_state.AND.
644  $ ( ignore_cwise.OR.z_state.NE.working_state ) )
645  $ GOTO 666
646 
647  IF ( incr_prec ) THEN
648  incr_prec = .false.
649  y_prec_state = y_prec_state + 1
650  DO i = 1, n
651  y_tail( i ) = 0.0d+0
652  END DO
653  END IF
654 
655  prevnormdx = normdx
656  prev_dz_z = dz_z
657 *
658 * Update soluton.
659 *
660  IF ( y_prec_state .LT. extra_y ) THEN
661  CALL zaxpy( n, dcmplx(1.0d+0), dy, 1, y(1,j), 1 )
662  ELSE
663  CALL zla_wwaddw( n, y(1,j), y_tail, dy )
664  END IF
665 
666  END DO
667 * Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
668  666 CONTINUE
669 *
670 * Set final_* when cnt hits ithresh.
671 *
672  IF ( x_state .EQ. working_state ) final_dx_x = dx_x
673  IF ( z_state .EQ. working_state ) final_dz_z = dz_z
674 *
675 * Compute error bounds.
676 *
677  IF ( n_norms .GE. 1 ) THEN
678  err_bnds_norm( j, la_linrx_err_i ) =
679  $ final_dx_x / (1 - dxratmax)
680  END IF
681  IF (n_norms .GE. 2) THEN
682  err_bnds_comp( j, la_linrx_err_i ) =
683  $ final_dz_z / (1 - dzratmax)
684  END IF
685 *
686 * Compute componentwise relative backward error from formula
687 * max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
688 * where abs(Z) is the componentwise absolute value of the matrix
689 * or vector Z.
690 *
691 * Compute residual RES = B_s - op(A_s) * Y,
692 * op(A) = A, A**T, or A**H depending on TRANS (and type).
693 *
694  CALL zcopy( n, b( 1, j ), 1, res, 1 )
695  CALL zhemv( uplo, n, dcmplx(-1.0d+0), a, lda, y(1,j), 1,
696  $ dcmplx(1.0d+0), res, 1 )
697 
698  DO i = 1, n
699  ayb( i ) = cabs1( b( i, j ) )
700  END DO
701 *
702 * Compute abs(op(A_s))*abs(Y) + abs(B_s).
703 *
704  CALL zla_heamv( uplo2, n, 1.0d+0,
705  $ a, lda, y(1, j), 1, 1.0d+0, ayb, 1 )
706 
707  CALL zla_lin_berr( n, n, 1, res, ayb, berr_out( j ) )
708 *
709 * End of loop for each RHS.
710 *
711  END DO
712 *
713  RETURN
714 *
715 * End of ZLA_HERFSX_EXTENDED
716 *
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:69
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
integer function ilauplo(UPLO)
ILAUPLO
Definition: ilauplo.f:58
subroutine zaxpy(N, ZA, ZX, INCX, ZY, INCY)
ZAXPY
Definition: zaxpy.f:88
subroutine zcopy(N, ZX, INCX, ZY, INCY)
ZCOPY
Definition: zcopy.f:81
subroutine zhemv(UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
ZHEMV
Definition: zhemv.f:154
subroutine zla_heamv(UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
ZLA_HEAMV computes a matrix-vector product using a Hermitian indefinite matrix to calculate error bou...
Definition: zla_heamv.f:178
subroutine zhetrs(UPLO, N, NRHS, A, LDA, IPIV, B, LDB, INFO)
ZHETRS
Definition: zhetrs.f:120
subroutine zla_wwaddw(N, X, Y, W)
ZLA_WWADDW adds a vector into a doubled-single vector.
Definition: zla_wwaddw.f:81
subroutine zla_lin_berr(N, NZ, NRHS, RES, AYB, BERR)
ZLA_LIN_BERR computes a component-wise relative backward error.
Definition: zla_lin_berr.f:101
Here is the call graph for this function:
Here is the caller graph for this function: