cpteqr()

subroutine cpteqr	(	character	compz,
		integer	n,
		real, dimension( * )	d,
		real, dimension( * )	e,
		complex, dimension( ldz, * )	z,
		integer	ldz,
		real, dimension( * )	work,
		integer	info )

CPTEQR

Download CPTEQR + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CPTEQR computes all eigenvalues and, optionally, eigenvectors of a
!> symmetric positive definite tridiagonal matrix by first factoring the
!> matrix using SPTTRF and then calling CBDSQR to compute the singular
!> values of the bidiagonal factor.
!>
!> This routine computes the eigenvalues of the positive definite
!> tridiagonal matrix to high relative accuracy.  This means that if the
!> eigenvalues range over many orders of magnitude in size, then the
!> small eigenvalues and corresponding eigenvectors will be computed
!> more accurately than, for example, with the standard QR method.
!>
!> The eigenvectors of a full or band positive definite Hermitian matrix
!> can also be found if CHETRD, CHPTRD, or CHBTRD has been used to
!> reduce this matrix to tridiagonal form.  (The reduction to
!> tridiagonal form, however, may preclude the possibility of obtaining
!> high relative accuracy in the small eigenvalues of the original
!> matrix, if these eigenvalues range over many orders of magnitude.)
!> 

Parameters

[in]	COMPZ	!> COMPZ is CHARACTER*1 !> = 'N': Compute eigenvalues only. !> = 'V': Compute eigenvectors of original Hermitian !> matrix also. Array Z contains the unitary matrix !> used to reduce the original matrix to tridiagonal !> form. !> = 'I': Compute eigenvectors of tridiagonal matrix also. !>
[in]	N	!> N is INTEGER !> The order of the matrix. N >= 0. !>
[in,out]	D	!> D is REAL array, dimension (N) !> On entry, the n diagonal elements of the tridiagonal matrix. !> On normal exit, D contains the eigenvalues, in descending !> order. !>
[in,out]	E	!> E is REAL array, dimension (N-1) !> On entry, the (n-1) subdiagonal elements of the tridiagonal !> matrix. !> On exit, E has been destroyed. !>
[in,out]	Z	!> Z is COMPLEX array, dimension (LDZ, N) !> On entry, if COMPZ = 'V', the unitary matrix used in the !> reduction to tridiagonal form. !> On exit, if COMPZ = 'V', the orthonormal eigenvectors of the !> original Hermitian matrix; !> if COMPZ = 'I', the orthonormal eigenvectors of the !> tridiagonal matrix. !> If INFO > 0 on exit, Z contains the eigenvectors associated !> with only the stored eigenvalues. !> If COMPZ = 'N', then Z is not referenced. !>
[in]	LDZ	!> LDZ is INTEGER !> The leading dimension of the array Z. LDZ >= 1, and if !> COMPZ = 'V' or 'I', LDZ >= max(1,N). !>
[out]	WORK	!> WORK is REAL array, dimension (4*N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit. !> < 0: if INFO = -i, the i-th argument had an illegal value. !> > 0: if INFO = i, and i is: !> <= N the Cholesky factorization of the matrix could !> not be performed because the leading principal !> minor of order i was not positive. !> > N the SVD algorithm failed to converge; !> if INFO = N+i, i off-diagonal elements of the !> bidiagonal factor did not converge to zero. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 142 of file cpteqr.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          COMPZ
      INTEGER            INFO, LDZ, N
*     ..
*     .. Array Arguments ..
      REAL               D( * ), E( * ), WORK( * )
      COMPLEX            Z( LDZ, * )
*     ..
*
*  ====================================================================
*
*     .. Parameters ..
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           cbdsqr, claset, spttrf, xerbla
*     ..
*     .. Local Arrays ..
      COMPLEX            C( 1, 1 ), VT( 1, 1 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, ICOMPZ, NRU
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
*
      IF( lsame( compz, 'N' ) ) THEN
         icompz = 0
      ELSE IF( lsame( compz, 'V' ) ) THEN
         icompz = 1
      ELSE IF( lsame( compz, 'I' ) ) THEN
         icompz = 2
      ELSE
         icompz = -1
      END IF
      IF( icompz.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( ( ldz.LT.1 ) .OR. ( icompz.GT.0 .AND. ldz.LT.max( 1,
     $         n ) ) ) THEN
         info = -6
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CPTEQR', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      IF( n.EQ.1 ) THEN
         IF( icompz.GT.0 )
     $      z( 1, 1 ) = cone
         RETURN
      END IF
      IF( icompz.EQ.2 )
     $   CALL claset( 'Full', n, n, czero, cone, z, ldz )
*
*     Call SPTTRF to factor the matrix.
*
      CALL spttrf( n, d, e, info )
      IF( info.NE.0 )
     $   RETURN
      DO 10 i = 1, n
         d( i ) = sqrt( d( i ) )
   10 CONTINUE
      DO 20 i = 1, n - 1
         e( i ) = e( i )*d( i )
   20 CONTINUE
*
*     Call CBDSQR to compute the singular values/vectors of the
*     bidiagonal factor.
*
      IF( icompz.GT.0 ) THEN
         nru = n
      ELSE
         nru = 0
      END IF
      CALL cbdsqr( 'Lower', n, 0, nru, 0, d, e, vt, 1, z, ldz, c, 1,
     $             work, info )
*
*     Square the singular values.
*
      IF( info.EQ.0 ) THEN
         DO 30 i = 1, n
            d( i ) = d( i )*d( i )
   30    CONTINUE
      ELSE
         info = n + info
      END IF
*
      RETURN
*
*     End of CPTEQR
*

Here is the call graph for this function:

Here is the caller graph for this function: