LAPACK  3.9.1
LAPACK: Linear Algebra PACKage

◆ zlatrd()

subroutine zlatrd ( character  UPLO,
integer  N,
integer  NB,
complex*16, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( * )  E,
complex*16, dimension( * )  TAU,
complex*16, dimension( ldw, * )  W,
integer  LDW 
)

ZLATRD reduces the first nb rows and columns of a symmetric/Hermitian matrix A to real tridiagonal form by an unitary similarity transformation.

Download ZLATRD + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZLATRD reduces NB rows and columns of a complex Hermitian matrix A to
 Hermitian tridiagonal form by a unitary similarity
 transformation Q**H * A * Q, and returns the matrices V and W which are
 needed to apply the transformation to the unreduced part of A.

 If UPLO = 'U', ZLATRD reduces the last NB rows and columns of a
 matrix, of which the upper triangle is supplied;
 if UPLO = 'L', ZLATRD reduces the first NB rows and columns of a
 matrix, of which the lower triangle is supplied.

 This is an auxiliary routine called by ZHETRD.
Parameters
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the upper or lower triangular part of the
          Hermitian matrix A is stored:
          = 'U': Upper triangular
          = 'L': Lower triangular
[in]N
          N is INTEGER
          The order of the matrix A.
[in]NB
          NB is INTEGER
          The number of rows and columns to be reduced.
[in,out]A
          A is COMPLEX*16 array, dimension (LDA,N)
          On entry, the Hermitian matrix A.  If UPLO = 'U', the leading
          n-by-n upper triangular part of A contains the upper
          triangular part of the matrix A, and the strictly lower
          triangular part of A is not referenced.  If UPLO = 'L', the
          leading n-by-n lower triangular part of A contains the lower
          triangular part of the matrix A, and the strictly upper
          triangular part of A is not referenced.
          On exit:
          if UPLO = 'U', the last NB columns have been reduced to
            tridiagonal form, with the diagonal elements overwriting
            the diagonal elements of A; the elements above the diagonal
            with the array TAU, represent the unitary matrix Q as a
            product of elementary reflectors;
          if UPLO = 'L', the first NB columns have been reduced to
            tridiagonal form, with the diagonal elements overwriting
            the diagonal elements of A; the elements below the diagonal
            with the array TAU, represent the  unitary matrix Q as a
            product of elementary reflectors.
          See Further Details.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[out]E
          E is DOUBLE PRECISION array, dimension (N-1)
          If UPLO = 'U', E(n-nb:n-1) contains the superdiagonal
          elements of the last NB columns of the reduced matrix;
          if UPLO = 'L', E(1:nb) contains the subdiagonal elements of
          the first NB columns of the reduced matrix.
[out]TAU
          TAU is COMPLEX*16 array, dimension (N-1)
          The scalar factors of the elementary reflectors, stored in
          TAU(n-nb:n-1) if UPLO = 'U', and in TAU(1:nb) if UPLO = 'L'.
          See Further Details.
[out]W
          W is COMPLEX*16 array, dimension (LDW,NB)
          The n-by-nb matrix W required to update the unreduced part
          of A.
[in]LDW
          LDW is INTEGER
          The leading dimension of the array W. LDW >= max(1,N).
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
  If UPLO = 'U', the matrix Q is represented as a product of elementary
  reflectors

     Q = H(n) H(n-1) . . . H(n-nb+1).

  Each H(i) has the form

     H(i) = I - tau * v * v**H

  where tau is a complex scalar, and v is a complex vector with
  v(i:n) = 0 and v(i-1) = 1; v(1:i-1) is stored on exit in A(1:i-1,i),
  and tau in TAU(i-1).

  If UPLO = 'L', the matrix Q is represented as a product of elementary
  reflectors

     Q = H(1) H(2) . . . H(nb).

  Each H(i) has the form

     H(i) = I - tau * v * v**H

  where tau is a complex scalar, and v is a complex vector with
  v(1:i) = 0 and v(i+1) = 1; v(i+1:n) is stored on exit in A(i+1:n,i),
  and tau in TAU(i).

  The elements of the vectors v together form the n-by-nb matrix V
  which is needed, with W, to apply the transformation to the unreduced
  part of the matrix, using a Hermitian rank-2k update of the form:
  A := A - V*W**H - W*V**H.

  The contents of A on exit are illustrated by the following examples
  with n = 5 and nb = 2:

  if UPLO = 'U':                       if UPLO = 'L':

    (  a   a   a   v4  v5 )              (  d                  )
    (      a   a   v4  v5 )              (  1   d              )
    (          a   1   v5 )              (  v1  1   a          )
    (              d   1  )              (  v1  v2  a   a      )
    (                  d  )              (  v1  v2  a   a   a  )

  where d denotes a diagonal element of the reduced matrix, a denotes
  an element of the original matrix that is unchanged, and vi denotes
  an element of the vector defining H(i).

Definition at line 198 of file zlatrd.f.

199 *
200 * -- LAPACK auxiliary routine --
201 * -- LAPACK is a software package provided by Univ. of Tennessee, --
202 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
203 *
204 * .. Scalar Arguments ..
205  CHARACTER UPLO
206  INTEGER LDA, LDW, N, NB
207 * ..
208 * .. Array Arguments ..
209  DOUBLE PRECISION E( * )
210  COMPLEX*16 A( LDA, * ), TAU( * ), W( LDW, * )
211 * ..
212 *
213 * =====================================================================
214 *
215 * .. Parameters ..
216  COMPLEX*16 ZERO, ONE, HALF
217  parameter( zero = ( 0.0d+0, 0.0d+0 ),
218  $ one = ( 1.0d+0, 0.0d+0 ),
219  $ half = ( 0.5d+0, 0.0d+0 ) )
220 * ..
221 * .. Local Scalars ..
222  INTEGER I, IW
223  COMPLEX*16 ALPHA
224 * ..
225 * .. External Subroutines ..
226  EXTERNAL zaxpy, zgemv, zhemv, zlacgv, zlarfg, zscal
227 * ..
228 * .. External Functions ..
229  LOGICAL LSAME
230  COMPLEX*16 ZDOTC
231  EXTERNAL lsame, zdotc
232 * ..
233 * .. Intrinsic Functions ..
234  INTRINSIC dble, min
235 * ..
236 * .. Executable Statements ..
237 *
238 * Quick return if possible
239 *
240  IF( n.LE.0 )
241  $ RETURN
242 *
243  IF( lsame( uplo, 'U' ) ) THEN
244 *
245 * Reduce last NB columns of upper triangle
246 *
247  DO 10 i = n, n - nb + 1, -1
248  iw = i - n + nb
249  IF( i.LT.n ) THEN
250 *
251 * Update A(1:i,i)
252 *
253  a( i, i ) = dble( a( i, i ) )
254  CALL zlacgv( n-i, w( i, iw+1 ), ldw )
255  CALL zgemv( 'No transpose', i, n-i, -one, a( 1, i+1 ),
256  $ lda, w( i, iw+1 ), ldw, one, a( 1, i ), 1 )
257  CALL zlacgv( n-i, w( i, iw+1 ), ldw )
258  CALL zlacgv( n-i, a( i, i+1 ), lda )
259  CALL zgemv( 'No transpose', i, n-i, -one, w( 1, iw+1 ),
260  $ ldw, a( i, i+1 ), lda, one, a( 1, i ), 1 )
261  CALL zlacgv( n-i, a( i, i+1 ), lda )
262  a( i, i ) = dble( a( i, i ) )
263  END IF
264  IF( i.GT.1 ) THEN
265 *
266 * Generate elementary reflector H(i) to annihilate
267 * A(1:i-2,i)
268 *
269  alpha = a( i-1, i )
270  CALL zlarfg( i-1, alpha, a( 1, i ), 1, tau( i-1 ) )
271  e( i-1 ) = alpha
272  a( i-1, i ) = one
273 *
274 * Compute W(1:i-1,i)
275 *
276  CALL zhemv( 'Upper', i-1, one, a, lda, a( 1, i ), 1,
277  $ zero, w( 1, iw ), 1 )
278  IF( i.LT.n ) THEN
279  CALL zgemv( 'Conjugate transpose', i-1, n-i, one,
280  $ w( 1, iw+1 ), ldw, a( 1, i ), 1, zero,
281  $ w( i+1, iw ), 1 )
282  CALL zgemv( 'No transpose', i-1, n-i, -one,
283  $ a( 1, i+1 ), lda, w( i+1, iw ), 1, one,
284  $ w( 1, iw ), 1 )
285  CALL zgemv( 'Conjugate transpose', i-1, n-i, one,
286  $ a( 1, i+1 ), lda, a( 1, i ), 1, zero,
287  $ w( i+1, iw ), 1 )
288  CALL zgemv( 'No transpose', i-1, n-i, -one,
289  $ w( 1, iw+1 ), ldw, w( i+1, iw ), 1, one,
290  $ w( 1, iw ), 1 )
291  END IF
292  CALL zscal( i-1, tau( i-1 ), w( 1, iw ), 1 )
293  alpha = -half*tau( i-1 )*zdotc( i-1, w( 1, iw ), 1,
294  $ a( 1, i ), 1 )
295  CALL zaxpy( i-1, alpha, a( 1, i ), 1, w( 1, iw ), 1 )
296  END IF
297 *
298  10 CONTINUE
299  ELSE
300 *
301 * Reduce first NB columns of lower triangle
302 *
303  DO 20 i = 1, nb
304 *
305 * Update A(i:n,i)
306 *
307  a( i, i ) = dble( a( i, i ) )
308  CALL zlacgv( i-1, w( i, 1 ), ldw )
309  CALL zgemv( 'No transpose', n-i+1, i-1, -one, a( i, 1 ),
310  $ lda, w( i, 1 ), ldw, one, a( i, i ), 1 )
311  CALL zlacgv( i-1, w( i, 1 ), ldw )
312  CALL zlacgv( i-1, a( i, 1 ), lda )
313  CALL zgemv( 'No transpose', n-i+1, i-1, -one, w( i, 1 ),
314  $ ldw, a( i, 1 ), lda, one, a( i, i ), 1 )
315  CALL zlacgv( i-1, a( i, 1 ), lda )
316  a( i, i ) = dble( a( i, i ) )
317  IF( i.LT.n ) THEN
318 *
319 * Generate elementary reflector H(i) to annihilate
320 * A(i+2:n,i)
321 *
322  alpha = a( i+1, i )
323  CALL zlarfg( n-i, alpha, a( min( i+2, n ), i ), 1,
324  $ tau( i ) )
325  e( i ) = alpha
326  a( i+1, i ) = one
327 *
328 * Compute W(i+1:n,i)
329 *
330  CALL zhemv( 'Lower', n-i, one, a( i+1, i+1 ), lda,
331  $ a( i+1, i ), 1, zero, w( i+1, i ), 1 )
332  CALL zgemv( 'Conjugate transpose', n-i, i-1, one,
333  $ w( i+1, 1 ), ldw, a( i+1, i ), 1, zero,
334  $ w( 1, i ), 1 )
335  CALL zgemv( 'No transpose', n-i, i-1, -one, a( i+1, 1 ),
336  $ lda, w( 1, i ), 1, one, w( i+1, i ), 1 )
337  CALL zgemv( 'Conjugate transpose', n-i, i-1, one,
338  $ a( i+1, 1 ), lda, a( i+1, i ), 1, zero,
339  $ w( 1, i ), 1 )
340  CALL zgemv( 'No transpose', n-i, i-1, -one, w( i+1, 1 ),
341  $ ldw, w( 1, i ), 1, one, w( i+1, i ), 1 )
342  CALL zscal( n-i, tau( i ), w( i+1, i ), 1 )
343  alpha = -half*tau( i )*zdotc( n-i, w( i+1, i ), 1,
344  $ a( i+1, i ), 1 )
345  CALL zaxpy( n-i, alpha, a( i+1, i ), 1, w( i+1, i ), 1 )
346  END IF
347 *
348  20 CONTINUE
349  END IF
350 *
351  RETURN
352 *
353 * End of ZLATRD
354 *
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
complex *16 function zdotc(N, ZX, INCX, ZY, INCY)
ZDOTC
Definition: zdotc.f:83
subroutine zaxpy(N, ZA, ZX, INCX, ZY, INCY)
ZAXPY
Definition: zaxpy.f:88
subroutine zscal(N, ZA, ZX, INCX)
ZSCAL
Definition: zscal.f:78
subroutine zhemv(UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
ZHEMV
Definition: zhemv.f:154
subroutine zgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
ZGEMV
Definition: zgemv.f:158
subroutine zlacgv(N, X, INCX)
ZLACGV conjugates a complex vector.
Definition: zlacgv.f:74
subroutine zlarfg(N, ALPHA, X, INCX, TAU)
ZLARFG generates an elementary reflector (Householder matrix).
Definition: zlarfg.f:106
Here is the call graph for this function:
Here is the caller graph for this function: