LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ dla_gbrfsx_extended()

subroutine dla_gbrfsx_extended ( integer  PREC_TYPE,
integer  TRANS_TYPE,
integer  N,
integer  KL,
integer  KU,
integer  NRHS,
double precision, dimension( ldab, * )  AB,
integer  LDAB,
double precision, dimension( ldafb, * )  AFB,
integer  LDAFB,
integer, dimension( * )  IPIV,
logical  COLEQU,
double precision, dimension( * )  C,
double precision, dimension( ldb, * )  B,
integer  LDB,
double precision, dimension( ldy, * )  Y,
integer  LDY,
double precision, dimension(*)  BERR_OUT,
integer  N_NORMS,
double precision, dimension( nrhs, * )  ERR_BNDS_NORM,
double precision, dimension( nrhs, * )  ERR_BNDS_COMP,
double precision, dimension(*)  RES,
double precision, dimension(*)  AYB,
double precision, dimension(*)  DY,
double precision, dimension(*)  Y_TAIL,
double precision  RCOND,
integer  ITHRESH,
double precision  RTHRESH,
double precision  DZ_UB,
logical  IGNORE_CWISE,
integer  INFO 
)

DLA_GBRFSX_EXTENDED improves the computed solution to a system of linear equations for general banded matrices by performing extra-precise iterative refinement and provides error bounds and backward error estimates for the solution.

Download DLA_GBRFSX_EXTENDED + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DLA_GBRFSX_EXTENDED improves the computed solution to a system of
 linear equations by performing extra-precise iterative refinement
 and provides error bounds and backward error estimates for the solution.
 This subroutine is called by DGBRFSX to perform iterative refinement.
 In addition to normwise error bound, the code provides maximum
 componentwise error bound if possible. See comments for ERR_BNDS_NORM
 and ERR_BNDS_COMP for details of the error bounds. Note that this
 subroutine is only resonsible for setting the second fields of
 ERR_BNDS_NORM and ERR_BNDS_COMP.
Parameters
[in]PREC_TYPE
          PREC_TYPE is INTEGER
     Specifies the intermediate precision to be used in refinement.
     The value is defined by ILAPREC(P) where P is a CHARACTER and P
          = 'S':  Single
          = 'D':  Double
          = 'I':  Indigenous
          = 'X' or 'E':  Extra
[in]TRANS_TYPE
          TRANS_TYPE is INTEGER
     Specifies the transposition operation on A.
     The value is defined by ILATRANS(T) where T is a CHARACTER and T
          = 'N':  No transpose
          = 'T':  Transpose
          = 'C':  Conjugate transpose
[in]N
          N is INTEGER
     The number of linear equations, i.e., the order of the
     matrix A.  N >= 0.
[in]KL
          KL is INTEGER
     The number of subdiagonals within the band of A.  KL >= 0.
[in]KU
          KU is INTEGER
     The number of superdiagonals within the band of A.  KU >= 0
[in]NRHS
          NRHS is INTEGER
     The number of right-hand-sides, i.e., the number of columns of the
     matrix B.
[in]AB
          AB is DOUBLE PRECISION array, dimension (LDAB,N)
          On entry, the N-by-N matrix AB.
[in]LDAB
          LDAB is INTEGER
          The leading dimension of the array AB.  LDBA >= max(1,N).
[in]AFB
          AFB is DOUBLE PRECISION array, dimension (LDAFB,N)
     The factors L and U from the factorization
     A = P*L*U as computed by DGBTRF.
[in]LDAFB
          LDAFB is INTEGER
     The leading dimension of the array AF.  LDAFB >= max(1,N).
[in]IPIV
          IPIV is INTEGER array, dimension (N)
     The pivot indices from the factorization A = P*L*U
     as computed by DGBTRF; row i of the matrix was interchanged
     with row IPIV(i).
[in]COLEQU
          COLEQU is LOGICAL
     If .TRUE. then column equilibration was done to A before calling
     this routine. This is needed to compute the solution and error
     bounds correctly.
[in]C
          C is DOUBLE PRECISION array, dimension (N)
     The column scale factors for A. If COLEQU = .FALSE., C
     is not accessed. If C is input, each element of C should be a power
     of the radix to ensure a reliable solution and error estimates.
     Scaling by powers of the radix does not cause rounding errors unless
     the result underflows or overflows. Rounding errors during scaling
     lead to refining with a matrix that is not equivalent to the
     input matrix, producing error estimates that may not be
     reliable.
[in]B
          B is DOUBLE PRECISION array, dimension (LDB,NRHS)
     The right-hand-side matrix B.
[in]LDB
          LDB is INTEGER
     The leading dimension of the array B.  LDB >= max(1,N).
[in,out]Y
          Y is DOUBLE PRECISION array, dimension (LDY,NRHS)
     On entry, the solution matrix X, as computed by DGBTRS.
     On exit, the improved solution matrix Y.
[in]LDY
          LDY is INTEGER
     The leading dimension of the array Y.  LDY >= max(1,N).
[out]BERR_OUT
          BERR_OUT is DOUBLE PRECISION array, dimension (NRHS)
     On exit, BERR_OUT(j) contains the componentwise relative backward
     error for right-hand-side j from the formula
         max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
     where abs(Z) is the componentwise absolute value of the matrix
     or vector Z. This is computed by DLA_LIN_BERR.
[in]N_NORMS
          N_NORMS is INTEGER
     Determines which error bounds to return (see ERR_BNDS_NORM
     and ERR_BNDS_COMP).
     If N_NORMS >= 1 return normwise error bounds.
     If N_NORMS >= 2 return componentwise error bounds.
[in,out]ERR_BNDS_NORM
          ERR_BNDS_NORM is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     normwise relative error, which is defined as follows:

     Normwise relative error in the ith solution vector:
             max_j (abs(XTRUE(j,i) - X(j,i)))
            ------------------------------
                  max_j abs(X(j,i))

     The array is indexed by the type of error information as described
     below. There currently are up to three pieces of information
     returned.

     The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_NORM(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated normwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*A, where S scales each row by a power of the
              radix so all absolute row sums of Z are approximately 1.

     This subroutine is only responsible for setting the second field
     above.
     See Lapack Working Note 165 for further details and extra
     cautions.
[in,out]ERR_BNDS_COMP
          ERR_BNDS_COMP is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     componentwise relative error, which is defined as follows:

     Componentwise relative error in the ith solution vector:
                    abs(XTRUE(j,i) - X(j,i))
             max_j ----------------------
                         abs(X(j,i))

     The array is indexed by the right-hand side i (on which the
     componentwise relative error depends), and the type of error
     information as described below. There currently are up to three
     pieces of information returned for each right-hand side. If
     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
     ERR_BNDS_COMP is not accessed.  If N_ERR_BNDS < 3, then at most
     the first (:,N_ERR_BNDS) entries are returned.

     The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_COMP(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated componentwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*(A*diag(x)), where x is the solution for the
              current right-hand side and S scales each row of
              A*diag(x) by a power of the radix so all absolute row
              sums of Z are approximately 1.

     This subroutine is only responsible for setting the second field
     above.
     See Lapack Working Note 165 for further details and extra
     cautions.
[in]RES
          RES is DOUBLE PRECISION array, dimension (N)
     Workspace to hold the intermediate residual.
[in]AYB
          AYB is DOUBLE PRECISION array, dimension (N)
     Workspace. This can be the same workspace passed for Y_TAIL.
[in]DY
          DY is DOUBLE PRECISION array, dimension (N)
     Workspace to hold the intermediate solution.
[in]Y_TAIL
          Y_TAIL is DOUBLE PRECISION array, dimension (N)
     Workspace to hold the trailing bits of the intermediate solution.
[in]RCOND
          RCOND is DOUBLE PRECISION
     Reciprocal scaled condition number.  This is an estimate of the
     reciprocal Skeel condition number of the matrix A after
     equilibration (if done).  If this is less than the machine
     precision (in particular, if it is zero), the matrix is singular
     to working precision.  Note that the error may still be small even
     if this number is very small and the matrix appears ill-
     conditioned.
[in]ITHRESH
          ITHRESH is INTEGER
     The maximum number of residual computations allowed for
     refinement. The default is 10. For 'aggressive' set to 100 to
     permit convergence using approximate factorizations or
     factorizations other than LU. If the factorization uses a
     technique other than Gaussian elimination, the guarantees in
     ERR_BNDS_NORM and ERR_BNDS_COMP may no longer be trustworthy.
[in]RTHRESH
          RTHRESH is DOUBLE PRECISION
     Determines when to stop refinement if the error estimate stops
     decreasing. Refinement will stop when the next solution no longer
     satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
     the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
     default value is 0.5. For 'aggressive' set to 0.9 to permit
     convergence on extremely ill-conditioned matrices. See LAWN 165
     for more details.
[in]DZ_UB
          DZ_UB is DOUBLE PRECISION
     Determines when to start considering componentwise convergence.
     Componentwise convergence is only considered after each component
     of the solution Y is stable, which we define as the relative
     change in each component being less than DZ_UB. The default value
     is 0.25, requiring the first bit to be stable. See LAWN 165 for
     more details.
[in]IGNORE_CWISE
          IGNORE_CWISE is LOGICAL
     If .TRUE. then ignore componentwise convergence. Default value
     is .FALSE..
[out]INFO
          INFO is INTEGER
       = 0:  Successful exit.
       < 0:  if INFO = -i, the ith argument to DGBTRS had an illegal
             value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 404 of file dla_gbrfsx_extended.f.

411 *
412 * -- LAPACK computational routine --
413 * -- LAPACK is a software package provided by Univ. of Tennessee, --
414 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
415 *
416 * .. Scalar Arguments ..
417  INTEGER INFO, LDAB, LDAFB, LDB, LDY, N, KL, KU, NRHS,
418  $ PREC_TYPE, TRANS_TYPE, N_NORMS, ITHRESH
419  LOGICAL COLEQU, IGNORE_CWISE
420  DOUBLE PRECISION RTHRESH, DZ_UB
421 * ..
422 * .. Array Arguments ..
423  INTEGER IPIV( * )
424  DOUBLE PRECISION AB( LDAB, * ), AFB( LDAFB, * ), B( LDB, * ),
425  $ Y( LDY, * ), RES(*), DY(*), Y_TAIL(*)
426  DOUBLE PRECISION C( * ), AYB(*), RCOND, BERR_OUT(*),
427  $ ERR_BNDS_NORM( NRHS, * ),
428  $ ERR_BNDS_COMP( NRHS, * )
429 * ..
430 *
431 * =====================================================================
432 *
433 * .. Local Scalars ..
434  CHARACTER TRANS
435  INTEGER CNT, I, J, M, X_STATE, Z_STATE, Y_PREC_STATE
436  DOUBLE PRECISION YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
437  $ DZRAT, PREVNORMDX, PREV_DZ_Z, DXRATMAX,
438  $ DZRATMAX, DX_X, DZ_Z, FINAL_DX_X, FINAL_DZ_Z,
439  $ EPS, HUGEVAL, INCR_THRESH
440  LOGICAL INCR_PREC
441 * ..
442 * .. Parameters ..
443  INTEGER UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
444  $ NOPROG_STATE, BASE_RESIDUAL, EXTRA_RESIDUAL,
445  $ EXTRA_Y
446  parameter( unstable_state = 0, working_state = 1,
447  $ conv_state = 2, noprog_state = 3 )
448  parameter( base_residual = 0, extra_residual = 1,
449  $ extra_y = 2 )
450  INTEGER FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
451  INTEGER RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
452  INTEGER CMP_ERR_I, PIV_GROWTH_I
453  parameter( final_nrm_err_i = 1, final_cmp_err_i = 2,
454  $ berr_i = 3 )
455  parameter( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
456  parameter( cmp_rcond_i = 7, cmp_err_i = 8,
457  $ piv_growth_i = 9 )
458  INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
459  $ LA_LINRX_CWISE_I
460  parameter( la_linrx_itref_i = 1,
461  $ la_linrx_ithresh_i = 2 )
462  parameter( la_linrx_cwise_i = 3 )
463  INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
464  $ LA_LINRX_RCOND_I
465  parameter( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
466  parameter( la_linrx_rcond_i = 3 )
467 * ..
468 * .. External Subroutines ..
469  EXTERNAL daxpy, dcopy, dgbtrs, dgbmv, blas_dgbmv_x,
470  $ blas_dgbmv2_x, dla_gbamv, dla_wwaddw, dlamch,
472  DOUBLE PRECISION DLAMCH
473  CHARACTER CHLA_TRANSTYPE
474 * ..
475 * .. Intrinsic Functions ..
476  INTRINSIC abs, max, min
477 * ..
478 * .. Executable Statements ..
479 *
480  IF (info.NE.0) RETURN
481  trans = chla_transtype(trans_type)
482  eps = dlamch( 'Epsilon' )
483  hugeval = dlamch( 'Overflow' )
484 * Force HUGEVAL to Inf
485  hugeval = hugeval * hugeval
486 * Using HUGEVAL may lead to spurious underflows.
487  incr_thresh = dble( n ) * eps
488  m = kl+ku+1
489 
490  DO j = 1, nrhs
491  y_prec_state = extra_residual
492  IF ( y_prec_state .EQ. extra_y ) THEN
493  DO i = 1, n
494  y_tail( i ) = 0.0d+0
495  END DO
496  END IF
497 
498  dxrat = 0.0d+0
499  dxratmax = 0.0d+0
500  dzrat = 0.0d+0
501  dzratmax = 0.0d+0
502  final_dx_x = hugeval
503  final_dz_z = hugeval
504  prevnormdx = hugeval
505  prev_dz_z = hugeval
506  dz_z = hugeval
507  dx_x = hugeval
508 
509  x_state = working_state
510  z_state = unstable_state
511  incr_prec = .false.
512 
513  DO cnt = 1, ithresh
514 *
515 * Compute residual RES = B_s - op(A_s) * Y,
516 * op(A) = A, A**T, or A**H depending on TRANS (and type).
517 *
518  CALL dcopy( n, b( 1, j ), 1, res, 1 )
519  IF ( y_prec_state .EQ. base_residual ) THEN
520  CALL dgbmv( trans, m, n, kl, ku, -1.0d+0, ab, ldab,
521  $ y( 1, j ), 1, 1.0d+0, res, 1 )
522  ELSE IF ( y_prec_state .EQ. extra_residual ) THEN
523  CALL blas_dgbmv_x( trans_type, n, n, kl, ku,
524  $ -1.0d+0, ab, ldab, y( 1, j ), 1, 1.0d+0, res, 1,
525  $ prec_type )
526  ELSE
527  CALL blas_dgbmv2_x( trans_type, n, n, kl, ku, -1.0d+0,
528  $ ab, ldab, y( 1, j ), y_tail, 1, 1.0d+0, res, 1,
529  $ prec_type )
530  END IF
531 
532 ! XXX: RES is no longer needed.
533  CALL dcopy( n, res, 1, dy, 1 )
534  CALL dgbtrs( trans, n, kl, ku, 1, afb, ldafb, ipiv, dy, n,
535  $ info )
536 *
537 * Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
538 *
539  normx = 0.0d+0
540  normy = 0.0d+0
541  normdx = 0.0d+0
542  dz_z = 0.0d+0
543  ymin = hugeval
544 
545  DO i = 1, n
546  yk = abs( y( i, j ) )
547  dyk = abs( dy( i ) )
548 
549  IF ( yk .NE. 0.0d+0 ) THEN
550  dz_z = max( dz_z, dyk / yk )
551  ELSE IF ( dyk .NE. 0.0d+0 ) THEN
552  dz_z = hugeval
553  END IF
554 
555  ymin = min( ymin, yk )
556 
557  normy = max( normy, yk )
558 
559  IF ( colequ ) THEN
560  normx = max( normx, yk * c( i ) )
561  normdx = max( normdx, dyk * c( i ) )
562  ELSE
563  normx = normy
564  normdx = max( normdx, dyk )
565  END IF
566  END DO
567 
568  IF ( normx .NE. 0.0d+0 ) THEN
569  dx_x = normdx / normx
570  ELSE IF ( normdx .EQ. 0.0d+0 ) THEN
571  dx_x = 0.0d+0
572  ELSE
573  dx_x = hugeval
574  END IF
575 
576  dxrat = normdx / prevnormdx
577  dzrat = dz_z / prev_dz_z
578 *
579 * Check termination criteria.
580 *
581  IF ( .NOT.ignore_cwise
582  $ .AND. ymin*rcond .LT. incr_thresh*normy
583  $ .AND. y_prec_state .LT. extra_y )
584  $ incr_prec = .true.
585 
586  IF ( x_state .EQ. noprog_state .AND. dxrat .LE. rthresh )
587  $ x_state = working_state
588  IF ( x_state .EQ. working_state ) THEN
589  IF ( dx_x .LE. eps ) THEN
590  x_state = conv_state
591  ELSE IF ( dxrat .GT. rthresh ) THEN
592  IF ( y_prec_state .NE. extra_y ) THEN
593  incr_prec = .true.
594  ELSE
595  x_state = noprog_state
596  END IF
597  ELSE
598  IF ( dxrat .GT. dxratmax ) dxratmax = dxrat
599  END IF
600  IF ( x_state .GT. working_state ) final_dx_x = dx_x
601  END IF
602 
603  IF ( z_state .EQ. unstable_state .AND. dz_z .LE. dz_ub )
604  $ z_state = working_state
605  IF ( z_state .EQ. noprog_state .AND. dzrat .LE. rthresh )
606  $ z_state = working_state
607  IF ( z_state .EQ. working_state ) THEN
608  IF ( dz_z .LE. eps ) THEN
609  z_state = conv_state
610  ELSE IF ( dz_z .GT. dz_ub ) THEN
611  z_state = unstable_state
612  dzratmax = 0.0d+0
613  final_dz_z = hugeval
614  ELSE IF ( dzrat .GT. rthresh ) THEN
615  IF ( y_prec_state .NE. extra_y ) THEN
616  incr_prec = .true.
617  ELSE
618  z_state = noprog_state
619  END IF
620  ELSE
621  IF ( dzrat .GT. dzratmax ) dzratmax = dzrat
622  END IF
623  IF ( z_state .GT. working_state ) final_dz_z = dz_z
624  END IF
625 *
626 * Exit if both normwise and componentwise stopped working,
627 * but if componentwise is unstable, let it go at least two
628 * iterations.
629 *
630  IF ( x_state.NE.working_state ) THEN
631  IF ( ignore_cwise ) GOTO 666
632  IF ( z_state.EQ.noprog_state .OR. z_state.EQ.conv_state )
633  $ GOTO 666
634  IF ( z_state.EQ.unstable_state .AND. cnt.GT.1 ) GOTO 666
635  END IF
636 
637  IF ( incr_prec ) THEN
638  incr_prec = .false.
639  y_prec_state = y_prec_state + 1
640  DO i = 1, n
641  y_tail( i ) = 0.0d+0
642  END DO
643  END IF
644 
645  prevnormdx = normdx
646  prev_dz_z = dz_z
647 *
648 * Update soluton.
649 *
650  IF (y_prec_state .LT. extra_y) THEN
651  CALL daxpy( n, 1.0d+0, dy, 1, y(1,j), 1 )
652  ELSE
653  CALL dla_wwaddw( n, y(1,j), y_tail, dy )
654  END IF
655 
656  END DO
657 * Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
658  666 CONTINUE
659 *
660 * Set final_* when cnt hits ithresh.
661 *
662  IF ( x_state .EQ. working_state ) final_dx_x = dx_x
663  IF ( z_state .EQ. working_state ) final_dz_z = dz_z
664 *
665 * Compute error bounds.
666 *
667  IF ( n_norms .GE. 1 ) THEN
668  err_bnds_norm( j, la_linrx_err_i ) =
669  $ final_dx_x / (1 - dxratmax)
670  END IF
671  IF (n_norms .GE. 2) THEN
672  err_bnds_comp( j, la_linrx_err_i ) =
673  $ final_dz_z / (1 - dzratmax)
674  END IF
675 *
676 * Compute componentwise relative backward error from formula
677 * max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
678 * where abs(Z) is the componentwise absolute value of the matrix
679 * or vector Z.
680 *
681 * Compute residual RES = B_s - op(A_s) * Y,
682 * op(A) = A, A**T, or A**H depending on TRANS (and type).
683 *
684  CALL dcopy( n, b( 1, j ), 1, res, 1 )
685  CALL dgbmv(trans, n, n, kl, ku, -1.0d+0, ab, ldab, y(1,j),
686  $ 1, 1.0d+0, res, 1 )
687 
688  DO i = 1, n
689  ayb( i ) = abs( b( i, j ) )
690  END DO
691 *
692 * Compute abs(op(A_s))*abs(Y) + abs(B_s).
693 *
694  CALL dla_gbamv( trans_type, n, n, kl, ku, 1.0d+0,
695  $ ab, ldab, y(1, j), 1, 1.0d+0, ayb, 1 )
696 
697  CALL dla_lin_berr( n, n, 1, res, ayb, berr_out( j ) )
698 *
699 * End of loop for each RHS
700 *
701  END DO
702 *
703  RETURN
704 *
705 * End of DLA_GBRFSX_EXTENDED
706 *
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:69
character *1 function chla_transtype(TRANS)
CHLA_TRANSTYPE
subroutine dcopy(N, DX, INCX, DY, INCY)
DCOPY
Definition: dcopy.f:82
subroutine daxpy(N, DA, DX, INCX, DY, INCY)
DAXPY
Definition: daxpy.f:89
subroutine dgbmv(TRANS, M, N, KL, KU, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
DGBMV
Definition: dgbmv.f:185
subroutine dgbtrs(TRANS, N, KL, KU, NRHS, AB, LDAB, IPIV, B, LDB, INFO)
DGBTRS
Definition: dgbtrs.f:138
subroutine dla_gbamv(TRANS, M, N, KL, KU, ALPHA, AB, LDAB, X, INCX, BETA, Y, INCY)
DLA_GBAMV performs a matrix-vector operation to calculate error bounds.
Definition: dla_gbamv.f:185
subroutine dla_lin_berr(N, NZ, NRHS, RES, AYB, BERR)
DLA_LIN_BERR computes a component-wise relative backward error.
Definition: dla_lin_berr.f:101
subroutine dla_wwaddw(N, X, Y, W)
DLA_WWADDW adds a vector into a doubled-single vector.
Definition: dla_wwaddw.f:81
Here is the call graph for this function:
Here is the caller graph for this function: