sorm22()

subroutine sorm22	(	character	side,
		character	trans,
		integer	m,
		integer	n,
		integer	n1,
		integer	n2,
		real, dimension( ldq, * )	q,
		integer	ldq,
		real, dimension( ldc, * )	c,
		integer	ldc,
		real, dimension( * )	work,
		integer	lwork,
		integer	info )

SORM22 multiplies a general matrix by a banded orthogonal matrix.

Download SORM22 + dependencies [TGZ] [ZIP] [TXT]

Purpose

!>
!>
!>  SORM22 overwrites the general real M-by-N matrix C with
!>
!>                  SIDE = 'L'     SIDE = 'R'
!>  TRANS = 'N':      Q * C          C * Q
!>  TRANS = 'T':      Q**T * C       C * Q**T
!>
!>  where Q is a real orthogonal matrix of order NQ, with NQ = M if
!>  SIDE = 'L' and NQ = N if SIDE = 'R'.
!>  The orthogonal matrix Q processes a 2-by-2 block structure
!>
!>         [  Q11  Q12  ]
!>     Q = [            ]
!>         [  Q21  Q22  ],
!>
!>  where Q12 is an N1-by-N1 lower triangular matrix and Q21 is an
!>  N2-by-N2 upper triangular matrix.
!> 

Parameters

[in]	SIDE	!> SIDE is CHARACTER*1 !> = 'L': apply Q or Q**T from the Left; !> = 'R': apply Q or Q**T from the Right. !>
[in]	TRANS	!> TRANS is CHARACTER*1 !> = 'N': apply Q (No transpose); !> = 'C': apply Q**T (Conjugate transpose). !>
[in]	M	!> M is INTEGER !> The number of rows of the matrix C. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix C. N >= 0. !>
[in]	N1
[in]	N2	!> N1 is INTEGER !> N2 is INTEGER !> The dimension of Q12 and Q21, respectively. N1, N2 >= 0. !> The following requirement must be satisfied: !> N1 + N2 = M if SIDE = 'L' and N1 + N2 = N if SIDE = 'R'. !>
[in]	Q	!> Q is REAL array, dimension !> (LDQ,M) if SIDE = 'L' !> (LDQ,N) if SIDE = 'R' !>
[in]	LDQ	!> LDQ is INTEGER !> The leading dimension of the array Q. !> LDQ >= max(1,M) if SIDE = 'L'; LDQ >= max(1,N) if SIDE = 'R'. !>
[in,out]	C	!> C is REAL array, dimension (LDC,N) !> On entry, the M-by-N matrix C. !> On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q. !>
[in]	LDC	!> LDC is INTEGER !> The leading dimension of the array C. LDC >= max(1,M). !>
[out]	WORK	!> WORK is REAL array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. !> If SIDE = 'L', LWORK >= max(1,N); !> if SIDE = 'R', LWORK >= max(1,M). !> For optimum performance LWORK >= M*N. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 159 of file sorm22.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
      IMPLICIT NONE
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE, TRANS
      INTEGER            M, N, N1, N2, LDQ, LDC, LWORK, INFO
*     ..
*     .. Array Arguments ..
      REAL               Q( LDQ, * ), C( LDC, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE
      parameter( one = 1.0e+0 )
*
*     .. Local Scalars ..
      LOGICAL            LEFT, LQUERY, NOTRAN
      INTEGER            I, LDWORK, LEN, LWKOPT, NB, NQ, NW
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SROUNDUP_LWORK
      EXTERNAL           lsame, sroundup_lwork
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, slacpy, strmm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      left = lsame( side, 'L' )
      notran = lsame( trans, 'N' )
      lquery = ( lwork.EQ.-1 )
*
*     NQ is the order of Q;
*     NW is the minimum dimension of WORK.
*
      IF( left ) THEN
         nq = m
      ELSE
         nq = n
      END IF
      nw = nq
      IF( n1.EQ.0 .OR. n2.EQ.0 ) nw = 1
      IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
         info = -1
      ELSE IF( .NOT.lsame( trans, 'N' ) .AND.
     $         .NOT.lsame( trans, 'T' ) )
     $          THEN
         info = -2
      ELSE IF( m.LT.0 ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( n1.LT.0 .OR. n1+n2.NE.nq ) THEN
         info = -5
      ELSE IF( n2.LT.0 ) THEN
         info = -6
      ELSE IF( ldq.LT.max( 1, nq ) ) THEN
         info = -8
      ELSE IF( ldc.LT.max( 1, m ) ) THEN
         info = -10
      ELSE IF( lwork.LT.nw .AND. .NOT.lquery ) THEN
         info = -12
      END IF
*
      IF( info.EQ.0 ) THEN
         lwkopt = m*n
         work( 1 ) = sroundup_lwork( lwkopt )
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SORM22', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 ) THEN
         work( 1 ) = 1
         RETURN
      END IF
*
*     Degenerate cases (N1 = 0 or N2 = 0) are handled using STRMM.
*
      IF( n1.EQ.0 ) THEN
         CALL strmm( side, 'Upper', trans, 'Non-Unit', m, n, one,
     $               q, ldq, c, ldc )
         work( 1 ) = one
         RETURN
      ELSE IF( n2.EQ.0 ) THEN
         CALL strmm( side, 'Lower', trans, 'Non-Unit', m, n, one,
     $               q, ldq, c, ldc )
         work( 1 ) = one
         RETURN
      END IF
*
*     Compute the largest chunk size available from the workspace.
*
      nb = max( 1, min( lwork, lwkopt ) / nq )
*
      IF( left ) THEN
         IF( notran ) THEN
            DO i = 1, n, nb
               len = min( nb, n-i+1 )
               ldwork = m
*
*              Multiply bottom part of C by Q12.
*
               CALL slacpy( 'All', n1, len, c( n2+1, i ), ldc, work,
     $                      ldwork )
               CALL strmm( 'Left', 'Lower', 'No Transpose',
     $                     'Non-Unit',
     $                     n1, len, one, q( 1, n2+1 ), ldq, work,
     $                     ldwork )
*
*              Multiply top part of C by Q11.
*
               CALL sgemm( 'No Transpose', 'No Transpose', n1, len,
     $                     n2,
     $                     one, q, ldq, c( 1, i ), ldc, one, work,
     $                     ldwork )
*
*              Multiply top part of C by Q21.
*
               CALL slacpy( 'All', n2, len, c( 1, i ), ldc,
     $                      work( n1+1 ), ldwork )
               CALL strmm( 'Left', 'Upper', 'No Transpose',
     $                     'Non-Unit',
     $                     n2, len, one, q( n1+1, 1 ), ldq,
     $                     work( n1+1 ), ldwork )
*
*              Multiply bottom part of C by Q22.
*
               CALL sgemm( 'No Transpose', 'No Transpose', n2, len,
     $                     n1,
     $                     one, q( n1+1, n2+1 ), ldq, c( n2+1, i ), ldc,
     $                     one, work( n1+1 ), ldwork )
*
*              Copy everything back.
*
               CALL slacpy( 'All', m, len, work, ldwork, c( 1, i ),
     $                      ldc )
            END DO
         ELSE
            DO i = 1, n, nb
               len = min( nb, n-i+1 )
               ldwork = m
*
*              Multiply bottom part of C by Q21**T.
*
               CALL slacpy( 'All', n2, len, c( n1+1, i ), ldc, work,
     $                      ldwork )
               CALL strmm( 'Left', 'Upper', 'Transpose', 'Non-Unit',
     $                     n2, len, one, q( n1+1, 1 ), ldq, work,
     $                     ldwork )
*
*              Multiply top part of C by Q11**T.
*
               CALL sgemm( 'Transpose', 'No Transpose', n2, len, n1,
     $                     one, q, ldq, c( 1, i ), ldc, one, work,
     $                     ldwork )
*
*              Multiply top part of C by Q12**T.
*
               CALL slacpy( 'All', n1, len, c( 1, i ), ldc,
     $                      work( n2+1 ), ldwork )
               CALL strmm( 'Left', 'Lower', 'Transpose', 'Non-Unit',
     $                     n1, len, one, q( 1, n2+1 ), ldq,
     $                     work( n2+1 ), ldwork )
*
*              Multiply bottom part of C by Q22**T.
*
               CALL sgemm( 'Transpose', 'No Transpose', n1, len, n2,
     $                     one, q( n1+1, n2+1 ), ldq, c( n1+1, i ), ldc,
     $                     one, work( n2+1 ), ldwork )
*
*              Copy everything back.
*
               CALL slacpy( 'All', m, len, work, ldwork, c( 1, i ),
     $                      ldc )
            END DO
         END IF
      ELSE
         IF( notran ) THEN
            DO i = 1, m, nb
               len = min( nb, m-i+1 )
               ldwork = len
*
*              Multiply right part of C by Q21.
*
               CALL slacpy( 'All', len, n2, c( i, n1+1 ), ldc, work,
     $                      ldwork )
               CALL strmm( 'Right', 'Upper', 'No Transpose',
     $                     'Non-Unit',
     $                     len, n2, one, q( n1+1, 1 ), ldq, work,
     $                     ldwork )
*
*              Multiply left part of C by Q11.
*
               CALL sgemm( 'No Transpose', 'No Transpose', len, n2,
     $                     n1,
     $                     one, c( i, 1 ), ldc, q, ldq, one, work,
     $                     ldwork )
*
*              Multiply left part of C by Q12.
*
               CALL slacpy( 'All', len, n1, c( i, 1 ), ldc,
     $                      work( 1 + n2*ldwork ), ldwork )
               CALL strmm( 'Right', 'Lower', 'No Transpose',
     $                     'Non-Unit',
     $                     len, n1, one, q( 1, n2+1 ), ldq,
     $                     work( 1 + n2*ldwork ), ldwork )
*
*              Multiply right part of C by Q22.
*
               CALL sgemm( 'No Transpose', 'No Transpose', len, n1,
     $                     n2,
     $                     one, c( i, n1+1 ), ldc, q( n1+1, n2+1 ), ldq,
     $                     one, work( 1 + n2*ldwork ), ldwork )
*
*              Copy everything back.
*
               CALL slacpy( 'All', len, n, work, ldwork, c( i, 1 ),
     $                      ldc )
            END DO
         ELSE
            DO i = 1, m, nb
               len = min( nb, m-i+1 )
               ldwork = len
*
*              Multiply right part of C by Q12**T.
*
               CALL slacpy( 'All', len, n1, c( i, n2+1 ), ldc, work,
     $                      ldwork )
               CALL strmm( 'Right', 'Lower', 'Transpose', 'Non-Unit',
     $                     len, n1, one, q( 1, n2+1 ), ldq, work,
     $                     ldwork )
*
*              Multiply left part of C by Q11**T.
*
               CALL sgemm( 'No Transpose', 'Transpose', len, n1, n2,
     $                     one, c( i, 1 ), ldc, q, ldq, one, work,
     $                     ldwork )
*
*              Multiply left part of C by Q21**T.
*
               CALL slacpy( 'All', len, n2, c( i, 1 ), ldc,
     $                      work( 1 + n1*ldwork ), ldwork )
               CALL strmm( 'Right', 'Upper', 'Transpose', 'Non-Unit',
     $                     len, n2, one, q( n1+1, 1 ), ldq,
     $                     work( 1 + n1*ldwork ), ldwork )
*
*              Multiply right part of C by Q22**T.
*
               CALL sgemm( 'No Transpose', 'Transpose', len, n2, n1,
     $                     one, c( i, n2+1 ), ldc, q( n1+1, n2+1 ), ldq,
     $                     one, work( 1 + n1*ldwork ), ldwork )
*
*              Copy everything back.
*
               CALL slacpy( 'All', len, n, work, ldwork, c( i, 1 ),
     $                      ldc )
            END DO
         END IF
      END IF
*
      work( 1 ) = sroundup_lwork( lwkopt )
      RETURN
*
*     End of SORM22
*

Here is the call graph for this function:

Here is the caller graph for this function: