LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ dpotri()

subroutine dpotri ( character  UPLO,
integer  N,
double precision, dimension( lda, * )  A,
integer  LDA,
integer  INFO 
)

DPOTRI

Download DPOTRI + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DPOTRI computes the inverse of a real symmetric positive definite
 matrix A using the Cholesky factorization A = U**T*U or A = L*L**T
 computed by DPOTRF.
Parameters
[in]UPLO
          UPLO is CHARACTER*1
          = 'U':  Upper triangle of A is stored;
          = 'L':  Lower triangle of A is stored.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in,out]A
          A is DOUBLE PRECISION array, dimension (LDA,N)
          On entry, the triangular factor U or L from the Cholesky
          factorization A = U**T*U or A = L*L**T, as computed by
          DPOTRF.
          On exit, the upper or lower triangle of the (symmetric)
          inverse of A, overwriting the input factor U or L.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
          > 0:  if INFO = i, the (i,i) element of the factor U or L is
                zero, and the inverse could not be computed.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 94 of file dpotri.f.

95 *
96 * -- LAPACK computational routine --
97 * -- LAPACK is a software package provided by Univ. of Tennessee, --
98 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
99 *
100 * .. Scalar Arguments ..
101  CHARACTER UPLO
102  INTEGER INFO, LDA, N
103 * ..
104 * .. Array Arguments ..
105  DOUBLE PRECISION A( LDA, * )
106 * ..
107 *
108 * =====================================================================
109 *
110 * .. External Functions ..
111  LOGICAL LSAME
112  EXTERNAL lsame
113 * ..
114 * .. External Subroutines ..
115  EXTERNAL dlauum, dtrtri, xerbla
116 * ..
117 * .. Intrinsic Functions ..
118  INTRINSIC max
119 * ..
120 * .. Executable Statements ..
121 *
122 * Test the input parameters.
123 *
124  info = 0
125  IF( .NOT.lsame( uplo, 'U' ) .AND. .NOT.lsame( uplo, 'L' ) ) THEN
126  info = -1
127  ELSE IF( n.LT.0 ) THEN
128  info = -2
129  ELSE IF( lda.LT.max( 1, n ) ) THEN
130  info = -4
131  END IF
132  IF( info.NE.0 ) THEN
133  CALL xerbla( 'DPOTRI', -info )
134  RETURN
135  END IF
136 *
137 * Quick return if possible
138 *
139  IF( n.EQ.0 )
140  $ RETURN
141 *
142 * Invert the triangular Cholesky factor U or L.
143 *
144  CALL dtrtri( uplo, 'Non-unit', n, a, lda, info )
145  IF( info.GT.0 )
146  $ RETURN
147 *
148 * Form inv(U) * inv(U)**T or inv(L)**T * inv(L).
149 *
150  CALL dlauum( uplo, n, a, lda, info )
151 *
152  RETURN
153 *
154 * End of DPOTRI
155 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine dlauum(UPLO, N, A, LDA, INFO)
DLAUUM computes the product UUH or LHL, where U and L are upper or lower triangular matrices (blocked...
Definition: dlauum.f:102
subroutine dtrtri(UPLO, DIAG, N, A, LDA, INFO)
DTRTRI
Definition: dtrtri.f:109
Here is the call graph for this function:
Here is the caller graph for this function: