 LAPACK  3.10.0 LAPACK: Linear Algebra PACKage

## ◆ zungrq()

 subroutine zungrq ( integer M, integer N, integer K, complex*16, dimension( lda, * ) A, integer LDA, complex*16, dimension( * ) TAU, complex*16, dimension( * ) WORK, integer LWORK, integer INFO )

ZUNGRQ

Purpose:
``` ZUNGRQ generates an M-by-N complex matrix Q with orthonormal rows,
which is defined as the last M rows of a product of K elementary
reflectors of order N

Q  =  H(1)**H H(2)**H . . . H(k)**H

as returned by ZGERQF.```
Parameters
 [in] M ``` M is INTEGER The number of rows of the matrix Q. M >= 0.``` [in] N ``` N is INTEGER The number of columns of the matrix Q. N >= M.``` [in] K ``` K is INTEGER The number of elementary reflectors whose product defines the matrix Q. M >= K >= 0.``` [in,out] A ``` A is COMPLEX*16 array, dimension (LDA,N) On entry, the (m-k+i)-th row must contain the vector which defines the elementary reflector H(i), for i = 1,2,...,k, as returned by ZGERQF in the last k rows of its array argument A. On exit, the M-by-N matrix Q.``` [in] LDA ``` LDA is INTEGER The first dimension of the array A. LDA >= max(1,M).``` [in] TAU ``` TAU is COMPLEX*16 array, dimension (K) TAU(i) must contain the scalar factor of the elementary reflector H(i), as returned by ZGERQF.``` [out] WORK ``` WORK is COMPLEX*16 array, dimension (MAX(1,LWORK)) On exit, if INFO = 0, WORK(1) returns the optimal LWORK.``` [in] LWORK ``` LWORK is INTEGER The dimension of the array WORK. LWORK >= max(1,M). For optimum performance LWORK >= M*NB, where NB is the optimal blocksize. If LWORK = -1, then a workspace query is assumed; the routine only calculates the optimal size of the WORK array, returns this value as the first entry of the WORK array, and no error message related to LWORK is issued by XERBLA.``` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument has an illegal value```

Definition at line 127 of file zungrq.f.

128 *
129 * -- LAPACK computational routine --
130 * -- LAPACK is a software package provided by Univ. of Tennessee, --
131 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
132 *
133 * .. Scalar Arguments ..
134  INTEGER INFO, K, LDA, LWORK, M, N
135 * ..
136 * .. Array Arguments ..
137  COMPLEX*16 A( LDA, * ), TAU( * ), WORK( * )
138 * ..
139 *
140 * =====================================================================
141 *
142 * .. Parameters ..
143  COMPLEX*16 ZERO
144  parameter( zero = ( 0.0d+0, 0.0d+0 ) )
145 * ..
146 * .. Local Scalars ..
147  LOGICAL LQUERY
148  INTEGER I, IB, II, IINFO, IWS, J, KK, L, LDWORK,
149  \$ LWKOPT, NB, NBMIN, NX
150 * ..
151 * .. External Subroutines ..
152  EXTERNAL xerbla, zlarfb, zlarft, zungr2
153 * ..
154 * .. Intrinsic Functions ..
155  INTRINSIC max, min
156 * ..
157 * .. External Functions ..
158  INTEGER ILAENV
159  EXTERNAL ilaenv
160 * ..
161 * .. Executable Statements ..
162 *
163 * Test the input arguments
164 *
165  info = 0
166  lquery = ( lwork.EQ.-1 )
167  IF( m.LT.0 ) THEN
168  info = -1
169  ELSE IF( n.LT.m ) THEN
170  info = -2
171  ELSE IF( k.LT.0 .OR. k.GT.m ) THEN
172  info = -3
173  ELSE IF( lda.LT.max( 1, m ) ) THEN
174  info = -5
175  END IF
176 *
177  IF( info.EQ.0 ) THEN
178  IF( m.LE.0 ) THEN
179  lwkopt = 1
180  ELSE
181  nb = ilaenv( 1, 'ZUNGRQ', ' ', m, n, k, -1 )
182  lwkopt = m*nb
183  END IF
184  work( 1 ) = lwkopt
185 *
186  IF( lwork.LT.max( 1, m ) .AND. .NOT.lquery ) THEN
187  info = -8
188  END IF
189  END IF
190 *
191  IF( info.NE.0 ) THEN
192  CALL xerbla( 'ZUNGRQ', -info )
193  RETURN
194  ELSE IF( lquery ) THEN
195  RETURN
196  END IF
197 *
198 * Quick return if possible
199 *
200  IF( m.LE.0 ) THEN
201  RETURN
202  END IF
203 *
204  nbmin = 2
205  nx = 0
206  iws = m
207  IF( nb.GT.1 .AND. nb.LT.k ) THEN
208 *
209 * Determine when to cross over from blocked to unblocked code.
210 *
211  nx = max( 0, ilaenv( 3, 'ZUNGRQ', ' ', m, n, k, -1 ) )
212  IF( nx.LT.k ) THEN
213 *
214 * Determine if workspace is large enough for blocked code.
215 *
216  ldwork = m
217  iws = ldwork*nb
218  IF( lwork.LT.iws ) THEN
219 *
220 * Not enough workspace to use optimal NB: reduce NB and
221 * determine the minimum value of NB.
222 *
223  nb = lwork / ldwork
224  nbmin = max( 2, ilaenv( 2, 'ZUNGRQ', ' ', m, n, k, -1 ) )
225  END IF
226  END IF
227  END IF
228 *
229  IF( nb.GE.nbmin .AND. nb.LT.k .AND. nx.LT.k ) THEN
230 *
231 * Use blocked code after the first block.
232 * The last kk rows are handled by the block method.
233 *
234  kk = min( k, ( ( k-nx+nb-1 ) / nb )*nb )
235 *
236 * Set A(1:m-kk,n-kk+1:n) to zero.
237 *
238  DO 20 j = n - kk + 1, n
239  DO 10 i = 1, m - kk
240  a( i, j ) = zero
241  10 CONTINUE
242  20 CONTINUE
243  ELSE
244  kk = 0
245  END IF
246 *
247 * Use unblocked code for the first or only block.
248 *
249  CALL zungr2( m-kk, n-kk, k-kk, a, lda, tau, work, iinfo )
250 *
251  IF( kk.GT.0 ) THEN
252 *
253 * Use blocked code
254 *
255  DO 50 i = k - kk + 1, k, nb
256  ib = min( nb, k-i+1 )
257  ii = m - k + i
258  IF( ii.GT.1 ) THEN
259 *
260 * Form the triangular factor of the block reflector
261 * H = H(i+ib-1) . . . H(i+1) H(i)
262 *
263  CALL zlarft( 'Backward', 'Rowwise', n-k+i+ib-1, ib,
264  \$ a( ii, 1 ), lda, tau( i ), work, ldwork )
265 *
266 * Apply H**H to A(1:m-k+i-1,1:n-k+i+ib-1) from the right
267 *
268  CALL zlarfb( 'Right', 'Conjugate transpose', 'Backward',
269  \$ 'Rowwise', ii-1, n-k+i+ib-1, ib, a( ii, 1 ),
270  \$ lda, work, ldwork, a, lda, work( ib+1 ),
271  \$ ldwork )
272  END IF
273 *
274 * Apply H**H to columns 1:n-k+i+ib-1 of current block
275 *
276  CALL zungr2( ib, n-k+i+ib-1, ib, a( ii, 1 ), lda, tau( i ),
277  \$ work, iinfo )
278 *
279 * Set columns n-k+i+ib:n of current block to zero
280 *
281  DO 40 l = n - k + i + ib, n
282  DO 30 j = ii, ii + ib - 1
283  a( j, l ) = zero
284  30 CONTINUE
285  40 CONTINUE
286  50 CONTINUE
287  END IF
288 *
289  work( 1 ) = iws
290  RETURN
291 *
292 * End of ZUNGRQ
293 *
integer function ilaenv(ISPEC, NAME, OPTS, N1, N2, N3, N4)
ILAENV
Definition: ilaenv.f:162
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine zlarfb(SIDE, TRANS, DIRECT, STOREV, M, N, K, V, LDV, T, LDT, C, LDC, WORK, LDWORK)
ZLARFB applies a block reflector or its conjugate-transpose to a general rectangular matrix.
Definition: zlarfb.f:197
subroutine zlarft(DIRECT, STOREV, N, K, V, LDV, TAU, T, LDT)
ZLARFT forms the triangular factor T of a block reflector H = I - vtvH
Definition: zlarft.f:163
subroutine zungr2(M, N, K, A, LDA, TAU, WORK, INFO)
ZUNGR2 generates all or part of the unitary matrix Q from an RQ factorization determined by cgerqf (u...
Definition: zungr2.f:114
Here is the call graph for this function:
Here is the caller graph for this function: