LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ chetrs2()

subroutine chetrs2 ( character uplo,
integer n,
integer nrhs,
complex, dimension( lda, * ) a,
integer lda,
integer, dimension( * ) ipiv,
complex, dimension( ldb, * ) b,
integer ldb,
complex, dimension( * ) work,
integer info )

CHETRS2

Download CHETRS2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> CHETRS2 solves a system of linear equations A*X = B with a complex
!> Hermitian matrix A using the factorization A = U*D*U**H or
!> A = L*D*L**H computed by CHETRF and converted by CSYCONV.
!>
Parameters
[in]UPLO
!>          UPLO is CHARACTER*1
!>          Specifies whether the details of the factorization are stored
!>          as an upper or lower triangular matrix.
!>          = 'U':  Upper triangular, form is A = U*D*U**H;
!>          = 'L':  Lower triangular, form is A = L*D*L**H.
!>
[in]N
!>          N is INTEGER
!>          The order of the matrix A.  N >= 0.
!>
[in]NRHS
!>          NRHS is INTEGER
!>          The number of right hand sides, i.e., the number of columns
!>          of the matrix B.  NRHS >= 0.
!>
[in]A
!>          A is COMPLEX array, dimension (LDA,N)
!>          The block diagonal matrix D and the multipliers used to
!>          obtain the factor U or L as computed by CHETRF.
!>
[in]LDA
!>          LDA is INTEGER
!>          The leading dimension of the array A.  LDA >= max(1,N).
!>
[in]IPIV
!>          IPIV is INTEGER array, dimension (N)
!>          Details of the interchanges and the block structure of D
!>          as determined by CHETRF.
!>
[in,out]B
!>          B is COMPLEX array, dimension (LDB,NRHS)
!>          On entry, the right hand side matrix B.
!>          On exit, the solution matrix X.
!>
[in]LDB
!>          LDB is INTEGER
!>          The leading dimension of the array B.  LDB >= max(1,N).
!>
[out]WORK
!>          WORK is COMPLEX array, dimension (N)
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 123 of file chetrs2.f.

125*
126* -- LAPACK computational routine --
127* -- LAPACK is a software package provided by Univ. of Tennessee, --
128* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
129*
130* .. Scalar Arguments ..
131 CHARACTER UPLO
132 INTEGER INFO, LDA, LDB, N, NRHS
133* ..
134* .. Array Arguments ..
135 INTEGER IPIV( * )
136 COMPLEX A( LDA, * ), B( LDB, * ), WORK( * )
137* ..
138*
139* =====================================================================
140*
141* .. Parameters ..
142 COMPLEX ONE
143 parameter( one = (1.0e+0,0.0e+0) )
144* ..
145* .. Local Scalars ..
146 LOGICAL UPPER
147 INTEGER I, IINFO, J, K, KP
148 REAL S
149 COMPLEX AK, AKM1, AKM1K, BK, BKM1, DENOM
150* ..
151* .. External Functions ..
152 LOGICAL LSAME
153 EXTERNAL lsame
154* ..
155* .. External Subroutines ..
156 EXTERNAL csscal, csyconv, cswap, ctrsm,
157 $ xerbla
158* ..
159* .. Intrinsic Functions ..
160 INTRINSIC conjg, max, real
161* ..
162* .. Executable Statements ..
163*
164 info = 0
165 upper = lsame( uplo, 'U' )
166 IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
167 info = -1
168 ELSE IF( n.LT.0 ) THEN
169 info = -2
170 ELSE IF( nrhs.LT.0 ) THEN
171 info = -3
172 ELSE IF( lda.LT.max( 1, n ) ) THEN
173 info = -5
174 ELSE IF( ldb.LT.max( 1, n ) ) THEN
175 info = -8
176 END IF
177 IF( info.NE.0 ) THEN
178 CALL xerbla( 'CHETRS2', -info )
179 RETURN
180 END IF
181*
182* Quick return if possible
183*
184 IF( n.EQ.0 .OR. nrhs.EQ.0 )
185 $ RETURN
186*
187* Convert A
188*
189 CALL csyconv( uplo, 'C', n, a, lda, ipiv, work, iinfo )
190*
191 IF( upper ) THEN
192*
193* Solve A*X = B, where A = U*D*U**H.
194*
195* P**T * B
196 k=n
197 DO WHILE ( k .GE. 1 )
198 IF( ipiv( k ).GT.0 ) THEN
199* 1 x 1 diagonal block
200* Interchange rows K and IPIV(K).
201 kp = ipiv( k )
202 IF( kp.NE.k )
203 $ CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
204 k=k-1
205 ELSE
206* 2 x 2 diagonal block
207* Interchange rows K-1 and -IPIV(K).
208 kp = -ipiv( k )
209 IF( kp.EQ.-ipiv( k-1 ) )
210 $ CALL cswap( nrhs, b( k-1, 1 ), ldb, b( kp, 1 ), ldb )
211 k=k-2
212 END IF
213 END DO
214*
215* Compute (U \P**T * B) -> B [ (U \P**T * B) ]
216*
217 CALL ctrsm('L','U','N','U',n,nrhs,one,a,lda,b,ldb)
218*
219* Compute D \ B -> B [ D \ (U \P**T * B) ]
220*
221 i=n
222 DO WHILE ( i .GE. 1 )
223 IF( ipiv(i) .GT. 0 ) THEN
224 s = real( one ) / real( a( i, i ) )
225 CALL csscal( nrhs, s, b( i, 1 ), ldb )
226 ELSEIF ( i .GT. 1) THEN
227 IF ( ipiv(i-1) .EQ. ipiv(i) ) THEN
228 akm1k = work(i)
229 akm1 = a( i-1, i-1 ) / akm1k
230 ak = a( i, i ) / conjg( akm1k )
231 denom = akm1*ak - one
232 DO 15 j = 1, nrhs
233 bkm1 = b( i-1, j ) / akm1k
234 bk = b( i, j ) / conjg( akm1k )
235 b( i-1, j ) = ( ak*bkm1-bk ) / denom
236 b( i, j ) = ( akm1*bk-bkm1 ) / denom
237 15 CONTINUE
238 i = i - 1
239 ENDIF
240 ENDIF
241 i = i - 1
242 END DO
243*
244* Compute (U**H \ B) -> B [ U**H \ (D \ (U \P**T * B) ) ]
245*
246 CALL ctrsm('L','U','C','U',n,nrhs,one,a,lda,b,ldb)
247*
248* P * B [ P * (U**H \ (D \ (U \P**T * B) )) ]
249*
250 k=1
251 DO WHILE ( k .LE. n )
252 IF( ipiv( k ).GT.0 ) THEN
253* 1 x 1 diagonal block
254* Interchange rows K and IPIV(K).
255 kp = ipiv( k )
256 IF( kp.NE.k )
257 $ CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
258 k=k+1
259 ELSE
260* 2 x 2 diagonal block
261* Interchange rows K-1 and -IPIV(K).
262 kp = -ipiv( k )
263 IF( k .LT. n .AND. kp.EQ.-ipiv( k+1 ) )
264 $ CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
265 k=k+2
266 ENDIF
267 END DO
268*
269 ELSE
270*
271* Solve A*X = B, where A = L*D*L**H.
272*
273* P**T * B
274 k=1
275 DO WHILE ( k .LE. n )
276 IF( ipiv( k ).GT.0 ) THEN
277* 1 x 1 diagonal block
278* Interchange rows K and IPIV(K).
279 kp = ipiv( k )
280 IF( kp.NE.k )
281 $ CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
282 k=k+1
283 ELSE
284* 2 x 2 diagonal block
285* Interchange rows K and -IPIV(K+1).
286 kp = -ipiv( k+1 )
287 IF( kp.EQ.-ipiv( k ) )
288 $ CALL cswap( nrhs, b( k+1, 1 ), ldb, b( kp, 1 ), ldb )
289 k=k+2
290 ENDIF
291 END DO
292*
293* Compute (L \P**T * B) -> B [ (L \P**T * B) ]
294*
295 CALL ctrsm('L','L','N','U',n,nrhs,one,a,lda,b,ldb)
296*
297* Compute D \ B -> B [ D \ (L \P**T * B) ]
298*
299 i=1
300 DO WHILE ( i .LE. n )
301 IF( ipiv(i) .GT. 0 ) THEN
302 s = real( one ) / real( a( i, i ) )
303 CALL csscal( nrhs, s, b( i, 1 ), ldb )
304 ELSE
305 akm1k = work(i)
306 akm1 = a( i, i ) / conjg( akm1k )
307 ak = a( i+1, i+1 ) / akm1k
308 denom = akm1*ak - one
309 DO 25 j = 1, nrhs
310 bkm1 = b( i, j ) / conjg( akm1k )
311 bk = b( i+1, j ) / akm1k
312 b( i, j ) = ( ak*bkm1-bk ) / denom
313 b( i+1, j ) = ( akm1*bk-bkm1 ) / denom
314 25 CONTINUE
315 i = i + 1
316 ENDIF
317 i = i + 1
318 END DO
319*
320* Compute (L**H \ B) -> B [ L**H \ (D \ (L \P**T * B) ) ]
321*
322 CALL ctrsm('L','L','C','U',n,nrhs,one,a,lda,b,ldb)
323*
324* P * B [ P * (L**H \ (D \ (L \P**T * B) )) ]
325*
326 k=n
327 DO WHILE ( k .GE. 1 )
328 IF( ipiv( k ).GT.0 ) THEN
329* 1 x 1 diagonal block
330* Interchange rows K and IPIV(K).
331 kp = ipiv( k )
332 IF( kp.NE.k )
333 $ CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
334 k=k-1
335 ELSE
336* 2 x 2 diagonal block
337* Interchange rows K-1 and -IPIV(K).
338 kp = -ipiv( k )
339 IF( k.GT.1 .AND. kp.EQ.-ipiv( k-1 ) )
340 $ CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
341 k=k-2
342 ENDIF
343 END DO
344*
345 END IF
346*
347* Revert A
348*
349 CALL csyconv( uplo, 'R', n, a, lda, ipiv, work, iinfo )
350*
351 RETURN
352*
353* End of CHETRS2
354*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
csscal
subroutine csscal(n, sa, cx, incx)
CSSCAL
Definition csscal.f:78
cswap
subroutine cswap(n, cx, incx, cy, incy)
CSWAP
Definition cswap.f:81
csyconv
subroutine csyconv(uplo, way, n, a, lda, ipiv, e, info)
CSYCONV
Definition csyconv.f:112
ctrsm
subroutine ctrsm(side, uplo, transa, diag, m, n, alpha, a, lda, b, ldb)
CTRSM
Definition ctrsm.f:180
Here is the call graph for this function:
Here is the caller graph for this function: