slar1v.f

Go to the documentation of this file.

*> \brief \b SLAR1V computes the (scaled) r-th column of the inverse of the submatrix in rows b1 through bn of the tridiagonal matrix LDLT - λI.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download SLAR1V + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/slar1v.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/slar1v.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/slar1v.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE SLAR1V( N, B1, BN, LAMBDA, D, L, LD, LLD,
*                  PIVMIN, GAPTOL, Z, WANTNC, NEGCNT, ZTZ, MINGMA,
*                  R, ISUPPZ, NRMINV, RESID, RQCORR, WORK )
*
*       .. Scalar Arguments ..
*       LOGICAL            WANTNC
*       INTEGER   B1, BN, N, NEGCNT, R
*       REAL               GAPTOL, LAMBDA, MINGMA, NRMINV, PIVMIN, RESID,
*      $                   RQCORR, ZTZ
*       ..
*       .. Array Arguments ..
*       INTEGER            ISUPPZ( * )
*       REAL               D( * ), L( * ), LD( * ), LLD( * ),
*      $                  WORK( * )
*       REAL             Z( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SLAR1V computes the (scaled) r-th column of the inverse of
*> the sumbmatrix in rows B1 through BN of the tridiagonal matrix
*> L D L**T - sigma I. When sigma is close to an eigenvalue, the
*> computed vector is an accurate eigenvector. Usually, r corresponds
*> to the index where the eigenvector is largest in magnitude.
*> The following steps accomplish this computation :
*> (a) Stationary qd transform,  L D L**T - sigma I = L(+) D(+) L(+)**T,
*> (b) Progressive qd transform, L D L**T - sigma I = U(-) D(-) U(-)**T,
*> (c) Computation of the diagonal elements of the inverse of
*>     L D L**T - sigma I by combining the above transforms, and choosing
*>     r as the index where the diagonal of the inverse is (one of the)
*>     largest in magnitude.
*> (d) Computation of the (scaled) r-th column of the inverse using the
*>     twisted factorization obtained by combining the top part of the
*>     the stationary and the bottom part of the progressive transform.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>           The order of the matrix L D L**T.
*> \endverbatim
*>
*> \param[in] B1
*> \verbatim
*>          B1 is INTEGER
*>           First index of the submatrix of L D L**T.
*> \endverbatim
*>
*> \param[in] BN
*> \verbatim
*>          BN is INTEGER
*>           Last index of the submatrix of L D L**T.
*> \endverbatim
*>
*> \param[in] LAMBDA
*> \verbatim
*>          LAMBDA is REAL
*>           The shift. In order to compute an accurate eigenvector,
*>           LAMBDA should be a good approximation to an eigenvalue
*>           of L D L**T.
*> \endverbatim
*>
*> \param[in] L
*> \verbatim
*>          L is REAL array, dimension (N-1)
*>           The (n-1) subdiagonal elements of the unit bidiagonal matrix
*>           L, in elements 1 to N-1.
*> \endverbatim
*>
*> \param[in] D
*> \verbatim
*>          D is REAL array, dimension (N)
*>           The n diagonal elements of the diagonal matrix D.
*> \endverbatim
*>
*> \param[in] LD
*> \verbatim
*>          LD is REAL array, dimension (N-1)
*>           The n-1 elements L(i)*D(i).
*> \endverbatim
*>
*> \param[in] LLD
*> \verbatim
*>          LLD is REAL array, dimension (N-1)
*>           The n-1 elements L(i)*L(i)*D(i).
*> \endverbatim
*>
*> \param[in] PIVMIN
*> \verbatim
*>          PIVMIN is REAL
*>           The minimum pivot in the Sturm sequence.
*> \endverbatim
*>
*> \param[in] GAPTOL
*> \verbatim
*>          GAPTOL is REAL
*>           Tolerance that indicates when eigenvector entries are negligible
*>           w.r.t. their contribution to the residual.
*> \endverbatim
*>
*> \param[in,out] Z
*> \verbatim
*>          Z is REAL array, dimension (N)
*>           On input, all entries of Z must be set to 0.
*>           On output, Z contains the (scaled) r-th column of the
*>           inverse. The scaling is such that Z(R) equals 1.
*> \endverbatim
*>
*> \param[in] WANTNC
*> \verbatim
*>          WANTNC is LOGICAL
*>           Specifies whether NEGCNT has to be computed.
*> \endverbatim
*>
*> \param[out] NEGCNT
*> \verbatim
*>          NEGCNT is INTEGER
*>           If WANTNC is .TRUE. then NEGCNT = the number of pivots < pivmin
*>           in the  matrix factorization L D L**T, and NEGCNT = -1 otherwise.
*> \endverbatim
*>
*> \param[out] ZTZ
*> \verbatim
*>          ZTZ is REAL
*>           The square of the 2-norm of Z.
*> \endverbatim
*>
*> \param[out] MINGMA
*> \verbatim
*>          MINGMA is REAL
*>           The reciprocal of the largest (in magnitude) diagonal
*>           element of the inverse of L D L**T - sigma I.
*> \endverbatim
*>
*> \param[in,out] R
*> \verbatim
*>          R is INTEGER
*>           The twist index for the twisted factorization used to
*>           compute Z.
*>           On input, 0 <= R <= N. If R is input as 0, R is set to
*>           the index where (L D L**T - sigma I)^{-1} is largest
*>           in magnitude. If 1 <= R <= N, R is unchanged.
*>           On output, R contains the twist index used to compute Z.
*>           Ideally, R designates the position of the maximum entry in the
*>           eigenvector.
*> \endverbatim
*>
*> \param[out] ISUPPZ
*> \verbatim
*>          ISUPPZ is INTEGER array, dimension (2)
*>           The support of the vector in Z, i.e., the vector Z is
*>           nonzero only in elements ISUPPZ(1) through ISUPPZ( 2 ).
*> \endverbatim
*>
*> \param[out] NRMINV
*> \verbatim
*>          NRMINV is REAL
*>           NRMINV = 1/SQRT( ZTZ )
*> \endverbatim
*>
*> \param[out] RESID
*> \verbatim
*>          RESID is REAL
*>           The residual of the FP vector.
*>           RESID = ABS( MINGMA )/SQRT( ZTZ )
*> \endverbatim
*>
*> \param[out] RQCORR
*> \verbatim
*>          RQCORR is REAL
*>           The Rayleigh Quotient correction to LAMBDA.
*>           RQCORR = MINGMA*TMP
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (4*N)
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup lar1v
*
*> \par Contributors:
*  ==================
*>
*> Beresford Parlett, University of California, Berkeley, USA \n
*> Jim Demmel, University of California, Berkeley, USA \n
*> Inderjit Dhillon, University of Texas, Austin, USA \n
*> Osni Marques, LBNL/NERSC, USA \n
*> Christof Voemel, University of California, Berkeley, USA
*
*  =====================================================================
      SUBROUTINE slar1v( N, B1, BN, LAMBDA, D, L, LD, LLD,
     $           PIVMIN, GAPTOL, Z, WANTNC, NEGCNT, ZTZ, MINGMA,
     $           R, ISUPPZ, NRMINV, RESID, RQCORR, WORK )
*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            WANTNC
      INTEGER   B1, BN, N, NEGCNT, R
      REAL               GAPTOL, LAMBDA, MINGMA, NRMINV, PIVMIN, RESID,
     $                   rqcorr, ztz
*     ..
*     .. Array Arguments ..
      INTEGER            ISUPPZ( * )
      REAL               D( * ), L( * ), LD( * ), LLD( * ),
     $                  work( * )
      REAL             Z( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      PARAMETER          ( ZERO = 0.0e0, one = 1.0e0 )
 
*     ..
*     .. Local Scalars ..
      LOGICAL            SAWNAN1, SAWNAN2
      INTEGER            I, INDLPL, INDP, INDS, INDUMN, NEG1, NEG2, R1,
     $                   r2
      REAL               DMINUS, DPLUS, EPS, S, TMP
*     ..
*     .. External Functions ..
      LOGICAL SISNAN
      REAL               SLAMCH
      EXTERNAL           sisnan, slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs
*     ..
*     .. Executable Statements ..
*
      eps = slamch( 'Precision' )
 
 
      IF( r.EQ.0 ) THEN
         r1 = b1
         r2 = bn
      ELSE
         r1 = r
         r2 = r
      END IF
 
*     Storage for LPLUS
      indlpl = 0
*     Storage for UMINUS
      indumn = n
      inds = 2*n + 1
      indp = 3*n + 1
 
      IF( b1.EQ.1 ) THEN
         work( inds ) = zero
      ELSE
         work( inds+b1-1 ) = lld( b1-1 )
      END IF
 
*
*     Compute the stationary transform (using the differential form)
*     until the index R2.
*
      sawnan1 = .false.
      neg1 = 0
      s = work( inds+b1-1 ) - lambda
      DO 50 i = b1, r1 - 1
         dplus = d( i ) + s
         work( indlpl+i ) = ld( i ) / dplus
         IF(dplus.LT.zero) neg1 = neg1 + 1
         work( inds+i ) = s*work( indlpl+i )*l( i )
         s = work( inds+i ) - lambda
 50   CONTINUE
      sawnan1 = sisnan( s )
      IF( sawnan1 ) GOTO 60
      DO 51 i = r1, r2 - 1
         dplus = d( i ) + s
         work( indlpl+i ) = ld( i ) / dplus
         work( inds+i ) = s*work( indlpl+i )*l( i )
         s = work( inds+i ) - lambda
 51   CONTINUE
      sawnan1 = sisnan( s )
*
 60   CONTINUE
      IF( sawnan1 ) THEN
*        Runs a slower version of the above loop if a NaN is detected
         neg1 = 0
         s = work( inds+b1-1 ) - lambda
         DO 70 i = b1, r1 - 1
            dplus = d( i ) + s
            IF(abs(dplus).LT.pivmin) dplus = -pivmin
            work( indlpl+i ) = ld( i ) / dplus
            IF(dplus.LT.zero) neg1 = neg1 + 1
            work( inds+i ) = s*work( indlpl+i )*l( i )
            IF( work( indlpl+i ).EQ.zero )
     $                      work( inds+i ) = lld( i )
            s = work( inds+i ) - lambda
 70      CONTINUE
         DO 71 i = r1, r2 - 1
            dplus = d( i ) + s
            IF(abs(dplus).LT.pivmin) dplus = -pivmin
            work( indlpl+i ) = ld( i ) / dplus
            work( inds+i ) = s*work( indlpl+i )*l( i )
            IF( work( indlpl+i ).EQ.zero )
     $                      work( inds+i ) = lld( i )
            s = work( inds+i ) - lambda
 71      CONTINUE
      END IF
*
*     Compute the progressive transform (using the differential form)
*     until the index R1
*
      sawnan2 = .false.
      neg2 = 0
      work( indp+bn-1 ) = d( bn ) - lambda
      DO 80 i = bn - 1, r1, -1
         dminus = lld( i ) + work( indp+i )
         tmp = d( i ) / dminus
         IF(dminus.LT.zero) neg2 = neg2 + 1
         work( indumn+i ) = l( i )*tmp
         work( indp+i-1 ) = work( indp+i )*tmp - lambda
 80   CONTINUE
      tmp = work( indp+r1-1 )
      sawnan2 = sisnan( tmp )
 
      IF( sawnan2 ) THEN
*        Runs a slower version of the above loop if a NaN is detected
         neg2 = 0
         DO 100 i = bn-1, r1, -1
            dminus = lld( i ) + work( indp+i )
            IF(abs(dminus).LT.pivmin) dminus = -pivmin
            tmp = d( i ) / dminus
            IF(dminus.LT.zero) neg2 = neg2 + 1
            work( indumn+i ) = l( i )*tmp
            work( indp+i-1 ) = work( indp+i )*tmp - lambda
            IF( tmp.EQ.zero )
     $          work( indp+i-1 ) = d( i ) - lambda
 100     CONTINUE
      END IF
*
*     Find the index (from R1 to R2) of the largest (in magnitude)
*     diagonal element of the inverse
*
      mingma = work( inds+r1-1 ) + work( indp+r1-1 )
      IF( mingma.LT.zero ) neg1 = neg1 + 1
      IF( wantnc ) THEN
         negcnt = neg1 + neg2
      ELSE
         negcnt = -1
      ENDIF
      IF( abs(mingma).EQ.zero )
     $   mingma = eps*work( inds+r1-1 )
      r = r1
      DO 110 i = r1, r2 - 1
         tmp = work( inds+i ) + work( indp+i )
         IF( tmp.EQ.zero )
     $      tmp = eps*work( inds+i )
         IF( abs( tmp ).LE.abs( mingma ) ) THEN
            mingma = tmp
            r = i + 1
         END IF
 110  CONTINUE
*
*     Compute the FP vector: solve N^T v = e_r
*
      isuppz( 1 ) = b1
      isuppz( 2 ) = bn
      z( r ) = one
      ztz = one
*
*     Compute the FP vector upwards from R
*
      IF( .NOT.sawnan1 .AND. .NOT.sawnan2 ) THEN
         DO 210 i = r-1, b1, -1
            z( i ) = -( work( indlpl+i )*z( i+1 ) )
            IF( (abs(z(i))+abs(z(i+1)))* abs(ld(i)).LT.gaptol )
     $           THEN
               z( i ) = zero
               isuppz( 1 ) = i + 1
               GOTO 220
            ENDIF
            ztz = ztz + z( i )*z( i )
 210     CONTINUE
 220     CONTINUE
      ELSE
*        Run slower loop if NaN occurred.
         DO 230 i = r - 1, b1, -1
            IF( z( i+1 ).EQ.zero ) THEN
               z( i ) = -( ld( i+1 ) / ld( i ) )*z( i+2 )
            ELSE
               z( i ) = -( work( indlpl+i )*z( i+1 ) )
            END IF
            IF( (abs(z(i))+abs(z(i+1)))* abs(ld(i)).LT.gaptol )
     $           THEN
               z( i ) = zero
               isuppz( 1 ) = i + 1
               GO TO 240
            END IF
            ztz = ztz + z( i )*z( i )
 230     CONTINUE
 240     CONTINUE
      ENDIF
 
*     Compute the FP vector downwards from R in blocks of size BLKSIZ
      IF( .NOT.sawnan1 .AND. .NOT.sawnan2 ) THEN
         DO 250 i = r, bn-1
            z( i+1 ) = -( work( indumn+i )*z( i ) )
            IF( (abs(z(i))+abs(z(i+1)))* abs(ld(i)).LT.gaptol )
     $         THEN
               z( i+1 ) = zero
               isuppz( 2 ) = i
               GO TO 260
            END IF
            ztz = ztz + z( i+1 )*z( i+1 )
 250     CONTINUE
 260     CONTINUE
      ELSE
*        Run slower loop if NaN occurred.
         DO 270 i = r, bn - 1
            IF( z( i ).EQ.zero ) THEN
               z( i+1 ) = -( ld( i-1 ) / ld( i ) )*z( i-1 )
            ELSE
               z( i+1 ) = -( work( indumn+i )*z( i ) )
            END IF
            IF( (abs(z(i))+abs(z(i+1)))* abs(ld(i)).LT.gaptol )
     $           THEN
               z( i+1 ) = zero
               isuppz( 2 ) = i
               GO TO 280
            END IF
            ztz = ztz + z( i+1 )*z( i+1 )
 270     CONTINUE
 280     CONTINUE
      END IF
*
*     Compute quantities for convergence test
*
      tmp = one / ztz
      nrminv = sqrt( tmp )
      resid = abs( mingma )*nrminv
      rqcorr = mingma*tmp
*
*
      RETURN
*
*     End of SLAR1V
*
      END