 LAPACK  3.10.0 LAPACK: Linear Algebra PACKage

◆ dget02()

 subroutine dget02 ( character TRANS, integer M, integer N, integer NRHS, double precision, dimension( lda, * ) A, integer LDA, double precision, dimension( ldx, * ) X, integer LDX, double precision, dimension( ldb, * ) B, integer LDB, double precision, dimension( * ) RWORK, double precision RESID )

DGET02

Purpose:
DGET02 computes the residual for a solution of a system of linear
equations op(A)*X = B:
RESID = norm(B - op(A)*X) / ( norm(op(A)) * norm(X) * EPS ),
where op(A) = A or A**T, depending on TRANS, and EPS is the
machine epsilon.
The norm used is the 1-norm.
Parameters
 [in] TRANS TRANS is CHARACTER*1 Specifies the form of the system of equations: = 'N': A * X = B (No transpose) = 'T': A**T * X = B (Transpose) = 'C': A**H * X = B (Conjugate transpose = Transpose) [in] M M is INTEGER The number of rows of the matrix A. M >= 0. [in] N N is INTEGER The number of columns of the matrix A. N >= 0. [in] NRHS NRHS is INTEGER The number of columns of B, the matrix of right hand sides. NRHS >= 0. [in] A A is DOUBLE PRECISION array, dimension (LDA,N) The original M x N matrix A. [in] LDA LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M). [in] X X is DOUBLE PRECISION array, dimension (LDX,NRHS) The computed solution vectors for the system of linear equations. [in] LDX LDX is INTEGER The leading dimension of the array X. If TRANS = 'N', LDX >= max(1,N); if TRANS = 'T' or 'C', LDX >= max(1,M). [in,out] B B is DOUBLE PRECISION array, dimension (LDB,NRHS) On entry, the right hand side vectors for the system of linear equations. On exit, B is overwritten with the difference B - A*X. [in] LDB LDB is INTEGER The leading dimension of the array B. IF TRANS = 'N', LDB >= max(1,M); if TRANS = 'T' or 'C', LDB >= max(1,N). [out] RWORK RWORK is DOUBLE PRECISION array, dimension (M) [out] RESID RESID is DOUBLE PRECISION The maximum over the number of right hand sides of norm(B - op(A)*X) / ( norm(op(A)) * norm(X) * EPS ).

Definition at line 133 of file dget02.f.

135 *
136 * -- LAPACK test routine --
137 * -- LAPACK is a software package provided by Univ. of Tennessee, --
138 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
139 *
140 * .. Scalar Arguments ..
141  CHARACTER TRANS
142  INTEGER LDA, LDB, LDX, M, N, NRHS
143  DOUBLE PRECISION RESID
144 * ..
145 * .. Array Arguments ..
146  DOUBLE PRECISION A( LDA, * ), B( LDB, * ), RWORK( * ),
147  \$ X( LDX, * )
148 * ..
149 *
150 * =====================================================================
151 *
152 * .. Parameters ..
153  DOUBLE PRECISION ZERO, ONE
154  parameter( zero = 0.0d+0, one = 1.0d+0 )
155 * ..
156 * .. Local Scalars ..
157  INTEGER J, N1, N2
158  DOUBLE PRECISION ANORM, BNORM, EPS, XNORM
159 * ..
160 * .. External Functions ..
161  LOGICAL LSAME
162  DOUBLE PRECISION DASUM, DLAMCH, DLANGE
163  EXTERNAL lsame, dasum, dlamch, dlange
164 * ..
165 * .. External Subroutines ..
166  EXTERNAL dgemm
167 * ..
168 * .. Intrinsic Functions ..
169  INTRINSIC max
170 * ..
171 * .. Executable Statements ..
172 *
173 * Quick exit if M = 0 or N = 0 or NRHS = 0
174 *
175  IF( m.LE.0 .OR. n.LE.0 .OR. nrhs.EQ.0 ) THEN
176  resid = zero
177  RETURN
178  END IF
179 *
180  IF( lsame( trans, 'T' ) .OR. lsame( trans, 'C' ) ) THEN
181  n1 = n
182  n2 = m
183  ELSE
184  n1 = m
185  n2 = n
186  END IF
187 *
188 * Exit with RESID = 1/EPS if ANORM = 0.
189 *
190  eps = dlamch( 'Epsilon' )
191  IF( lsame( trans, 'N' ) ) THEN
192  anorm = dlange( '1', m, n, a, lda, rwork )
193  ELSE
194  anorm = dlange( 'I', m, n, a, lda, rwork )
195  END IF
196  IF( anorm.LE.zero ) THEN
197  resid = one / eps
198  RETURN
199  END IF
200 *
201 * Compute B - op(A)*X and store in B.
202 *
203  CALL dgemm( trans, 'No transpose', n1, nrhs, n2, -one, a, lda, x,
204  \$ ldx, one, b, ldb )
205 *
206 * Compute the maximum over the number of right hand sides of
207 * norm(B - op(A)*X) / ( norm(op(A)) * norm(X) * EPS ) .
208 *
209  resid = zero
210  DO 10 j = 1, nrhs
211  bnorm = dasum( n1, b( 1, j ), 1 )
212  xnorm = dasum( n2, x( 1, j ), 1 )
213  IF( xnorm.LE.zero ) THEN
214  resid = one / eps
215  ELSE
216  resid = max( resid, ( ( bnorm / anorm ) / xnorm ) / eps )
217  END IF
218  10 CONTINUE
219 *
220  RETURN
221 *
222 * End of DGET02
223 *
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:69
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
double precision function dasum(N, DX, INCX)
DASUM
Definition: dasum.f:71
subroutine dgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
DGEMM
Definition: dgemm.f:187
double precision function dlange(NORM, M, N, A, LDA, WORK)
DLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: dlange.f:114
Here is the call graph for this function:
Here is the caller graph for this function: