LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ clansy()

real function clansy ( character  NORM,
character  UPLO,
integer  N,
complex, dimension( lda, * )  A,
integer  LDA,
real, dimension( * )  WORK 
)

CLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex symmetric matrix.

Download CLANSY + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CLANSY  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the  element of  largest absolute value  of a
 complex symmetric matrix A.
Returns
CLANSY
    CLANSY = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in CLANSY as described
          above.
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the upper or lower triangular part of the
          symmetric matrix A is to be referenced.
          = 'U':  Upper triangular part of A is referenced
          = 'L':  Lower triangular part of A is referenced
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.  When N = 0, CLANSY is
          set to zero.
[in]A
          A is COMPLEX array, dimension (LDA,N)
          The symmetric matrix A.  If UPLO = 'U', the leading n by n
          upper triangular part of A contains the upper triangular part
          of the matrix A, and the strictly lower triangular part of A
          is not referenced.  If UPLO = 'L', the leading n by n lower
          triangular part of A contains the lower triangular part of
          the matrix A, and the strictly upper triangular part of A is
          not referenced.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(N,1).
[out]WORK
          WORK is REAL array, dimension (MAX(1,LWORK)),
          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
          WORK is not referenced.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 122 of file clansy.f.

123 *
124 * -- LAPACK auxiliary routine --
125 * -- LAPACK is a software package provided by Univ. of Tennessee, --
126 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
127 *
128  IMPLICIT NONE
129 * .. Scalar Arguments ..
130  CHARACTER NORM, UPLO
131  INTEGER LDA, N
132 * ..
133 * .. Array Arguments ..
134  REAL WORK( * )
135  COMPLEX A( LDA, * )
136 * ..
137 *
138 * =====================================================================
139 *
140 * .. Parameters ..
141  REAL ONE, ZERO
142  parameter( one = 1.0e+0, zero = 0.0e+0 )
143 * ..
144 * .. Local Scalars ..
145  INTEGER I, J
146  REAL ABSA, SUM, VALUE
147 * ..
148 * .. Local Arrays ..
149  REAL SSQ( 2 ), COLSSQ( 2 )
150 * ..
151 * .. External Functions ..
152  LOGICAL LSAME, SISNAN
153  EXTERNAL lsame, sisnan
154 * ..
155 * .. External Subroutines ..
156  EXTERNAL classq, scombssq
157 * ..
158 * .. Intrinsic Functions ..
159  INTRINSIC abs, sqrt
160 * ..
161 * .. Executable Statements ..
162 *
163  IF( n.EQ.0 ) THEN
164  VALUE = zero
165  ELSE IF( lsame( norm, 'M' ) ) THEN
166 *
167 * Find max(abs(A(i,j))).
168 *
169  VALUE = zero
170  IF( lsame( uplo, 'U' ) ) THEN
171  DO 20 j = 1, n
172  DO 10 i = 1, j
173  sum = abs( a( i, j ) )
174  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
175  10 CONTINUE
176  20 CONTINUE
177  ELSE
178  DO 40 j = 1, n
179  DO 30 i = j, n
180  sum = abs( a( i, j ) )
181  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
182  30 CONTINUE
183  40 CONTINUE
184  END IF
185  ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
186  $ ( norm.EQ.'1' ) ) THEN
187 *
188 * Find normI(A) ( = norm1(A), since A is symmetric).
189 *
190  VALUE = zero
191  IF( lsame( uplo, 'U' ) ) THEN
192  DO 60 j = 1, n
193  sum = zero
194  DO 50 i = 1, j - 1
195  absa = abs( a( i, j ) )
196  sum = sum + absa
197  work( i ) = work( i ) + absa
198  50 CONTINUE
199  work( j ) = sum + abs( a( j, j ) )
200  60 CONTINUE
201  DO 70 i = 1, n
202  sum = work( i )
203  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
204  70 CONTINUE
205  ELSE
206  DO 80 i = 1, n
207  work( i ) = zero
208  80 CONTINUE
209  DO 100 j = 1, n
210  sum = work( j ) + abs( a( j, j ) )
211  DO 90 i = j + 1, n
212  absa = abs( a( i, j ) )
213  sum = sum + absa
214  work( i ) = work( i ) + absa
215  90 CONTINUE
216  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
217  100 CONTINUE
218  END IF
219  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
220 *
221 * Find normF(A).
222 * SSQ(1) is scale
223 * SSQ(2) is sum-of-squares
224 * For better accuracy, sum each column separately.
225 *
226  ssq( 1 ) = zero
227  ssq( 2 ) = one
228 *
229 * Sum off-diagonals
230 *
231  IF( lsame( uplo, 'U' ) ) THEN
232  DO 110 j = 2, n
233  colssq( 1 ) = zero
234  colssq( 2 ) = one
235  CALL classq( j-1, a( 1, j ), 1, colssq(1), colssq(2) )
236  CALL scombssq( ssq, colssq )
237  110 CONTINUE
238  ELSE
239  DO 120 j = 1, n - 1
240  colssq( 1 ) = zero
241  colssq( 2 ) = one
242  CALL classq( n-j, a( j+1, j ), 1, colssq(1), colssq(2) )
243  CALL scombssq( ssq, colssq )
244  120 CONTINUE
245  END IF
246  ssq( 2 ) = 2*ssq( 2 )
247 *
248 * Sum diagonal
249 *
250  colssq( 1 ) = zero
251  colssq( 2 ) = one
252  CALL classq( n, a, lda+1, colssq( 1 ), colssq( 2 ) )
253  CALL scombssq( ssq, colssq )
254  VALUE = ssq( 1 )*sqrt( ssq( 2 ) )
255  END IF
256 *
257  clansy = VALUE
258  RETURN
259 *
260 * End of CLANSY
261 *
subroutine scombssq(V1, V2)
SCOMBSSQ adds two scaled sum of squares quantities
Definition: scombssq.f:60
subroutine classq(n, x, incx, scl, sumsq)
CLASSQ updates a sum of squares represented in scaled form.
Definition: classq.f90:126
logical function sisnan(SIN)
SISNAN tests input for NaN.
Definition: sisnan.f:59
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
real function clansy(NORM, UPLO, N, A, LDA, WORK)
CLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: clansy.f:123
Here is the call graph for this function:
Here is the caller graph for this function: