LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ zhegs2()

subroutine zhegs2 ( integer  ITYPE,
character  UPLO,
integer  N,
complex*16, dimension( lda, * )  A,
integer  LDA,
complex*16, dimension( ldb, * )  B,
integer  LDB,
integer  INFO 
)

ZHEGS2 reduces a Hermitian definite generalized eigenproblem to standard form, using the factorization results obtained from cpotrf (unblocked algorithm).

Download ZHEGS2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZHEGS2 reduces a complex Hermitian-definite generalized
 eigenproblem to standard form.

 If ITYPE = 1, the problem is A*x = lambda*B*x,
 and A is overwritten by inv(U**H)*A*inv(U) or inv(L)*A*inv(L**H)

 If ITYPE = 2 or 3, the problem is A*B*x = lambda*x or
 B*A*x = lambda*x, and A is overwritten by U*A*U**H or L**H *A*L.

 B must have been previously factorized as U**H *U or L*L**H by ZPOTRF.
Parameters
[in]ITYPE
          ITYPE is INTEGER
          = 1: compute inv(U**H)*A*inv(U) or inv(L)*A*inv(L**H);
          = 2 or 3: compute U*A*U**H or L**H *A*L.
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the upper or lower triangular part of the
          Hermitian matrix A is stored, and how B has been factorized.
          = 'U':  Upper triangular
          = 'L':  Lower triangular
[in]N
          N is INTEGER
          The order of the matrices A and B.  N >= 0.
[in,out]A
          A is COMPLEX*16 array, dimension (LDA,N)
          On entry, the Hermitian matrix A.  If UPLO = 'U', the leading
          n by n upper triangular part of A contains the upper
          triangular part of the matrix A, and the strictly lower
          triangular part of A is not referenced.  If UPLO = 'L', the
          leading n by n lower triangular part of A contains the lower
          triangular part of the matrix A, and the strictly upper
          triangular part of A is not referenced.

          On exit, if INFO = 0, the transformed matrix, stored in the
          same format as A.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[in,out]B
          B is COMPLEX*16 array, dimension (LDB,N)
          The triangular factor from the Cholesky factorization of B,
          as returned by ZPOTRF.
          B is modified by the routine but restored on exit.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,N).
[out]INFO
          INFO is INTEGER
          = 0:  successful exit.
          < 0:  if INFO = -i, the i-th argument had an illegal value.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 127 of file zhegs2.f.

128 *
129 * -- LAPACK computational routine --
130 * -- LAPACK is a software package provided by Univ. of Tennessee, --
131 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
132 *
133 * .. Scalar Arguments ..
134  CHARACTER UPLO
135  INTEGER INFO, ITYPE, LDA, LDB, N
136 * ..
137 * .. Array Arguments ..
138  COMPLEX*16 A( LDA, * ), B( LDB, * )
139 * ..
140 *
141 * =====================================================================
142 *
143 * .. Parameters ..
144  DOUBLE PRECISION ONE, HALF
145  parameter( one = 1.0d+0, half = 0.5d+0 )
146  COMPLEX*16 CONE
147  parameter( cone = ( 1.0d+0, 0.0d+0 ) )
148 * ..
149 * .. Local Scalars ..
150  LOGICAL UPPER
151  INTEGER K
152  DOUBLE PRECISION AKK, BKK
153  COMPLEX*16 CT
154 * ..
155 * .. External Subroutines ..
156  EXTERNAL xerbla, zaxpy, zdscal, zher2, zlacgv, ztrmv,
157  $ ztrsv
158 * ..
159 * .. Intrinsic Functions ..
160  INTRINSIC max
161 * ..
162 * .. External Functions ..
163  LOGICAL LSAME
164  EXTERNAL lsame
165 * ..
166 * .. Executable Statements ..
167 *
168 * Test the input parameters.
169 *
170  info = 0
171  upper = lsame( uplo, 'U' )
172  IF( itype.LT.1 .OR. itype.GT.3 ) THEN
173  info = -1
174  ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
175  info = -2
176  ELSE IF( n.LT.0 ) THEN
177  info = -3
178  ELSE IF( lda.LT.max( 1, n ) ) THEN
179  info = -5
180  ELSE IF( ldb.LT.max( 1, n ) ) THEN
181  info = -7
182  END IF
183  IF( info.NE.0 ) THEN
184  CALL xerbla( 'ZHEGS2', -info )
185  RETURN
186  END IF
187 *
188  IF( itype.EQ.1 ) THEN
189  IF( upper ) THEN
190 *
191 * Compute inv(U**H)*A*inv(U)
192 *
193  DO 10 k = 1, n
194 *
195 * Update the upper triangle of A(k:n,k:n)
196 *
197  akk = dble( a( k, k ) )
198  bkk = dble( b( k, k ) )
199  akk = akk / bkk**2
200  a( k, k ) = akk
201  IF( k.LT.n ) THEN
202  CALL zdscal( n-k, one / bkk, a( k, k+1 ), lda )
203  ct = -half*akk
204  CALL zlacgv( n-k, a( k, k+1 ), lda )
205  CALL zlacgv( n-k, b( k, k+1 ), ldb )
206  CALL zaxpy( n-k, ct, b( k, k+1 ), ldb, a( k, k+1 ),
207  $ lda )
208  CALL zher2( uplo, n-k, -cone, a( k, k+1 ), lda,
209  $ b( k, k+1 ), ldb, a( k+1, k+1 ), lda )
210  CALL zaxpy( n-k, ct, b( k, k+1 ), ldb, a( k, k+1 ),
211  $ lda )
212  CALL zlacgv( n-k, b( k, k+1 ), ldb )
213  CALL ztrsv( uplo, 'Conjugate transpose', 'Non-unit',
214  $ n-k, b( k+1, k+1 ), ldb, a( k, k+1 ),
215  $ lda )
216  CALL zlacgv( n-k, a( k, k+1 ), lda )
217  END IF
218  10 CONTINUE
219  ELSE
220 *
221 * Compute inv(L)*A*inv(L**H)
222 *
223  DO 20 k = 1, n
224 *
225 * Update the lower triangle of A(k:n,k:n)
226 *
227  akk = dble( a( k, k ) )
228  bkk = dble( b( k, k ) )
229  akk = akk / bkk**2
230  a( k, k ) = akk
231  IF( k.LT.n ) THEN
232  CALL zdscal( n-k, one / bkk, a( k+1, k ), 1 )
233  ct = -half*akk
234  CALL zaxpy( n-k, ct, b( k+1, k ), 1, a( k+1, k ), 1 )
235  CALL zher2( uplo, n-k, -cone, a( k+1, k ), 1,
236  $ b( k+1, k ), 1, a( k+1, k+1 ), lda )
237  CALL zaxpy( n-k, ct, b( k+1, k ), 1, a( k+1, k ), 1 )
238  CALL ztrsv( uplo, 'No transpose', 'Non-unit', n-k,
239  $ b( k+1, k+1 ), ldb, a( k+1, k ), 1 )
240  END IF
241  20 CONTINUE
242  END IF
243  ELSE
244  IF( upper ) THEN
245 *
246 * Compute U*A*U**H
247 *
248  DO 30 k = 1, n
249 *
250 * Update the upper triangle of A(1:k,1:k)
251 *
252  akk = dble( a( k, k ) )
253  bkk = dble( b( k, k ) )
254  CALL ztrmv( uplo, 'No transpose', 'Non-unit', k-1, b,
255  $ ldb, a( 1, k ), 1 )
256  ct = half*akk
257  CALL zaxpy( k-1, ct, b( 1, k ), 1, a( 1, k ), 1 )
258  CALL zher2( uplo, k-1, cone, a( 1, k ), 1, b( 1, k ), 1,
259  $ a, lda )
260  CALL zaxpy( k-1, ct, b( 1, k ), 1, a( 1, k ), 1 )
261  CALL zdscal( k-1, bkk, a( 1, k ), 1 )
262  a( k, k ) = akk*bkk**2
263  30 CONTINUE
264  ELSE
265 *
266 * Compute L**H *A*L
267 *
268  DO 40 k = 1, n
269 *
270 * Update the lower triangle of A(1:k,1:k)
271 *
272  akk = dble( a( k, k ) )
273  bkk = dble( b( k, k ) )
274  CALL zlacgv( k-1, a( k, 1 ), lda )
275  CALL ztrmv( uplo, 'Conjugate transpose', 'Non-unit', k-1,
276  $ b, ldb, a( k, 1 ), lda )
277  ct = half*akk
278  CALL zlacgv( k-1, b( k, 1 ), ldb )
279  CALL zaxpy( k-1, ct, b( k, 1 ), ldb, a( k, 1 ), lda )
280  CALL zher2( uplo, k-1, cone, a( k, 1 ), lda, b( k, 1 ),
281  $ ldb, a, lda )
282  CALL zaxpy( k-1, ct, b( k, 1 ), ldb, a( k, 1 ), lda )
283  CALL zlacgv( k-1, b( k, 1 ), ldb )
284  CALL zdscal( k-1, bkk, a( k, 1 ), lda )
285  CALL zlacgv( k-1, a( k, 1 ), lda )
286  a( k, k ) = akk*bkk**2
287  40 CONTINUE
288  END IF
289  END IF
290  RETURN
291 *
292 * End of ZHEGS2
293 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine zdscal(N, DA, ZX, INCX)
ZDSCAL
Definition: zdscal.f:78
subroutine zaxpy(N, ZA, ZX, INCX, ZY, INCY)
ZAXPY
Definition: zaxpy.f:88
subroutine ztrmv(UPLO, TRANS, DIAG, N, A, LDA, X, INCX)
ZTRMV
Definition: ztrmv.f:147
subroutine ztrsv(UPLO, TRANS, DIAG, N, A, LDA, X, INCX)
ZTRSV
Definition: ztrsv.f:149
subroutine zher2(UPLO, N, ALPHA, X, INCX, Y, INCY, A, LDA)
ZHER2
Definition: zher2.f:150
subroutine zlacgv(N, X, INCX)
ZLACGV conjugates a complex vector.
Definition: zlacgv.f:74
Here is the call graph for this function:
Here is the caller graph for this function: