dgeql2()

subroutine dgeql2	(	integer	m,
		integer	n,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( * )	tau,
		double precision, dimension( * )	work,
		integer	info )

DGEQL2 computes the QL factorization of a general rectangular matrix using an unblocked algorithm.

Download DGEQL2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DGEQL2 computes a QL factorization of a real m by n matrix A:
!> A = Q * L.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in,out]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N) !> On entry, the m by n matrix A. !> On exit, if m >= n, the lower triangle of the subarray !> A(m-n+1:m,1:n) contains the n by n lower triangular matrix L; !> if m <= n, the elements on and below the (n-m)-th !> superdiagonal contain the m by n lower trapezoidal matrix L; !> the remaining elements, with the array TAU, represent the !> orthogonal matrix Q as a product of elementary reflectors !> (see Further Details). !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,M). !>
[out]	TAU	!> TAU is DOUBLE PRECISION array, dimension (min(M,N)) !> The scalar factors of the elementary reflectors (see Further !> Details). !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  The matrix Q is represented as a product of elementary reflectors
!>
!>     Q = H(k) . . . H(2) H(1), where k = min(m,n).
!>
!>  Each H(i) has the form
!>
!>     H(i) = I - tau * v * v**T
!>
!>  where tau is a real scalar, and v is a real vector with
!>  v(m-k+i+1:m) = 0 and v(m-k+i) = 1; v(1:m-k+i-1) is stored on exit in
!>  A(1:m-k+i-1,n-k+i), and tau in TAU(i).
!> 

Definition at line 120 of file dgeql2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE
      parameter( one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, K
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlarf1l, dlarfg, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DGEQL2', -info )
         RETURN
      END IF
*
      k = min( m, n )
*
      DO 10 i = k, 1, -1
*
*        Generate elementary reflector H(i) to annihilate
*        A(1:m-k+i-1,n-k+i)
*
         CALL dlarfg( m-k+i, a( m-k+i, n-k+i ), a( 1, n-k+i ), 1,
     $                tau( i ) )
*
*        Apply H(i) to A(1:m-k+i,1:n-k+i-1) from the left
*
         CALL dlarf1l( 'Left', m-k+i, n-k+i-1, a( 1, n-k+i ), 1,
     $               tau( i ),
     $               a, lda, work )
   10 CONTINUE
      RETURN
*
*     End of DGEQL2
*

Here is the call graph for this function:

Here is the caller graph for this function: