zrqt02()

subroutine zrqt02	(	integer	m,
		integer	n,
		integer	k,
		complex*16, dimension( lda, * )	a,
		complex*16, dimension( lda, * )	af,
		complex*16, dimension( lda, * )	q,
		complex*16, dimension( lda, * )	r,
		integer	lda,
		complex*16, dimension( * )	tau,
		complex*16, dimension( lwork )	work,
		integer	lwork,
		double precision, dimension( * )	rwork,
		double precision, dimension( * )	result )

ZRQT02

Purpose:

!>
!> ZRQT02 tests ZUNGRQ, which generates an m-by-n matrix Q with
!> orthonormal rows that is defined as the product of k elementary
!> reflectors.
!>
!> Given the RQ factorization of an m-by-n matrix A, ZRQT02 generates
!> the orthogonal matrix Q defined by the factorization of the last k
!> rows of A; it compares R(m-k+1:m,n-m+1:n) with
!> A(m-k+1:m,1:n)*Q(n-m+1:n,1:n)', and checks that the rows of Q are
!> orthonormal.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix Q to be generated. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix Q to be generated. !> N >= M >= 0. !>
[in]	K	!> K is INTEGER !> The number of elementary reflectors whose product defines the !> matrix Q. M >= K >= 0. !>
[in]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> The m-by-n matrix A which was factorized by ZRQT01. !>
[in]	AF	!> AF is COMPLEX*16 array, dimension (LDA,N) !> Details of the RQ factorization of A, as returned by ZGERQF. !> See ZGERQF for further details. !>
[out]	Q	!> Q is COMPLEX*16 array, dimension (LDA,N) !>
[out]	R	!> R is COMPLEX*16 array, dimension (LDA,M) !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the arrays A, AF, Q and L. LDA >= N. !>
[in]	TAU	!> TAU is COMPLEX*16 array, dimension (M) !> The scalar factors of the elementary reflectors corresponding !> to the RQ factorization in AF. !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (M) !>
[out]	RESULT	!> RESULT is DOUBLE PRECISION array, dimension (2) !> The test ratios: !> RESULT(1) = norm( R - A*Q' ) / ( N * norm(A) * EPS ) !> RESULT(2) = norm( I - Q*Q' ) / ( N * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 134 of file zrqt02.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            K, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   RESULT( * ), RWORK( * )
      COMPLEX*16         A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
     $                   R( LDA, * ), TAU( * ), WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         ROGUE
      parameter( rogue = ( -1.0d+10, -1.0d+10 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO
      DOUBLE PRECISION   ANORM, EPS, RESID
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, ZLANGE, ZLANSY
      EXTERNAL           dlamch, zlange, zlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemm, zherk, zlacpy, zlaset, zungrq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, max
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 ) THEN
         result( 1 ) = zero
         result( 2 ) = zero
         RETURN
      END IF
*
      eps = dlamch( 'Epsilon' )
*
*     Copy the last k rows of the factorization to the array Q
*
      CALL zlaset( 'Full', m, n, rogue, rogue, q, lda )
      IF( k.LT.n )
     $   CALL zlacpy( 'Full', k, n-k, af( m-k+1, 1 ), lda,
     $                q( m-k+1, 1 ), lda )
      IF( k.GT.1 )
     $   CALL zlacpy( 'Lower', k-1, k-1, af( m-k+2, n-k+1 ), lda,
     $                q( m-k+2, n-k+1 ), lda )
*
*     Generate the last n rows of the matrix Q
*
      srnamt = 'ZUNGRQ'
      CALL zungrq( m, n, k, q, lda, tau( m-k+1 ), work, lwork, info )
*
*     Copy R(m-k+1:m,n-m+1:n)
*
      CALL zlaset( 'Full', k, m, dcmplx( zero ), dcmplx( zero ),
     $             r( m-k+1, n-m+1 ), lda )
      CALL zlacpy( 'Upper', k, k, af( m-k+1, n-k+1 ), lda,
     $             r( m-k+1, n-k+1 ), lda )
*
*     Compute R(m-k+1:m,n-m+1:n) - A(m-k+1:m,1:n) * Q(n-m+1:n,1:n)'
*
      CALL zgemm( 'No transpose', 'Conjugate transpose', k, m, n,
     $            dcmplx( -one ), a( m-k+1, 1 ), lda, q, lda,
     $            dcmplx( one ), r( m-k+1, n-m+1 ), lda )
*
*     Compute norm( R - A*Q' ) / ( N * norm(A) * EPS ) .
*
      anorm = zlange( '1', k, n, a( m-k+1, 1 ), lda, rwork )
      resid = zlange( '1', k, m, r( m-k+1, n-m+1 ), lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / dble( max( 1, n ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL zlaset( 'Full', m, m, dcmplx( zero ), dcmplx( one ), r, lda )
      CALL zherk( 'Upper', 'No transpose', m, n, -one, q, lda, one, r,
     $            lda )
*
*     Compute norm( I - Q*Q' ) / ( N * EPS ) .
*
      resid = zlansy( '1', 'Upper', m, r, lda, rwork )
*
      result( 2 ) = ( resid / dble( max( 1, n ) ) ) / eps
*
      RETURN
*
*     End of ZRQT02
*

Here is the call graph for this function:

Here is the caller graph for this function: