claqhp()

subroutine claqhp	(	character	uplo,
		integer	n,
		complex, dimension( * )	ap,
		real, dimension( * )	s,
		real	scond,
		real	amax,
		character	equed
	)

CLAQHP scales a Hermitian matrix stored in packed form.

Download CLAQHP + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CLAQHP equilibrates a Hermitian matrix A using the scaling factors
 in the vector S.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the Hermitian matrix A is stored. = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	AP	AP is COMPLEX array, dimension (N*(N+1)/2) On entry, the upper or lower triangle of the Hermitian matrix A, packed columnwise in a linear array. The j-th column of A is stored in the array AP as follows: if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j; if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n. On exit, the equilibrated matrix: diag(S) * A * diag(S), in the same storage format as A.
[in]	S	S is REAL array, dimension (N) The scale factors for A.
[in]	SCOND	SCOND is REAL Ratio of the smallest S(i) to the largest S(i).
[in]	AMAX	AMAX is REAL Absolute value of largest matrix entry.
[out]	EQUED	EQUED is CHARACTER*1 Specifies whether or not equilibration was done. = 'N': No equilibration. = 'Y': Equilibration was done, i.e., A has been replaced by diag(S) * A * diag(S).

Internal Parameters:

  THRESH is a threshold value used to decide if scaling should be done
  based on the ratio of the scaling factors.  If SCOND < THRESH,
  scaling is done.

  LARGE and SMALL are threshold values used to decide if scaling should
  be done based on the absolute size of the largest matrix element.
  If AMAX > LARGE or AMAX < SMALL, scaling is done.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 125 of file claqhp.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          EQUED, UPLO
      INTEGER            N
      REAL               AMAX, SCOND
*     ..
*     .. Array Arguments ..
      REAL               S( * )
      COMPLEX            AP( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, THRESH
      parameter( one = 1.0e+0, thresh = 0.1e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, JC
      REAL               CJ, LARGE, SMALL
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SLAMCH
      EXTERNAL           lsame, slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.0 ) THEN
         equed = 'N'
         RETURN
      END IF
*
*     Initialize LARGE and SMALL.
*
      small = slamch( 'Safe minimum' ) / slamch( 'Precision' )
      large = one / small
*
      IF( scond.GE.thresh .AND. amax.GE.small .AND. amax.LE.large ) THEN
*
*        No equilibration
*
         equed = 'N'
      ELSE
*
*        Replace A by diag(S) * A * diag(S).
*
         IF( lsame( uplo, 'U' ) ) THEN
*
*           Upper triangle of A is stored.
*
            jc = 1
            DO 20 j = 1, n
               cj = s( j )
               DO 10 i = 1, j - 1
                  ap( jc+i-1 ) = cj*s( i )*ap( jc+i-1 )
   10          CONTINUE
               ap( jc+j-1 ) = cj*cj*real( ap( jc+j-1 ) )
               jc = jc + j
   20       CONTINUE
         ELSE
*
*           Lower triangle of A is stored.
*
            jc = 1
            DO 40 j = 1, n
               cj = s( j )
               ap( jc ) = cj*cj*real( ap( jc ) )
               DO 30 i = j + 1, n
                  ap( jc+i-j ) = cj*s( i )*ap( jc+i-j )
   30          CONTINUE
               jc = jc + n - j + 1
   40       CONTINUE
         END IF
         equed = 'Y'
      END IF
*
      RETURN
*
*     End of CLAQHP
*

Here is the caller graph for this function: