LAPACK  3.9.1
LAPACK: Linear Algebra PACKage

◆ zlahr2()

subroutine zlahr2 ( integer  N,
integer  K,
integer  NB,
complex*16, dimension( lda, * )  A,
integer  LDA,
complex*16, dimension( nb )  TAU,
complex*16, dimension( ldt, nb )  T,
integer  LDT,
complex*16, dimension( ldy, nb )  Y,
integer  LDY 
)

ZLAHR2 reduces the specified number of first columns of a general rectangular matrix A so that elements below the specified subdiagonal are zero, and returns auxiliary matrices which are needed to apply the transformation to the unreduced part of A.

Download ZLAHR2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZLAHR2 reduces the first NB columns of A complex general n-BY-(n-k+1)
 matrix A so that elements below the k-th subdiagonal are zero. The
 reduction is performed by an unitary similarity transformation
 Q**H * A * Q. The routine returns the matrices V and T which determine
 Q as a block reflector I - V*T*V**H, and also the matrix Y = A * V * T.

 This is an auxiliary routine called by ZGEHRD.
Parameters
[in]N
          N is INTEGER
          The order of the matrix A.
[in]K
          K is INTEGER
          The offset for the reduction. Elements below the k-th
          subdiagonal in the first NB columns are reduced to zero.
          K < N.
[in]NB
          NB is INTEGER
          The number of columns to be reduced.
[in,out]A
          A is COMPLEX*16 array, dimension (LDA,N-K+1)
          On entry, the n-by-(n-k+1) general matrix A.
          On exit, the elements on and above the k-th subdiagonal in
          the first NB columns are overwritten with the corresponding
          elements of the reduced matrix; the elements below the k-th
          subdiagonal, with the array TAU, represent the matrix Q as a
          product of elementary reflectors. The other columns of A are
          unchanged. See Further Details.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[out]TAU
          TAU is COMPLEX*16 array, dimension (NB)
          The scalar factors of the elementary reflectors. See Further
          Details.
[out]T
          T is COMPLEX*16 array, dimension (LDT,NB)
          The upper triangular matrix T.
[in]LDT
          LDT is INTEGER
          The leading dimension of the array T.  LDT >= NB.
[out]Y
          Y is COMPLEX*16 array, dimension (LDY,NB)
          The n-by-nb matrix Y.
[in]LDY
          LDY is INTEGER
          The leading dimension of the array Y. LDY >= N.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
  The matrix Q is represented as a product of nb elementary reflectors

     Q = H(1) H(2) . . . H(nb).

  Each H(i) has the form

     H(i) = I - tau * v * v**H

  where tau is a complex scalar, and v is a complex vector with
  v(1:i+k-1) = 0, v(i+k) = 1; v(i+k+1:n) is stored on exit in
  A(i+k+1:n,i), and tau in TAU(i).

  The elements of the vectors v together form the (n-k+1)-by-nb matrix
  V which is needed, with T and Y, to apply the transformation to the
  unreduced part of the matrix, using an update of the form:
  A := (I - V*T*V**H) * (A - Y*V**H).

  The contents of A on exit are illustrated by the following example
  with n = 7, k = 3 and nb = 2:

     ( a   a   a   a   a )
     ( a   a   a   a   a )
     ( a   a   a   a   a )
     ( h   h   a   a   a )
     ( v1  h   a   a   a )
     ( v1  v2  a   a   a )
     ( v1  v2  a   a   a )

  where a denotes an element of the original matrix A, h denotes a
  modified element of the upper Hessenberg matrix H, and vi denotes an
  element of the vector defining H(i).

  This subroutine is a slight modification of LAPACK-3.0's DLAHRD
  incorporating improvements proposed by Quintana-Orti and Van de
  Gejin. Note that the entries of A(1:K,2:NB) differ from those
  returned by the original LAPACK-3.0's DLAHRD routine. (This
  subroutine is not backward compatible with LAPACK-3.0's DLAHRD.)
References:
Gregorio Quintana-Orti and Robert van de Geijn, "Improving the performance of reduction to Hessenberg form," ACM Transactions on Mathematical Software, 32(2):180-194, June 2006.

Definition at line 180 of file zlahr2.f.

181 *
182 * -- LAPACK auxiliary routine --
183 * -- LAPACK is a software package provided by Univ. of Tennessee, --
184 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
185 *
186 * .. Scalar Arguments ..
187  INTEGER K, LDA, LDT, LDY, N, NB
188 * ..
189 * .. Array Arguments ..
190  COMPLEX*16 A( LDA, * ), T( LDT, NB ), TAU( NB ),
191  $ Y( LDY, NB )
192 * ..
193 *
194 * =====================================================================
195 *
196 * .. Parameters ..
197  COMPLEX*16 ZERO, ONE
198  parameter( zero = ( 0.0d+0, 0.0d+0 ),
199  $ one = ( 1.0d+0, 0.0d+0 ) )
200 * ..
201 * .. Local Scalars ..
202  INTEGER I
203  COMPLEX*16 EI
204 * ..
205 * .. External Subroutines ..
206  EXTERNAL zaxpy, zcopy, zgemm, zgemv, zlacpy,
208 * ..
209 * .. Intrinsic Functions ..
210  INTRINSIC min
211 * ..
212 * .. Executable Statements ..
213 *
214 * Quick return if possible
215 *
216  IF( n.LE.1 )
217  $ RETURN
218 *
219  DO 10 i = 1, nb
220  IF( i.GT.1 ) THEN
221 *
222 * Update A(K+1:N,I)
223 *
224 * Update I-th column of A - Y * V**H
225 *
226  CALL zlacgv( i-1, a( k+i-1, 1 ), lda )
227  CALL zgemv( 'NO TRANSPOSE', n-k, i-1, -one, y(k+1,1), ldy,
228  $ a( k+i-1, 1 ), lda, one, a( k+1, i ), 1 )
229  CALL zlacgv( i-1, a( k+i-1, 1 ), lda )
230 *
231 * Apply I - V * T**H * V**H to this column (call it b) from the
232 * left, using the last column of T as workspace
233 *
234 * Let V = ( V1 ) and b = ( b1 ) (first I-1 rows)
235 * ( V2 ) ( b2 )
236 *
237 * where V1 is unit lower triangular
238 *
239 * w := V1**H * b1
240 *
241  CALL zcopy( i-1, a( k+1, i ), 1, t( 1, nb ), 1 )
242  CALL ztrmv( 'Lower', 'Conjugate transpose', 'UNIT',
243  $ i-1, a( k+1, 1 ),
244  $ lda, t( 1, nb ), 1 )
245 *
246 * w := w + V2**H * b2
247 *
248  CALL zgemv( 'Conjugate transpose', n-k-i+1, i-1,
249  $ one, a( k+i, 1 ),
250  $ lda, a( k+i, i ), 1, one, t( 1, nb ), 1 )
251 *
252 * w := T**H * w
253 *
254  CALL ztrmv( 'Upper', 'Conjugate transpose', 'NON-UNIT',
255  $ i-1, t, ldt,
256  $ t( 1, nb ), 1 )
257 *
258 * b2 := b2 - V2*w
259 *
260  CALL zgemv( 'NO TRANSPOSE', n-k-i+1, i-1, -one,
261  $ a( k+i, 1 ),
262  $ lda, t( 1, nb ), 1, one, a( k+i, i ), 1 )
263 *
264 * b1 := b1 - V1*w
265 *
266  CALL ztrmv( 'Lower', 'NO TRANSPOSE',
267  $ 'UNIT', i-1,
268  $ a( k+1, 1 ), lda, t( 1, nb ), 1 )
269  CALL zaxpy( i-1, -one, t( 1, nb ), 1, a( k+1, i ), 1 )
270 *
271  a( k+i-1, i-1 ) = ei
272  END IF
273 *
274 * Generate the elementary reflector H(I) to annihilate
275 * A(K+I+1:N,I)
276 *
277  CALL zlarfg( n-k-i+1, a( k+i, i ), a( min( k+i+1, n ), i ), 1,
278  $ tau( i ) )
279  ei = a( k+i, i )
280  a( k+i, i ) = one
281 *
282 * Compute Y(K+1:N,I)
283 *
284  CALL zgemv( 'NO TRANSPOSE', n-k, n-k-i+1,
285  $ one, a( k+1, i+1 ),
286  $ lda, a( k+i, i ), 1, zero, y( k+1, i ), 1 )
287  CALL zgemv( 'Conjugate transpose', n-k-i+1, i-1,
288  $ one, a( k+i, 1 ), lda,
289  $ a( k+i, i ), 1, zero, t( 1, i ), 1 )
290  CALL zgemv( 'NO TRANSPOSE', n-k, i-1, -one,
291  $ y( k+1, 1 ), ldy,
292  $ t( 1, i ), 1, one, y( k+1, i ), 1 )
293  CALL zscal( n-k, tau( i ), y( k+1, i ), 1 )
294 *
295 * Compute T(1:I,I)
296 *
297  CALL zscal( i-1, -tau( i ), t( 1, i ), 1 )
298  CALL ztrmv( 'Upper', 'No Transpose', 'NON-UNIT',
299  $ i-1, t, ldt,
300  $ t( 1, i ), 1 )
301  t( i, i ) = tau( i )
302 *
303  10 CONTINUE
304  a( k+nb, nb ) = ei
305 *
306 * Compute Y(1:K,1:NB)
307 *
308  CALL zlacpy( 'ALL', k, nb, a( 1, 2 ), lda, y, ldy )
309  CALL ztrmm( 'RIGHT', 'Lower', 'NO TRANSPOSE',
310  $ 'UNIT', k, nb,
311  $ one, a( k+1, 1 ), lda, y, ldy )
312  IF( n.GT.k+nb )
313  $ CALL zgemm( 'NO TRANSPOSE', 'NO TRANSPOSE', k,
314  $ nb, n-k-nb, one,
315  $ a( 1, 2+nb ), lda, a( k+1+nb, 1 ), lda, one, y,
316  $ ldy )
317  CALL ztrmm( 'RIGHT', 'Upper', 'NO TRANSPOSE',
318  $ 'NON-UNIT', k, nb,
319  $ one, t, ldt, y, ldy )
320 *
321  RETURN
322 *
323 * End of ZLAHR2
324 *
subroutine zaxpy(N, ZA, ZX, INCX, ZY, INCY)
ZAXPY
Definition: zaxpy.f:88
subroutine zscal(N, ZA, ZX, INCX)
ZSCAL
Definition: zscal.f:78
subroutine zcopy(N, ZX, INCX, ZY, INCY)
ZCOPY
Definition: zcopy.f:81
subroutine ztrmv(UPLO, TRANS, DIAG, N, A, LDA, X, INCX)
ZTRMV
Definition: ztrmv.f:147
subroutine zgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
ZGEMV
Definition: zgemv.f:158
subroutine zgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
ZGEMM
Definition: zgemm.f:187
subroutine ztrmm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
ZTRMM
Definition: ztrmm.f:177
subroutine zlacpy(UPLO, M, N, A, LDA, B, LDB)
ZLACPY copies all or part of one two-dimensional array to another.
Definition: zlacpy.f:103
subroutine zlacgv(N, X, INCX)
ZLACGV conjugates a complex vector.
Definition: zlacgv.f:74
subroutine zlarfg(N, ALPHA, X, INCX, TAU)
ZLARFG generates an elementary reflector (Householder matrix).
Definition: zlarfg.f:106
Here is the call graph for this function:
Here is the caller graph for this function: