LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ spbtf2()

subroutine spbtf2 ( character  UPLO,
integer  N,
integer  KD,
real, dimension( ldab, * )  AB,
integer  LDAB,
integer  INFO 
)

SPBTF2 computes the Cholesky factorization of a symmetric/Hermitian positive definite band matrix (unblocked algorithm).

Download SPBTF2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 SPBTF2 computes the Cholesky factorization of a real symmetric
 positive definite band matrix A.

 The factorization has the form
    A = U**T * U ,  if UPLO = 'U', or
    A = L  * L**T,  if UPLO = 'L',
 where U is an upper triangular matrix, U**T is the transpose of U, and
 L is lower triangular.

 This is the unblocked version of the algorithm, calling Level 2 BLAS.
Parameters
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the upper or lower triangular part of the
          symmetric matrix A is stored:
          = 'U':  Upper triangular
          = 'L':  Lower triangular
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in]KD
          KD is INTEGER
          The number of super-diagonals of the matrix A if UPLO = 'U',
          or the number of sub-diagonals if UPLO = 'L'.  KD >= 0.
[in,out]AB
          AB is REAL array, dimension (LDAB,N)
          On entry, the upper or lower triangle of the symmetric band
          matrix A, stored in the first KD+1 rows of the array.  The
          j-th column of A is stored in the j-th column of the array AB
          as follows:
          if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j;
          if UPLO = 'L', AB(1+i-j,j)    = A(i,j) for j<=i<=min(n,j+kd).

          On exit, if INFO = 0, the triangular factor U or L from the
          Cholesky factorization A = U**T*U or A = L*L**T of the band
          matrix A, in the same storage format as A.
[in]LDAB
          LDAB is INTEGER
          The leading dimension of the array AB.  LDAB >= KD+1.
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -k, the k-th argument had an illegal value
          > 0: if INFO = k, the leading minor of order k is not
               positive definite, and the factorization could not be
               completed.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
  The band storage scheme is illustrated by the following example, when
  N = 6, KD = 2, and UPLO = 'U':

  On entry:                       On exit:

      *    *   a13  a24  a35  a46      *    *   u13  u24  u35  u46
      *   a12  a23  a34  a45  a56      *   u12  u23  u34  u45  u56
     a11  a22  a33  a44  a55  a66     u11  u22  u33  u44  u55  u66

  Similarly, if UPLO = 'L' the format of A is as follows:

  On entry:                       On exit:

     a11  a22  a33  a44  a55  a66     l11  l22  l33  l44  l55  l66
     a21  a32  a43  a54  a65   *      l21  l32  l43  l54  l65   *
     a31  a42  a53  a64   *    *      l31  l42  l53  l64   *    *

  Array elements marked * are not used by the routine.

Definition at line 141 of file spbtf2.f.

142 *
143 * -- LAPACK computational routine --
144 * -- LAPACK is a software package provided by Univ. of Tennessee, --
145 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
146 *
147 * .. Scalar Arguments ..
148  CHARACTER UPLO
149  INTEGER INFO, KD, LDAB, N
150 * ..
151 * .. Array Arguments ..
152  REAL AB( LDAB, * )
153 * ..
154 *
155 * =====================================================================
156 *
157 * .. Parameters ..
158  REAL ONE, ZERO
159  parameter( one = 1.0e+0, zero = 0.0e+0 )
160 * ..
161 * .. Local Scalars ..
162  LOGICAL UPPER
163  INTEGER J, KLD, KN
164  REAL AJJ
165 * ..
166 * .. External Functions ..
167  LOGICAL LSAME
168  EXTERNAL lsame
169 * ..
170 * .. External Subroutines ..
171  EXTERNAL sscal, ssyr, xerbla
172 * ..
173 * .. Intrinsic Functions ..
174  INTRINSIC max, min, sqrt
175 * ..
176 * .. Executable Statements ..
177 *
178 * Test the input parameters.
179 *
180  info = 0
181  upper = lsame( uplo, 'U' )
182  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
183  info = -1
184  ELSE IF( n.LT.0 ) THEN
185  info = -2
186  ELSE IF( kd.LT.0 ) THEN
187  info = -3
188  ELSE IF( ldab.LT.kd+1 ) THEN
189  info = -5
190  END IF
191  IF( info.NE.0 ) THEN
192  CALL xerbla( 'SPBTF2', -info )
193  RETURN
194  END IF
195 *
196 * Quick return if possible
197 *
198  IF( n.EQ.0 )
199  $ RETURN
200 *
201  kld = max( 1, ldab-1 )
202 *
203  IF( upper ) THEN
204 *
205 * Compute the Cholesky factorization A = U**T*U.
206 *
207  DO 10 j = 1, n
208 *
209 * Compute U(J,J) and test for non-positive-definiteness.
210 *
211  ajj = ab( kd+1, j )
212  IF( ajj.LE.zero )
213  $ GO TO 30
214  ajj = sqrt( ajj )
215  ab( kd+1, j ) = ajj
216 *
217 * Compute elements J+1:J+KN of row J and update the
218 * trailing submatrix within the band.
219 *
220  kn = min( kd, n-j )
221  IF( kn.GT.0 ) THEN
222  CALL sscal( kn, one / ajj, ab( kd, j+1 ), kld )
223  CALL ssyr( 'Upper', kn, -one, ab( kd, j+1 ), kld,
224  $ ab( kd+1, j+1 ), kld )
225  END IF
226  10 CONTINUE
227  ELSE
228 *
229 * Compute the Cholesky factorization A = L*L**T.
230 *
231  DO 20 j = 1, n
232 *
233 * Compute L(J,J) and test for non-positive-definiteness.
234 *
235  ajj = ab( 1, j )
236  IF( ajj.LE.zero )
237  $ GO TO 30
238  ajj = sqrt( ajj )
239  ab( 1, j ) = ajj
240 *
241 * Compute elements J+1:J+KN of column J and update the
242 * trailing submatrix within the band.
243 *
244  kn = min( kd, n-j )
245  IF( kn.GT.0 ) THEN
246  CALL sscal( kn, one / ajj, ab( 2, j ), 1 )
247  CALL ssyr( 'Lower', kn, -one, ab( 2, j ), 1,
248  $ ab( 1, j+1 ), kld )
249  END IF
250  20 CONTINUE
251  END IF
252  RETURN
253 *
254  30 CONTINUE
255  info = j
256  RETURN
257 *
258 * End of SPBTF2
259 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine sscal(N, SA, SX, INCX)
SSCAL
Definition: sscal.f:79
subroutine ssyr(UPLO, N, ALPHA, X, INCX, A, LDA)
SSYR
Definition: ssyr.f:132
Here is the call graph for this function:
Here is the caller graph for this function: