LAPACK  3.10.1
LAPACK: Linear Algebra PACKage
clanhp.f
Go to the documentation of this file.
1 *> \brief \b CLANHP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix supplied in packed form.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download CLANHP + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/clanhp.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/clanhp.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/clanhp.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * REAL FUNCTION CLANHP( NORM, UPLO, N, AP, WORK )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER NORM, UPLO
25 * INTEGER N
26 * ..
27 * .. Array Arguments ..
28 * REAL WORK( * )
29 * COMPLEX AP( * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> CLANHP returns the value of the one norm, or the Frobenius norm, or
39 *> the infinity norm, or the element of largest absolute value of a
40 *> complex hermitian matrix A, supplied in packed form.
41 *> \endverbatim
42 *>
43 *> \return CLANHP
44 *> \verbatim
45 *>
46 *> CLANHP = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47 *> (
48 *> ( norm1(A), NORM = '1', 'O' or 'o'
49 *> (
50 *> ( normI(A), NORM = 'I' or 'i'
51 *> (
52 *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53 *>
54 *> where norm1 denotes the one norm of a matrix (maximum column sum),
55 *> normI denotes the infinity norm of a matrix (maximum row sum) and
56 *> normF denotes the Frobenius norm of a matrix (square root of sum of
57 *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58 *> \endverbatim
59 *
60 * Arguments:
61 * ==========
62 *
63 *> \param[in] NORM
64 *> \verbatim
65 *> NORM is CHARACTER*1
66 *> Specifies the value to be returned in CLANHP as described
67 *> above.
68 *> \endverbatim
69 *>
70 *> \param[in] UPLO
71 *> \verbatim
72 *> UPLO is CHARACTER*1
73 *> Specifies whether the upper or lower triangular part of the
74 *> hermitian matrix A is supplied.
75 *> = 'U': Upper triangular part of A is supplied
76 *> = 'L': Lower triangular part of A is supplied
77 *> \endverbatim
78 *>
79 *> \param[in] N
80 *> \verbatim
81 *> N is INTEGER
82 *> The order of the matrix A. N >= 0. When N = 0, CLANHP is
83 *> set to zero.
84 *> \endverbatim
85 *>
86 *> \param[in] AP
87 *> \verbatim
88 *> AP is COMPLEX array, dimension (N*(N+1)/2)
89 *> The upper or lower triangle of the hermitian matrix A, packed
90 *> columnwise in a linear array. The j-th column of A is stored
91 *> in the array AP as follows:
92 *> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
93 *> if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
94 *> Note that the imaginary parts of the diagonal elements need
95 *> not be set and are assumed to be zero.
96 *> \endverbatim
97 *>
98 *> \param[out] WORK
99 *> \verbatim
100 *> WORK is REAL array, dimension (MAX(1,LWORK)),
101 *> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
102 *> WORK is not referenced.
103 *> \endverbatim
104 *
105 * Authors:
106 * ========
107 *
108 *> \author Univ. of Tennessee
109 *> \author Univ. of California Berkeley
110 *> \author Univ. of Colorado Denver
111 *> \author NAG Ltd.
112 *
113 *> \ingroup complexOTHERauxiliary
114 *
115 * =====================================================================
116  REAL function clanhp( norm, uplo, n, ap, work )
117 *
118 * -- LAPACK auxiliary routine --
119 * -- LAPACK is a software package provided by Univ. of Tennessee, --
120 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
121 *
122 * .. Scalar Arguments ..
123  CHARACTER norm, uplo
124  INTEGER n
125 * ..
126 * .. Array Arguments ..
127  REAL work( * )
128  COMPLEX ap( * )
129 * ..
130 *
131 * =====================================================================
132 *
133 * .. Parameters ..
134  REAL one, zero
135  parameter( one = 1.0e+0, zero = 0.0e+0 )
136 * ..
137 * .. Local Scalars ..
138  INTEGER i, j, k
139  REAL absa, scale, sum, value
140 * ..
141 * .. External Functions ..
142  LOGICAL lsame, sisnan
143  EXTERNAL lsame, sisnan
144 * ..
145 * .. External Subroutines ..
146  EXTERNAL classq
147 * ..
148 * .. Intrinsic Functions ..
149  INTRINSIC abs, real, sqrt
150 * ..
151 * .. Executable Statements ..
152 *
153  IF( n.EQ.0 ) THEN
154  VALUE = zero
155  ELSE IF( lsame( norm, 'M' ) ) THEN
156 *
157 * Find max(abs(A(i,j))).
158 *
159  VALUE = zero
160  IF( lsame( uplo, 'U' ) ) THEN
161  k = 0
162  DO 20 j = 1, n
163  DO 10 i = k + 1, k + j - 1
164  sum = abs( ap( i ) )
165  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
166  10 CONTINUE
167  k = k + j
168  sum = abs( real( ap( k ) ) )
169  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
170  20 CONTINUE
171  ELSE
172  k = 1
173  DO 40 j = 1, n
174  sum = abs( real( ap( k ) ) )
175  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
176  DO 30 i = k + 1, k + n - j
177  sum = abs( ap( i ) )
178  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
179  30 CONTINUE
180  k = k + n - j + 1
181  40 CONTINUE
182  END IF
183  ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
184  $ ( norm.EQ.'1' ) ) THEN
185 *
186 * Find normI(A) ( = norm1(A), since A is hermitian).
187 *
188  VALUE = zero
189  k = 1
190  IF( lsame( uplo, 'U' ) ) THEN
191  DO 60 j = 1, n
192  sum = zero
193  DO 50 i = 1, j - 1
194  absa = abs( ap( k ) )
195  sum = sum + absa
196  work( i ) = work( i ) + absa
197  k = k + 1
198  50 CONTINUE
199  work( j ) = sum + abs( real( ap( k ) ) )
200  k = k + 1
201  60 CONTINUE
202  DO 70 i = 1, n
203  sum = work( i )
204  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
205  70 CONTINUE
206  ELSE
207  DO 80 i = 1, n
208  work( i ) = zero
209  80 CONTINUE
210  DO 100 j = 1, n
211  sum = work( j ) + abs( real( ap( k ) ) )
212  k = k + 1
213  DO 90 i = j + 1, n
214  absa = abs( ap( k ) )
215  sum = sum + absa
216  work( i ) = work( i ) + absa
217  k = k + 1
218  90 CONTINUE
219  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
220  100 CONTINUE
221  END IF
222  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
223 *
224 * Find normF(A).
225 *
226  scale = zero
227  sum = one
228  k = 2
229  IF( lsame( uplo, 'U' ) ) THEN
230  DO 110 j = 2, n
231  CALL classq( j-1, ap( k ), 1, scale, sum )
232  k = k + j
233  110 CONTINUE
234  ELSE
235  DO 120 j = 1, n - 1
236  CALL classq( n-j, ap( k ), 1, scale, sum )
237  k = k + n - j + 1
238  120 CONTINUE
239  END IF
240  sum = 2*sum
241  k = 1
242  DO 130 i = 1, n
243  IF( real( ap( k ) ).NE.zero ) THEN
244  absa = abs( real( ap( k ) ) )
245  IF( scale.LT.absa ) THEN
246  sum = one + sum*( scale / absa )**2
247  scale = absa
248  ELSE
249  sum = sum + ( absa / scale )**2
250  END IF
251  END IF
252  IF( lsame( uplo, 'U' ) ) THEN
253  k = k + i + 1
254  ELSE
255  k = k + n - i + 1
256  END IF
257  130 CONTINUE
258  VALUE = scale*sqrt( sum )
259  END IF
260 *
261  clanhp = VALUE
262  RETURN
263 *
264 * End of CLANHP
265 *
266  END
subroutine classq(n, x, incx, scl, sumsq)
CLASSQ updates a sum of squares represented in scaled form.
Definition: classq.f90:137
logical function sisnan(SIN)
SISNAN tests input for NaN.
Definition: sisnan.f:59
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
real function clanhp(NORM, UPLO, N, AP, WORK)
CLANHP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: clanhp.f:117