LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
zgqrts.f
Go to the documentation of this file.
1*> \brief \b ZGQRTS
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* SUBROUTINE ZGQRTS( N, M, P, A, AF, Q, R, LDA, TAUA, B, BF, Z, T,
12* BWK, LDB, TAUB, WORK, LWORK, RWORK, RESULT )
13*
14* .. Scalar Arguments ..
15* INTEGER LDA, LDB, LWORK, M, N, P
16* ..
17* .. Array Arguments ..
18* DOUBLE PRECISION RESULT( 4 ), RWORK( * )
19* COMPLEX*16 A( LDA, * ), AF( LDA, * ), B( LDB, * ),
20* $ BF( LDB, * ), BWK( LDB, * ), Q( LDA, * ),
21* $ R( LDA, * ), T( LDB, * ), TAUA( * ), TAUB( * ),
22* $ WORK( LWORK ), Z( LDB, * )
23* ..
24*
25*
26*> \par Purpose:
27* =============
28*>
29*> \verbatim
30*>
31*> ZGQRTS tests ZGGQRF, which computes the GQR factorization of an
32*> N-by-M matrix A and a N-by-P matrix B: A = Q*R and B = Q*T*Z.
33*> \endverbatim
34*
35* Arguments:
36* ==========
37*
38*> \param[in] N
39*> \verbatim
40*> N is INTEGER
41*> The number of rows of the matrices A and B. N >= 0.
42*> \endverbatim
43*>
44*> \param[in] M
45*> \verbatim
46*> M is INTEGER
47*> The number of columns of the matrix A. M >= 0.
48*> \endverbatim
49*>
50*> \param[in] P
51*> \verbatim
52*> P is INTEGER
53*> The number of columns of the matrix B. P >= 0.
54*> \endverbatim
55*>
56*> \param[in] A
57*> \verbatim
58*> A is COMPLEX*16 array, dimension (LDA,M)
59*> The N-by-M matrix A.
60*> \endverbatim
61*>
62*> \param[out] AF
63*> \verbatim
64*> AF is COMPLEX*16 array, dimension (LDA,N)
65*> Details of the GQR factorization of A and B, as returned
66*> by ZGGQRF, see CGGQRF for further details.
67*> \endverbatim
68*>
69*> \param[out] Q
70*> \verbatim
71*> Q is COMPLEX*16 array, dimension (LDA,N)
72*> The M-by-M unitary matrix Q.
73*> \endverbatim
74*>
75*> \param[out] R
76*> \verbatim
77*> R is COMPLEX*16 array, dimension (LDA,MAX(M,N))
78*> \endverbatim
79*>
80*> \param[in] LDA
81*> \verbatim
82*> LDA is INTEGER
83*> The leading dimension of the arrays A, AF, R and Q.
84*> LDA >= max(M,N).
85*> \endverbatim
86*>
87*> \param[out] TAUA
88*> \verbatim
89*> TAUA is COMPLEX*16 array, dimension (min(M,N))
90*> The scalar factors of the elementary reflectors, as returned
91*> by ZGGQRF.
92*> \endverbatim
93*>
94*> \param[in] B
95*> \verbatim
96*> B is COMPLEX*16 array, dimension (LDB,P)
97*> On entry, the N-by-P matrix A.
98*> \endverbatim
99*>
100*> \param[out] BF
101*> \verbatim
102*> BF is COMPLEX*16 array, dimension (LDB,N)
103*> Details of the GQR factorization of A and B, as returned
104*> by ZGGQRF, see CGGQRF for further details.
105*> \endverbatim
106*>
107*> \param[out] Z
108*> \verbatim
109*> Z is COMPLEX*16 array, dimension (LDB,P)
110*> The P-by-P unitary matrix Z.
111*> \endverbatim
112*>
113*> \param[out] T
114*> \verbatim
115*> T is COMPLEX*16 array, dimension (LDB,max(P,N))
116*> \endverbatim
117*>
118*> \param[out] BWK
119*> \verbatim
120*> BWK is COMPLEX*16 array, dimension (LDB,N)
121*> \endverbatim
122*>
123*> \param[in] LDB
124*> \verbatim
125*> LDB is INTEGER
126*> The leading dimension of the arrays B, BF, Z and T.
127*> LDB >= max(P,N).
128*> \endverbatim
129*>
130*> \param[out] TAUB
131*> \verbatim
132*> TAUB is COMPLEX*16 array, dimension (min(P,N))
133*> The scalar factors of the elementary reflectors, as returned
134*> by DGGRQF.
135*> \endverbatim
136*>
137*> \param[out] WORK
138*> \verbatim
139*> WORK is COMPLEX*16 array, dimension (LWORK)
140*> \endverbatim
141*>
142*> \param[in] LWORK
143*> \verbatim
144*> LWORK is INTEGER
145*> The dimension of the array WORK, LWORK >= max(N,M,P)**2.
146*> \endverbatim
147*>
148*> \param[out] RWORK
149*> \verbatim
150*> RWORK is DOUBLE PRECISION array, dimension (max(N,M,P))
151*> \endverbatim
152*>
153*> \param[out] RESULT
154*> \verbatim
155*> RESULT is DOUBLE PRECISION array, dimension (4)
156*> The test ratios:
157*> RESULT(1) = norm( R - Q'*A ) / ( MAX(M,N)*norm(A)*ULP)
158*> RESULT(2) = norm( T*Z - Q'*B ) / (MAX(P,N)*norm(B)*ULP)
159*> RESULT(3) = norm( I - Q'*Q ) / ( M*ULP )
160*> RESULT(4) = norm( I - Z'*Z ) / ( P*ULP )
161*> \endverbatim
162*
163* Authors:
164* ========
165*
166*> \author Univ. of Tennessee
167*> \author Univ. of California Berkeley
168*> \author Univ. of Colorado Denver
169*> \author NAG Ltd.
170*
171*> \ingroup complex16_eig
172*
173* =====================================================================
174 SUBROUTINE zgqrts( N, M, P, A, AF, Q, R, LDA, TAUA, B, BF, Z, T,
175 $ BWK, LDB, TAUB, WORK, LWORK, RWORK, RESULT )
176*
177* -- LAPACK test routine --
178* -- LAPACK is a software package provided by Univ. of Tennessee, --
179* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
180*
181* .. Scalar Arguments ..
182 INTEGER LDA, LDB, LWORK, M, N, P
183* ..
184* .. Array Arguments ..
185 DOUBLE PRECISION RESULT( 4 ), RWORK( * )
186 COMPLEX*16 A( LDA, * ), AF( LDA, * ), B( LDB, * ),
187 $ bf( ldb, * ), bwk( ldb, * ), q( lda, * ),
188 $ r( lda, * ), t( ldb, * ), taua( * ), taub( * ),
189 $ work( lwork ), z( ldb, * )
190* ..
191*
192* =====================================================================
193*
194* .. Parameters ..
195 DOUBLE PRECISION ZERO, ONE
196 parameter( zero = 0.0d+0, one = 1.0d+0 )
197 COMPLEX*16 CZERO, CONE
198 parameter( czero = ( 0.0d+0, 0.0d+0 ),
199 $ cone = ( 1.0d+0, 0.0d+0 ) )
200 COMPLEX*16 CROGUE
201 parameter( crogue = ( -1.0d+10, 0.0d+0 ) )
202* ..
203* .. Local Scalars ..
204 INTEGER INFO
205 DOUBLE PRECISION ANORM, BNORM, RESID, ULP, UNFL
206* ..
207* .. External Functions ..
208 DOUBLE PRECISION DLAMCH, ZLANGE, ZLANHE
209 EXTERNAL dlamch, zlange, zlanhe
210* ..
211* .. External Subroutines ..
212 EXTERNAL zgemm, zggqrf, zherk, zlacpy, zlaset, zungqr,
213 $ zungrq
214* ..
215* .. Intrinsic Functions ..
216 INTRINSIC dble, max, min
217* ..
218* .. Executable Statements ..
219*
220 ulp = dlamch( 'Precision' )
221 unfl = dlamch( 'Safe minimum' )
222*
223* Copy the matrix A to the array AF.
224*
225 CALL zlacpy( 'Full', n, m, a, lda, af, lda )
226 CALL zlacpy( 'Full', n, p, b, ldb, bf, ldb )
227*
228 anorm = max( zlange( '1', n, m, a, lda, rwork ), unfl )
229 bnorm = max( zlange( '1', n, p, b, ldb, rwork ), unfl )
230*
231* Factorize the matrices A and B in the arrays AF and BF.
232*
233 CALL zggqrf( n, m, p, af, lda, taua, bf, ldb, taub, work, lwork,
234 $ info )
235*
236* Generate the N-by-N matrix Q
237*
238 CALL zlaset( 'Full', n, n, crogue, crogue, q, lda )
239 CALL zlacpy( 'Lower', n-1, m, af( 2, 1 ), lda, q( 2, 1 ), lda )
240 CALL zungqr( n, n, min( n, m ), q, lda, taua, work, lwork, info )
241*
242* Generate the P-by-P matrix Z
243*
244 CALL zlaset( 'Full', p, p, crogue, crogue, z, ldb )
245 IF( n.LE.p ) THEN
246 IF( n.GT.0 .AND. n.LT.p )
247 $ CALL zlacpy( 'Full', n, p-n, bf, ldb, z( p-n+1, 1 ), ldb )
248 IF( n.GT.1 )
249 $ CALL zlacpy( 'Lower', n-1, n-1, bf( 2, p-n+1 ), ldb,
250 $ z( p-n+2, p-n+1 ), ldb )
251 ELSE
252 IF( p.GT.1 )
253 $ CALL zlacpy( 'Lower', p-1, p-1, bf( n-p+2, 1 ), ldb,
254 $ z( 2, 1 ), ldb )
255 END IF
256 CALL zungrq( p, p, min( n, p ), z, ldb, taub, work, lwork, info )
257*
258* Copy R
259*
260 CALL zlaset( 'Full', n, m, czero, czero, r, lda )
261 CALL zlacpy( 'Upper', n, m, af, lda, r, lda )
262*
263* Copy T
264*
265 CALL zlaset( 'Full', n, p, czero, czero, t, ldb )
266 IF( n.LE.p ) THEN
267 CALL zlacpy( 'Upper', n, n, bf( 1, p-n+1 ), ldb, t( 1, p-n+1 ),
268 $ ldb )
269 ELSE
270 CALL zlacpy( 'Full', n-p, p, bf, ldb, t, ldb )
271 CALL zlacpy( 'Upper', p, p, bf( n-p+1, 1 ), ldb, t( n-p+1, 1 ),
272 $ ldb )
273 END IF
274*
275* Compute R - Q'*A
276*
277 CALL zgemm( 'Conjugate transpose', 'No transpose', n, m, n, -cone,
278 $ q, lda, a, lda, cone, r, lda )
279*
280* Compute norm( R - Q'*A ) / ( MAX(M,N)*norm(A)*ULP ) .
281*
282 resid = zlange( '1', n, m, r, lda, rwork )
283 IF( anorm.GT.zero ) THEN
284 result( 1 ) = ( ( resid / dble( max( 1, m, n ) ) ) / anorm ) /
285 $ ulp
286 ELSE
287 result( 1 ) = zero
288 END IF
289*
290* Compute T*Z - Q'*B
291*
292 CALL zgemm( 'No Transpose', 'No transpose', n, p, p, cone, t, ldb,
293 $ z, ldb, czero, bwk, ldb )
294 CALL zgemm( 'Conjugate transpose', 'No transpose', n, p, n, -cone,
295 $ q, lda, b, ldb, cone, bwk, ldb )
296*
297* Compute norm( T*Z - Q'*B ) / ( MAX(P,N)*norm(A)*ULP ) .
298*
299 resid = zlange( '1', n, p, bwk, ldb, rwork )
300 IF( bnorm.GT.zero ) THEN
301 result( 2 ) = ( ( resid / dble( max( 1, p, n ) ) ) / bnorm ) /
302 $ ulp
303 ELSE
304 result( 2 ) = zero
305 END IF
306*
307* Compute I - Q'*Q
308*
309 CALL zlaset( 'Full', n, n, czero, cone, r, lda )
310 CALL zherk( 'Upper', 'Conjugate transpose', n, n, -one, q, lda,
311 $ one, r, lda )
312*
313* Compute norm( I - Q'*Q ) / ( N * ULP ) .
314*
315 resid = zlanhe( '1', 'Upper', n, r, lda, rwork )
316 result( 3 ) = ( resid / dble( max( 1, n ) ) ) / ulp
317*
318* Compute I - Z'*Z
319*
320 CALL zlaset( 'Full', p, p, czero, cone, t, ldb )
321 CALL zherk( 'Upper', 'Conjugate transpose', p, p, -one, z, ldb,
322 $ one, t, ldb )
323*
324* Compute norm( I - Z'*Z ) / ( P*ULP ) .
325*
326 resid = zlanhe( '1', 'Upper', p, t, ldb, rwork )
327 result( 4 ) = ( resid / dble( max( 1, p ) ) ) / ulp
328*
329 RETURN
330*
331* End of ZGQRTS
332*
333 END
subroutine zgemm(transa, transb, m, n, k, alpha, a, lda, b, ldb, beta, c, ldc)
ZGEMM
Definition zgemm.f:188
subroutine zggqrf(n, m, p, a, lda, taua, b, ldb, taub, work, lwork, info)
ZGGQRF
Definition zggqrf.f:215
subroutine zherk(uplo, trans, n, k, alpha, a, lda, beta, c, ldc)
ZHERK
Definition zherk.f:173
subroutine zlacpy(uplo, m, n, a, lda, b, ldb)
ZLACPY copies all or part of one two-dimensional array to another.
Definition zlacpy.f:103
subroutine zlaset(uplo, m, n, alpha, beta, a, lda)
ZLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition zlaset.f:106
subroutine zungqr(m, n, k, a, lda, tau, work, lwork, info)
ZUNGQR
Definition zungqr.f:128
subroutine zungrq(m, n, k, a, lda, tau, work, lwork, info)
ZUNGRQ
Definition zungrq.f:128
subroutine zgqrts(n, m, p, a, af, q, r, lda, taua, b, bf, z, t, bwk, ldb, taub, work, lwork, rwork, result)
ZGQRTS
Definition zgqrts.f:176