LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ sorgr2()

subroutine sorgr2 ( integer  M,
integer  N,
integer  K,
real, dimension( lda, * )  A,
integer  LDA,
real, dimension( * )  TAU,
real, dimension( * )  WORK,
integer  INFO 
)

SORGR2 generates all or part of the orthogonal matrix Q from an RQ factorization determined by sgerqf (unblocked algorithm).

Download SORGR2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 SORGR2 generates an m by n real matrix Q with orthonormal rows,
 which is defined as the last m rows of a product of k elementary
 reflectors of order n

       Q  =  H(1) H(2) . . . H(k)

 as returned by SGERQF.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix Q. M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix Q. N >= M.
[in]K
          K is INTEGER
          The number of elementary reflectors whose product defines the
          matrix Q. M >= K >= 0.
[in,out]A
          A is REAL array, dimension (LDA,N)
          On entry, the (m-k+i)-th row must contain the vector which
          defines the elementary reflector H(i), for i = 1,2,...,k, as
          returned by SGERQF in the last k rows of its array argument
          A.
          On exit, the m by n matrix Q.
[in]LDA
          LDA is INTEGER
          The first dimension of the array A. LDA >= max(1,M).
[in]TAU
          TAU is REAL array, dimension (K)
          TAU(i) must contain the scalar factor of the elementary
          reflector H(i), as returned by SGERQF.
[out]WORK
          WORK is REAL array, dimension (M)
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument has an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 113 of file sorgr2.f.

114 *
115 * -- LAPACK computational routine --
116 * -- LAPACK is a software package provided by Univ. of Tennessee, --
117 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
118 *
119 * .. Scalar Arguments ..
120  INTEGER INFO, K, LDA, M, N
121 * ..
122 * .. Array Arguments ..
123  REAL A( LDA, * ), TAU( * ), WORK( * )
124 * ..
125 *
126 * =====================================================================
127 *
128 * .. Parameters ..
129  REAL ONE, ZERO
130  parameter( one = 1.0e+0, zero = 0.0e+0 )
131 * ..
132 * .. Local Scalars ..
133  INTEGER I, II, J, L
134 * ..
135 * .. External Subroutines ..
136  EXTERNAL slarf, sscal, xerbla
137 * ..
138 * .. Intrinsic Functions ..
139  INTRINSIC max
140 * ..
141 * .. Executable Statements ..
142 *
143 * Test the input arguments
144 *
145  info = 0
146  IF( m.LT.0 ) THEN
147  info = -1
148  ELSE IF( n.LT.m ) THEN
149  info = -2
150  ELSE IF( k.LT.0 .OR. k.GT.m ) THEN
151  info = -3
152  ELSE IF( lda.LT.max( 1, m ) ) THEN
153  info = -5
154  END IF
155  IF( info.NE.0 ) THEN
156  CALL xerbla( 'SORGR2', -info )
157  RETURN
158  END IF
159 *
160 * Quick return if possible
161 *
162  IF( m.LE.0 )
163  $ RETURN
164 *
165  IF( k.LT.m ) THEN
166 *
167 * Initialise rows 1:m-k to rows of the unit matrix
168 *
169  DO 20 j = 1, n
170  DO 10 l = 1, m - k
171  a( l, j ) = zero
172  10 CONTINUE
173  IF( j.GT.n-m .AND. j.LE.n-k )
174  $ a( m-n+j, j ) = one
175  20 CONTINUE
176  END IF
177 *
178  DO 40 i = 1, k
179  ii = m - k + i
180 *
181 * Apply H(i) to A(1:m-k+i,1:n-k+i) from the right
182 *
183  a( ii, n-m+ii ) = one
184  CALL slarf( 'Right', ii-1, n-m+ii, a( ii, 1 ), lda, tau( i ),
185  $ a, lda, work )
186  CALL sscal( n-m+ii-1, -tau( i ), a( ii, 1 ), lda )
187  a( ii, n-m+ii ) = one - tau( i )
188 *
189 * Set A(m-k+i,n-k+i+1:n) to zero
190 *
191  DO 30 l = n - m + ii + 1, n
192  a( ii, l ) = zero
193  30 CONTINUE
194  40 CONTINUE
195  RETURN
196 *
197 * End of SORGR2
198 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine slarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
SLARF applies an elementary reflector to a general rectangular matrix.
Definition: slarf.f:124
subroutine sscal(N, SA, SX, INCX)
SSCAL
Definition: sscal.f:79
Here is the call graph for this function:
Here is the caller graph for this function: