LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
subroutine dorg2r ( integer  M,
integer  N,
integer  K,
double precision, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( * )  TAU,
double precision, dimension( * )  WORK,
integer  INFO 
)

DORG2R generates all or part of the orthogonal matrix Q from a QR factorization determined by sgeqrf (unblocked algorithm).

Download DORG2R + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DORG2R generates an m by n real matrix Q with orthonormal columns,
 which is defined as the first n columns of a product of k elementary
 reflectors of order m

       Q  =  H(1) H(2) . . . H(k)

 as returned by DGEQRF.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix Q. M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix Q. M >= N >= 0.
[in]K
          K is INTEGER
          The number of elementary reflectors whose product defines the
          matrix Q. N >= K >= 0.
[in,out]A
          A is DOUBLE PRECISION array, dimension (LDA,N)
          On entry, the i-th column must contain the vector which
          defines the elementary reflector H(i), for i = 1,2,...,k, as
          returned by DGEQRF in the first k columns of its array
          argument A.
          On exit, the m-by-n matrix Q.
[in]LDA
          LDA is INTEGER
          The first dimension of the array A. LDA >= max(1,M).
[in]TAU
          TAU is DOUBLE PRECISION array, dimension (K)
          TAU(i) must contain the scalar factor of the elementary
          reflector H(i), as returned by DGEQRF.
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (N)
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument has an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
September 2012

Definition at line 116 of file dorg2r.f.

116 *
117 * -- LAPACK computational routine (version 3.4.2) --
118 * -- LAPACK is a software package provided by Univ. of Tennessee, --
119 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
120 * September 2012
121 *
122 * .. Scalar Arguments ..
123  INTEGER info, k, lda, m, n
124 * ..
125 * .. Array Arguments ..
126  DOUBLE PRECISION a( lda, * ), tau( * ), work( * )
127 * ..
128 *
129 * =====================================================================
130 *
131 * .. Parameters ..
132  DOUBLE PRECISION one, zero
133  parameter ( one = 1.0d+0, zero = 0.0d+0 )
134 * ..
135 * .. Local Scalars ..
136  INTEGER i, j, l
137 * ..
138 * .. External Subroutines ..
139  EXTERNAL dlarf, dscal, xerbla
140 * ..
141 * .. Intrinsic Functions ..
142  INTRINSIC max
143 * ..
144 * .. Executable Statements ..
145 *
146 * Test the input arguments
147 *
148  info = 0
149  IF( m.LT.0 ) THEN
150  info = -1
151  ELSE IF( n.LT.0 .OR. n.GT.m ) THEN
152  info = -2
153  ELSE IF( k.LT.0 .OR. k.GT.n ) THEN
154  info = -3
155  ELSE IF( lda.LT.max( 1, m ) ) THEN
156  info = -5
157  END IF
158  IF( info.NE.0 ) THEN
159  CALL xerbla( 'DORG2R', -info )
160  RETURN
161  END IF
162 *
163 * Quick return if possible
164 *
165  IF( n.LE.0 )
166  $ RETURN
167 *
168 * Initialise columns k+1:n to columns of the unit matrix
169 *
170  DO 20 j = k + 1, n
171  DO 10 l = 1, m
172  a( l, j ) = zero
173  10 CONTINUE
174  a( j, j ) = one
175  20 CONTINUE
176 *
177  DO 40 i = k, 1, -1
178 *
179 * Apply H(i) to A(i:m,i:n) from the left
180 *
181  IF( i.LT.n ) THEN
182  a( i, i ) = one
183  CALL dlarf( 'Left', m-i+1, n-i, a( i, i ), 1, tau( i ),
184  $ a( i, i+1 ), lda, work )
185  END IF
186  IF( i.LT.m )
187  $ CALL dscal( m-i, -tau( i ), a( i+1, i ), 1 )
188  a( i, i ) = one - tau( i )
189 *
190 * Set A(1:i-1,i) to zero
191 *
192  DO 30 l = 1, i - 1
193  a( l, i ) = zero
194  30 CONTINUE
195  40 CONTINUE
196  RETURN
197 *
198 * End of DORG2R
199 *
subroutine dlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
DLARF applies an elementary reflector to a general rectangular matrix.
Definition: dlarf.f:126
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine dscal(N, DA, DX, INCX)
DSCAL
Definition: dscal.f:55

Here is the call graph for this function:

Here is the caller graph for this function: