LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ dpoequb()

subroutine dpoequb ( integer  N,
double precision, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( * )  S,
double precision  SCOND,
double precision  AMAX,
integer  INFO 
)

DPOEQUB

Download DPOEQUB + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DPOEQUB computes row and column scalings intended to equilibrate a
 symmetric positive definite matrix A and reduce its condition number
 (with respect to the two-norm).  S contains the scale factors,
 S(i) = 1/sqrt(A(i,i)), chosen so that the scaled matrix B with
 elements B(i,j) = S(i)*A(i,j)*S(j) has ones on the diagonal.  This
 choice of S puts the condition number of B within a factor N of the
 smallest possible condition number over all possible diagonal
 scalings.

 This routine differs from DPOEQU by restricting the scaling factors
 to a power of the radix.  Barring over- and underflow, scaling by
 these factors introduces no additional rounding errors.  However, the
 scaled diagonal entries are no longer approximately 1 but lie
 between sqrt(radix) and 1/sqrt(radix).
Parameters
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in]A
          A is DOUBLE PRECISION array, dimension (LDA,N)
          The N-by-N symmetric positive definite matrix whose scaling
          factors are to be computed.  Only the diagonal elements of A
          are referenced.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[out]S
          S is DOUBLE PRECISION array, dimension (N)
          If INFO = 0, S contains the scale factors for A.
[out]SCOND
          SCOND is DOUBLE PRECISION
          If INFO = 0, S contains the ratio of the smallest S(i) to
          the largest S(i).  If SCOND >= 0.1 and AMAX is neither too
          large nor too small, it is not worth scaling by S.
[out]AMAX
          AMAX is DOUBLE PRECISION
          Absolute value of largest matrix element.  If AMAX is very
          close to overflow or very close to underflow, the matrix
          should be scaled.
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
          > 0:  if INFO = i, the i-th diagonal element is nonpositive.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 117 of file dpoequb.f.

118 *
119 * -- LAPACK computational routine --
120 * -- LAPACK is a software package provided by Univ. of Tennessee, --
121 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
122 *
123 * .. Scalar Arguments ..
124  INTEGER INFO, LDA, N
125  DOUBLE PRECISION AMAX, SCOND
126 * ..
127 * .. Array Arguments ..
128  DOUBLE PRECISION A( LDA, * ), S( * )
129 * ..
130 *
131 * =====================================================================
132 *
133 * .. Parameters ..
134  DOUBLE PRECISION ZERO, ONE
135  parameter( zero = 0.0d+0, one = 1.0d+0 )
136 * ..
137 * .. Local Scalars ..
138  INTEGER I
139  DOUBLE PRECISION SMIN, BASE, TMP
140 * ..
141 * .. External Functions ..
142  DOUBLE PRECISION DLAMCH
143  EXTERNAL dlamch
144 * ..
145 * .. External Subroutines ..
146  EXTERNAL xerbla
147 * ..
148 * .. Intrinsic Functions ..
149  INTRINSIC max, min, sqrt, log, int
150 * ..
151 * .. Executable Statements ..
152 *
153 * Test the input parameters.
154 *
155 * Positive definite only performs 1 pass of equilibration.
156 *
157  info = 0
158  IF( n.LT.0 ) THEN
159  info = -1
160  ELSE IF( lda.LT.max( 1, n ) ) THEN
161  info = -3
162  END IF
163  IF( info.NE.0 ) THEN
164  CALL xerbla( 'DPOEQUB', -info )
165  RETURN
166  END IF
167 *
168 * Quick return if possible.
169 *
170  IF( n.EQ.0 ) THEN
171  scond = one
172  amax = zero
173  RETURN
174  END IF
175 
176  base = dlamch( 'B' )
177  tmp = -0.5d+0 / log( base )
178 *
179 * Find the minimum and maximum diagonal elements.
180 *
181  s( 1 ) = a( 1, 1 )
182  smin = s( 1 )
183  amax = s( 1 )
184  DO 10 i = 2, n
185  s( i ) = a( i, i )
186  smin = min( smin, s( i ) )
187  amax = max( amax, s( i ) )
188  10 CONTINUE
189 *
190  IF( smin.LE.zero ) THEN
191 *
192 * Find the first non-positive diagonal element and return.
193 *
194  DO 20 i = 1, n
195  IF( s( i ).LE.zero ) THEN
196  info = i
197  RETURN
198  END IF
199  20 CONTINUE
200  ELSE
201 *
202 * Set the scale factors to the reciprocals
203 * of the diagonal elements.
204 *
205  DO 30 i = 1, n
206  s( i ) = base ** int( tmp * log( s( i ) ) )
207  30 CONTINUE
208 *
209 * Compute SCOND = min(S(I)) / max(S(I)).
210 *
211  scond = sqrt( smin ) / sqrt( amax )
212  END IF
213 *
214  RETURN
215 *
216 * End of DPOEQUB
217 *
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:69
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
Here is the call graph for this function:
Here is the caller graph for this function: