LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ sggrqf()

subroutine sggrqf ( integer  M,
integer  P,
integer  N,
real, dimension( lda, * )  A,
integer  LDA,
real, dimension( * )  TAUA,
real, dimension( ldb, * )  B,
integer  LDB,
real, dimension( * )  TAUB,
real, dimension( * )  WORK,
integer  LWORK,
integer  INFO 
)

SGGRQF

Download SGGRQF + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 SGGRQF computes a generalized RQ factorization of an M-by-N matrix A
 and a P-by-N matrix B:

             A = R*Q,        B = Z*T*Q,

 where Q is an N-by-N orthogonal matrix, Z is a P-by-P orthogonal
 matrix, and R and T assume one of the forms:

 if M <= N,  R = ( 0  R12 ) M,   or if M > N,  R = ( R11 ) M-N,
                  N-M  M                           ( R21 ) N
                                                      N

 where R12 or R21 is upper triangular, and

 if P >= N,  T = ( T11 ) N  ,   or if P < N,  T = ( T11  T12 ) P,
                 (  0  ) P-N                         P   N-P
                    N

 where T11 is upper triangular.

 In particular, if B is square and nonsingular, the GRQ factorization
 of A and B implicitly gives the RQ factorization of A*inv(B):

              A*inv(B) = (R*inv(T))*Z**T

 where inv(B) denotes the inverse of the matrix B, and Z**T denotes the
 transpose of the matrix Z.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >= 0.
[in]P
          P is INTEGER
          The number of rows of the matrix B.  P >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrices A and B. N >= 0.
[in,out]A
          A is REAL array, dimension (LDA,N)
          On entry, the M-by-N matrix A.
          On exit, if M <= N, the upper triangle of the subarray
          A(1:M,N-M+1:N) contains the M-by-M upper triangular matrix R;
          if M > N, the elements on and above the (M-N)-th subdiagonal
          contain the M-by-N upper trapezoidal matrix R; the remaining
          elements, with the array TAUA, represent the orthogonal
          matrix Q as a product of elementary reflectors (see Further
          Details).
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A. LDA >= max(1,M).
[out]TAUA
          TAUA is REAL array, dimension (min(M,N))
          The scalar factors of the elementary reflectors which
          represent the orthogonal matrix Q (see Further Details).
[in,out]B
          B is REAL array, dimension (LDB,N)
          On entry, the P-by-N matrix B.
          On exit, the elements on and above the diagonal of the array
          contain the min(P,N)-by-N upper trapezoidal matrix T (T is
          upper triangular if P >= N); the elements below the diagonal,
          with the array TAUB, represent the orthogonal matrix Z as a
          product of elementary reflectors (see Further Details).
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B. LDB >= max(1,P).
[out]TAUB
          TAUB is REAL array, dimension (min(P,N))
          The scalar factors of the elementary reflectors which
          represent the orthogonal matrix Z (see Further Details).
[out]WORK
          WORK is REAL array, dimension (MAX(1,LWORK))
          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
[in]LWORK
          LWORK is INTEGER
          The dimension of the array WORK. LWORK >= max(1,N,M,P).
          For optimum performance LWORK >= max(N,M,P)*max(NB1,NB2,NB3),
          where NB1 is the optimal blocksize for the RQ factorization
          of an M-by-N matrix, NB2 is the optimal blocksize for the
          QR factorization of a P-by-N matrix, and NB3 is the optimal
          blocksize for a call of SORMRQ.

          If LWORK = -1, then a workspace query is assumed; the routine
          only calculates the optimal size of the WORK array, returns
          this value as the first entry of the WORK array, and no error
          message related to LWORK is issued by XERBLA.
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INF0= -i, the i-th argument had an illegal value.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
  The matrix Q is represented as a product of elementary reflectors

     Q = H(1) H(2) . . . H(k), where k = min(m,n).

  Each H(i) has the form

     H(i) = I - taua * v * v**T

  where taua is a real scalar, and v is a real vector with
  v(n-k+i+1:n) = 0 and v(n-k+i) = 1; v(1:n-k+i-1) is stored on exit in
  A(m-k+i,1:n-k+i-1), and taua in TAUA(i).
  To form Q explicitly, use LAPACK subroutine SORGRQ.
  To use Q to update another matrix, use LAPACK subroutine SORMRQ.

  The matrix Z is represented as a product of elementary reflectors

     Z = H(1) H(2) . . . H(k), where k = min(p,n).

  Each H(i) has the form

     H(i) = I - taub * v * v**T

  where taub is a real scalar, and v is a real vector with
  v(1:i-1) = 0 and v(i) = 1; v(i+1:p) is stored on exit in B(i+1:p,i),
  and taub in TAUB(i).
  To form Z explicitly, use LAPACK subroutine SORGQR.
  To use Z to update another matrix, use LAPACK subroutine SORMQR.

Definition at line 212 of file sggrqf.f.

214 *
215 * -- LAPACK computational routine --
216 * -- LAPACK is a software package provided by Univ. of Tennessee, --
217 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
218 *
219 * .. Scalar Arguments ..
220  INTEGER INFO, LDA, LDB, LWORK, M, N, P
221 * ..
222 * .. Array Arguments ..
223  REAL A( LDA, * ), B( LDB, * ), TAUA( * ), TAUB( * ),
224  $ WORK( * )
225 * ..
226 *
227 * =====================================================================
228 *
229 * .. Local Scalars ..
230  LOGICAL LQUERY
231  INTEGER LOPT, LWKOPT, NB, NB1, NB2, NB3
232 * ..
233 * .. External Subroutines ..
234  EXTERNAL sgeqrf, sgerqf, sormrq, xerbla
235 * ..
236 * .. External Functions ..
237  INTEGER ILAENV
238  EXTERNAL ilaenv
239 * ..
240 * .. Intrinsic Functions ..
241  INTRINSIC int, max, min
242 * ..
243 * .. Executable Statements ..
244 *
245 * Test the input parameters
246 *
247  info = 0
248  nb1 = ilaenv( 1, 'SGERQF', ' ', m, n, -1, -1 )
249  nb2 = ilaenv( 1, 'SGEQRF', ' ', p, n, -1, -1 )
250  nb3 = ilaenv( 1, 'SORMRQ', ' ', m, n, p, -1 )
251  nb = max( nb1, nb2, nb3 )
252  lwkopt = max( n, m, p)*nb
253  work( 1 ) = lwkopt
254  lquery = ( lwork.EQ.-1 )
255  IF( m.LT.0 ) THEN
256  info = -1
257  ELSE IF( p.LT.0 ) THEN
258  info = -2
259  ELSE IF( n.LT.0 ) THEN
260  info = -3
261  ELSE IF( lda.LT.max( 1, m ) ) THEN
262  info = -5
263  ELSE IF( ldb.LT.max( 1, p ) ) THEN
264  info = -8
265  ELSE IF( lwork.LT.max( 1, m, p, n ) .AND. .NOT.lquery ) THEN
266  info = -11
267  END IF
268  IF( info.NE.0 ) THEN
269  CALL xerbla( 'SGGRQF', -info )
270  RETURN
271  ELSE IF( lquery ) THEN
272  RETURN
273  END IF
274 *
275 * RQ factorization of M-by-N matrix A: A = R*Q
276 *
277  CALL sgerqf( m, n, a, lda, taua, work, lwork, info )
278  lopt = work( 1 )
279 *
280 * Update B := B*Q**T
281 *
282  CALL sormrq( 'Right', 'Transpose', p, n, min( m, n ),
283  $ a( max( 1, m-n+1 ), 1 ), lda, taua, b, ldb, work,
284  $ lwork, info )
285  lopt = max( lopt, int( work( 1 ) ) )
286 *
287 * QR factorization of P-by-N matrix B: B = Z*T
288 *
289  CALL sgeqrf( p, n, b, ldb, taub, work, lwork, info )
290  work( 1 ) = max( lopt, int( work( 1 ) ) )
291 *
292  RETURN
293 *
294 * End of SGGRQF
295 *
integer function ilaenv(ISPEC, NAME, OPTS, N1, N2, N3, N4)
ILAENV
Definition: ilaenv.f:162
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine sgerqf(M, N, A, LDA, TAU, WORK, LWORK, INFO)
SGERQF
Definition: sgerqf.f:138
subroutine sgeqrf(M, N, A, LDA, TAU, WORK, LWORK, INFO)
SGEQRF
Definition: sgeqrf.f:145
subroutine sormrq(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
SORMRQ
Definition: sormrq.f:168
Here is the call graph for this function:
Here is the caller graph for this function: