LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ zgerq2()

subroutine zgerq2 ( integer  M,
integer  N,
complex*16, dimension( lda, * )  A,
integer  LDA,
complex*16, dimension( * )  TAU,
complex*16, dimension( * )  WORK,
integer  INFO 
)

ZGERQ2 computes the RQ factorization of a general rectangular matrix using an unblocked algorithm.

Download ZGERQ2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZGERQ2 computes an RQ factorization of a complex m by n matrix A:
 A = R * Q.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix A.  N >= 0.
[in,out]A
          A is COMPLEX*16 array, dimension (LDA,N)
          On entry, the m by n matrix A.
          On exit, if m <= n, the upper triangle of the subarray
          A(1:m,n-m+1:n) contains the m by m upper triangular matrix R;
          if m >= n, the elements on and above the (m-n)-th subdiagonal
          contain the m by n upper trapezoidal matrix R; the remaining
          elements, with the array TAU, represent the unitary matrix
          Q as a product of elementary reflectors (see Further
          Details).
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,M).
[out]TAU
          TAU is COMPLEX*16 array, dimension (min(M,N))
          The scalar factors of the elementary reflectors (see Further
          Details).
[out]WORK
          WORK is COMPLEX*16 array, dimension (M)
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
  The matrix Q is represented as a product of elementary reflectors

     Q = H(1)**H H(2)**H . . . H(k)**H, where k = min(m,n).

  Each H(i) has the form

     H(i) = I - tau * v * v**H

  where tau is a complex scalar, and v is a complex vector with
  v(n-k+i+1:n) = 0 and v(n-k+i) = 1; conjg(v(1:n-k+i-1)) is stored on
  exit in A(m-k+i,1:n-k+i-1), and tau in TAU(i).

Definition at line 122 of file zgerq2.f.

123 *
124 * -- LAPACK computational routine --
125 * -- LAPACK is a software package provided by Univ. of Tennessee, --
126 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
127 *
128 * .. Scalar Arguments ..
129  INTEGER INFO, LDA, M, N
130 * ..
131 * .. Array Arguments ..
132  COMPLEX*16 A( LDA, * ), TAU( * ), WORK( * )
133 * ..
134 *
135 * =====================================================================
136 *
137 * .. Parameters ..
138  COMPLEX*16 ONE
139  parameter( one = ( 1.0d+0, 0.0d+0 ) )
140 * ..
141 * .. Local Scalars ..
142  INTEGER I, K
143  COMPLEX*16 ALPHA
144 * ..
145 * .. External Subroutines ..
146  EXTERNAL xerbla, zlacgv, zlarf, zlarfg
147 * ..
148 * .. Intrinsic Functions ..
149  INTRINSIC max, min
150 * ..
151 * .. Executable Statements ..
152 *
153 * Test the input arguments
154 *
155  info = 0
156  IF( m.LT.0 ) THEN
157  info = -1
158  ELSE IF( n.LT.0 ) THEN
159  info = -2
160  ELSE IF( lda.LT.max( 1, m ) ) THEN
161  info = -4
162  END IF
163  IF( info.NE.0 ) THEN
164  CALL xerbla( 'ZGERQ2', -info )
165  RETURN
166  END IF
167 *
168  k = min( m, n )
169 *
170  DO 10 i = k, 1, -1
171 *
172 * Generate elementary reflector H(i) to annihilate
173 * A(m-k+i,1:n-k+i-1)
174 *
175  CALL zlacgv( n-k+i, a( m-k+i, 1 ), lda )
176  alpha = a( m-k+i, n-k+i )
177  CALL zlarfg( n-k+i, alpha, a( m-k+i, 1 ), lda, tau( i ) )
178 *
179 * Apply H(i) to A(1:m-k+i-1,1:n-k+i) from the right
180 *
181  a( m-k+i, n-k+i ) = one
182  CALL zlarf( 'Right', m-k+i-1, n-k+i, a( m-k+i, 1 ), lda,
183  $ tau( i ), a, lda, work )
184  a( m-k+i, n-k+i ) = alpha
185  CALL zlacgv( n-k+i-1, a( m-k+i, 1 ), lda )
186  10 CONTINUE
187  RETURN
188 *
189 * End of ZGERQ2
190 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine zlacgv(N, X, INCX)
ZLACGV conjugates a complex vector.
Definition: zlacgv.f:74
subroutine zlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
ZLARF applies an elementary reflector to a general rectangular matrix.
Definition: zlarf.f:128
subroutine zlarfg(N, ALPHA, X, INCX, TAU)
ZLARFG generates an elementary reflector (Householder matrix).
Definition: zlarfg.f:106
Here is the call graph for this function:
Here is the caller graph for this function: