zlaqr1()

subroutine zlaqr1	(	integer	n,
		complex*16, dimension( ldh, * )	h,
		integer	ldh,
		complex*16	s1,
		complex*16	s2,
		complex*16, dimension( * )	v )

ZLAQR1 sets a scalar multiple of the first column of the product of 2-by-2 or 3-by-3 matrix H and specified shifts.

Download ZLAQR1 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!>      Given a 2-by-2 or 3-by-3 matrix H, ZLAQR1 sets v to a
!>      scalar multiple of the first column of the product
!>
!>      (*)  K = (H - s1*I)*(H - s2*I)
!>
!>      scaling to avoid overflows and most underflows.
!>
!>      This is useful for starting double implicit shift bulges
!>      in the QR algorithm.
!> 

Parameters

[in]	N	!> N is INTEGER !> Order of the matrix H. N must be either 2 or 3. !>
[in]	H	!> H is COMPLEX*16 array, dimension (LDH,N) !> The 2-by-2 or 3-by-3 matrix H in (*). !>
[in]	LDH	!> LDH is INTEGER !> The leading dimension of H as declared in !> the calling procedure. LDH >= N !>
[in]	S1	!> S1 is COMPLEX*16 !>
[in]	S2	!> S2 is COMPLEX*16 !> !> S1 and S2 are the shifts defining K in (*) above. !>
[out]	V	!> V is COMPLEX*16 array, dimension (N) !> A scalar multiple of the first column of the !> matrix K in (*). !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

Karen Braman and Ralph Byers, Department of Mathematics, University of Kansas, USA

Definition at line 104 of file zlaqr1.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      COMPLEX*16         S1, S2
      INTEGER            LDH, N
*     ..
*     .. Array Arguments ..
      COMPLEX*16         H( LDH, * ), V( * )
*     ..
*
*  ================================================================
*
*     .. Parameters ..
      COMPLEX*16         ZERO
      parameter( zero = ( 0.0d0, 0.0d0 ) )
      DOUBLE PRECISION   RZERO
      parameter( rzero = 0.0d0 )
*     ..
*     .. Local Scalars ..
      COMPLEX*16         CDUM, H21S, H31S
      DOUBLE PRECISION   S
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dimag
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( cdum ) = abs( dble( cdum ) ) + abs( dimag( cdum ) )
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.NE.2 .AND. n.NE.3 ) THEN
         RETURN
      END IF
*
      IF( n.EQ.2 ) THEN
         s = cabs1( h( 1, 1 )-s2 ) + cabs1( h( 2, 1 ) )
         IF( s.EQ.rzero ) THEN
            v( 1 ) = zero
            v( 2 ) = zero
         ELSE
            h21s = h( 2, 1 ) / s
            v( 1 ) = h21s*h( 1, 2 ) + ( h( 1, 1 )-s1 )*
     $               ( ( h( 1, 1 )-s2 ) / s )
            v( 2 ) = h21s*( h( 1, 1 )+h( 2, 2 )-s1-s2 )
         END IF
      ELSE
         s = cabs1( h( 1, 1 )-s2 ) + cabs1( h( 2, 1 ) ) +
     $       cabs1( h( 3, 1 ) )
         IF( s.EQ.zero ) THEN
            v( 1 ) = zero
            v( 2 ) = zero
            v( 3 ) = zero
         ELSE
            h21s = h( 2, 1 ) / s
            h31s = h( 3, 1 ) / s
            v( 1 ) = ( h( 1, 1 )-s1 )*( ( h( 1, 1 )-s2 ) / s ) +
     $               h( 1, 2 )*h21s + h( 1, 3 )*h31s
            v( 2 ) = h21s*( h( 1, 1 )+h( 2, 2 )-s1-s2 ) + h( 2, 3 )*h31s
            v( 3 ) = h31s*( h( 1, 1 )+h( 3, 3 )-s1-s2 ) + h21s*h( 3, 2 )
         END IF
      END IF

Here is the caller graph for this function: