cchkgk()

subroutine cchkgk	(	integer	nin,
		integer	nout )

CCHKGK

Purpose:

!>
!> CCHKGK tests CGGBAK, a routine for backward balancing  of
!> a matrix pair (A, B).
!> 

Parameters

[in]	NIN	!> NIN is INTEGER !> The logical unit number for input. NIN > 0. !>
[in]	NOUT	!> NOUT is INTEGER !> The logical unit number for output. NOUT > 0. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 53 of file cchkgk.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            NIN, NOUT
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            LDA, LDB, LDVL, LDVR
      parameter( lda = 50, ldb = 50, ldvl = 50, ldvr = 50 )
      INTEGER            LDE, LDF, LDWORK, LRWORK
      parameter( lde = 50, ldf = 50, ldwork = 50,
     $                   lrwork = 6*50 )
      REAL               ZERO
      parameter( zero = 0.0e+0 )
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IHI, ILO, INFO, J, KNT, M, N, NINFO
      REAL               ANORM, BNORM, EPS, RMAX, VMAX
      COMPLEX            CDUM
*     ..
*     .. Local Arrays ..
      INTEGER            LMAX( 4 )
      REAL               LSCALE( LDA ), RSCALE( LDA ), RWORK( LRWORK )
      COMPLEX            A( LDA, LDA ), AF( LDA, LDA ), B( LDB, LDB ),
     $                   BF( LDB, LDB ), E( LDE, LDE ), F( LDF, LDF ),
     $                   VL( LDVL, LDVL ), VLF( LDVL, LDVL ),
     $                   VR( LDVR, LDVR ), VRF( LDVR, LDVR ),
     $                   WORK( LDWORK, LDWORK )
*     ..
*     .. External Functions ..
      REAL               CLANGE, SLAMCH
      EXTERNAL           clange, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, cggbak, cggbal, clacpy
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, max, real
*     ..
*     .. Statement Functions ..
      REAL               CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( cdum ) = abs( real( cdum ) ) + abs( aimag( cdum ) )
*     ..
*     .. Executable Statements ..
*
      lmax( 1 ) = 0
      lmax( 2 ) = 0
      lmax( 3 ) = 0
      lmax( 4 ) = 0
      ninfo = 0
      knt = 0
      rmax = zero
*
      eps = slamch( 'Precision' )
*
   10 CONTINUE
      READ( nin, fmt = * )n, m
      IF( n.EQ.0 )
     $   GO TO 100
*
      DO 20 i = 1, n
         READ( nin, fmt = * )( a( i, j ), j = 1, n )
   20 CONTINUE
*
      DO 30 i = 1, n
         READ( nin, fmt = * )( b( i, j ), j = 1, n )
   30 CONTINUE
*
      DO 40 i = 1, n
         READ( nin, fmt = * )( vl( i, j ), j = 1, m )
   40 CONTINUE
*
      DO 50 i = 1, n
         READ( nin, fmt = * )( vr( i, j ), j = 1, m )
   50 CONTINUE
*
      knt = knt + 1
*
      anorm = clange( 'M', n, n, a, lda, rwork )
      bnorm = clange( 'M', n, n, b, ldb, rwork )
*
      CALL clacpy( 'FULL', n, n, a, lda, af, lda )
      CALL clacpy( 'FULL', n, n, b, ldb, bf, ldb )
*
      CALL cggbal( 'B', n, a, lda, b, ldb, ilo, ihi, lscale, rscale,
     $             rwork, info )
      IF( info.NE.0 ) THEN
         ninfo = ninfo + 1
         lmax( 1 ) = knt
      END IF
*
      CALL clacpy( 'FULL', n, m, vl, ldvl, vlf, ldvl )
      CALL clacpy( 'FULL', n, m, vr, ldvr, vrf, ldvr )
*
      CALL cggbak( 'B', 'L', n, ilo, ihi, lscale, rscale, m, vl, ldvl,
     $             info )
      IF( info.NE.0 ) THEN
         ninfo = ninfo + 1
         lmax( 2 ) = knt
      END IF
*
      CALL cggbak( 'B', 'R', n, ilo, ihi, lscale, rscale, m, vr, ldvr,
     $             info )
      IF( info.NE.0 ) THEN
         ninfo = ninfo + 1
         lmax( 3 ) = knt
      END IF
*
*     Test of CGGBAK
*
*     Check tilde(VL)'*A*tilde(VR) - VL'*tilde(A)*VR
*     where tilde(A) denotes the transformed matrix.
*
      CALL cgemm( 'N', 'N', n, m, n, cone, af, lda, vr, ldvr, czero,
     $            work, ldwork )
      CALL cgemm( 'C', 'N', m, m, n, cone, vl, ldvl, work, ldwork,
     $            czero, e, lde )
*
      CALL cgemm( 'N', 'N', n, m, n, cone, a, lda, vrf, ldvr, czero,
     $            work, ldwork )
      CALL cgemm( 'C', 'N', m, m, n, cone, vlf, ldvl, work, ldwork,
     $            czero, f, ldf )
*
      vmax = zero
      DO 70 j = 1, m
         DO 60 i = 1, m
            vmax = max( vmax, cabs1( e( i, j )-f( i, j ) ) )
   60    CONTINUE
   70 CONTINUE
      vmax = vmax / ( eps*max( anorm, bnorm ) )
      IF( vmax.GT.rmax ) THEN
         lmax( 4 ) = knt
         rmax = vmax
      END IF
*
*     Check tilde(VL)'*B*tilde(VR) - VL'*tilde(B)*VR
*
      CALL cgemm( 'N', 'N', n, m, n, cone, bf, ldb, vr, ldvr, czero,
     $            work, ldwork )
      CALL cgemm( 'C', 'N', m, m, n, cone, vl, ldvl, work, ldwork,
     $            czero, e, lde )
*
      CALL cgemm( 'n', 'n', n, m, n, cone, b, ldb, vrf, ldvr, czero,
     $            work, ldwork )
      CALL cgemm( 'C', 'N', m, m, n, cone, vlf, ldvl, work, ldwork,
     $            czero, f, ldf )
*
      vmax = zero
      DO 90 j = 1, m
         DO 80 i = 1, m
            vmax = max( vmax, cabs1( e( i, j )-f( i, j ) ) )
   80    CONTINUE
   90 CONTINUE
      vmax = vmax / ( eps*max( anorm, bnorm ) )
      IF( vmax.GT.rmax ) THEN
         lmax( 4 ) = knt
         rmax = vmax
      END IF
*
      GO TO 10
*
  100 CONTINUE
*
      WRITE( nout, fmt = 9999 )
 9999 FORMAT( 1x, '.. test output of CGGBAK .. ' )
*
      WRITE( nout, fmt = 9998 )rmax
 9998 FORMAT( ' value of largest test error                  =', e12.3 )
      WRITE( nout, fmt = 9997 )lmax( 1 )
 9997 FORMAT( ' example number where CGGBAL info is not 0    =', i4 )
      WRITE( nout, fmt = 9996 )lmax( 2 )
 9996 FORMAT( ' example number where CGGBAK(L) info is not 0 =', i4 )
      WRITE( nout, fmt = 9995 )lmax( 3 )
 9995 FORMAT( ' example number where CGGBAK(R) info is not 0 =', i4 )
      WRITE( nout, fmt = 9994 )lmax( 4 )
 9994 FORMAT( ' example number having largest error          =', i4 )
      WRITE( nout, fmt = 9992 )ninfo
 9992 FORMAT( ' number of examples where info is not 0       =', i4 )
      WRITE( nout, fmt = 9991 )knt
 9991 FORMAT( ' total number of examples tested              =', i4 )
*
      RETURN
*
*     End of CCHKGK
*

Here is the call graph for this function:

Here is the caller graph for this function: